Finite Volume Elements (FVE) for ThinkOrSwim

[korygill]

The Finite Volume Elements (FVE) strategy is a money flow indicator that combines trading volume and volatility indicators to gauge market sentiment. The FVE strategy is considered stable and reliable compared to single indicators.

This indicator is the work of Markos Katsanos. I have ported the indicator to thinkorswim.

Here is a chart of the indicator from Markos

ThinkScript code for this indicator

#
# FiniteVolumeElements_FVE
#
# Author: Kory Gill, @korygill
#
# Created from idea on https://usethinkscript.com/threads/finite-volume-elements.593/
# Original idea is from http://mkatsanos.com/FVE.html
#
# VERSION HISTORY (sortable date and time (your local time is fine), and your initials
# 20190907-1200-KG    - Created.
# ...
# ...

declare once_per_bar;
declare lower;

#
# inputs
#
input CutOff = 0.003;
input Samples = 22;

#
# logic
#
def bn = BarNumber();
def nan = double.NaN;

def tp = hlc3;
def mf = (close - (high+low)/2) + tp - tp[1];
def fveFactor = if mf > (CutOff*Close)
                then 1
                else if mf < (-1*CutOff*Close) then -1
                else 0;

def VolumePlusMinus = volume * fveFactor;
def fveSum = Sum(VolumePlusMinus, Samples);
def fve = if bn > Samples
          then (fveSum / (Average(volume,Samples) * Samples)) * 100
          else nan;


#
# plots
#
plot pFVE = fve;

plot pFVE_MA = MovingAverage(AverageType.SIMPLE, fve, 30);
pFVE_MA.SetDefaultColor(Color.Gray);
PFVE_MA.SetPaintingStrategy(PaintingStrategy.DASHES);

plot zeroLine = 0;
zeroLine.SetDefaultColor(Color.White);

Link to a flex grid as shown above

https://tos.mx/PUmEFD

Happy trading,
Kory Gill, @korygill

 

[SolidChiken]

Thank you @korygill. Grateful

 

[skynetgen]

Man this is amazing work, Thank you for porting it and bringing it up
I took some liberty and added some visual signals to this
https://tos.mx/qg6j5F

 

[SolidChiken]

Shocked. Genius work there @skynetgen. Unbelievable

 

[skynetgen]

https://tos.mx/ZlHR6d
Version with reworked short/long signal and variableMA

Also for daily the default settings are fine. For weekly , 30m and 5m 13,21 are better

 

[korygill]

Version with reworked short/long signal and variableMA

Finally loaded up your edits on this @skynetgen. I like the technique with the 50 histogram. Nice coloring as well.

 

[markos]

@korygill and @skynetgen Great job! This will be a good addition to my repertoire.

 

[skynetgen]

I think I did a few fixes since I last posted it. This is latest version

https://tos.mx/4ESHZd9
I am using it on hourly, daily and weekly timeframes. Using 13/21 settings

 

[ball]

Hello, I have serious doubts about this code.

Why are you not using any measurement of price range in the cutoff?

 

[markos]

@ball welcome to useThinkScript. The following is from the author's website... "You can find a money flow divergence system using both FVE and VFI here and a comparison between 7 Money Flow Indicators in my article in the July 2011 of S&C. " You may find the answer there.

 

[zeek]

Can anyone post a screenshot of how the reworked version looks like?

 

[BenTen]

@zeek Kory already posted it above. You can always add it to your ToS as well.

 

[SolidChiken]

Hi @korygill @skynetgen... Do you guys facing the missing plot after a period of time? Gotta refresh the chart in order to get it back. Wondering is there a way to fix it?

 

[SolidChiken]

Solved by take out declare once_per_bar;

 

[MerryDay]

I have been using this indicator for about 6 months. I keep noticing more and more correlations with the movement of stock.

This indicator can be used to signal entry as indicated by the 1st rectangle in the photo below. But my favorite use is to identify chop as shown in the 2nd rectangle.

If both the FVE and OBV (On Balance Volume) are below their moving averages (as signified by the red lines), the stock is either descending or in chop.

I use it to filter every scan I run and every arrow that I draw. It removes a lot of false signals.

Here is my chart:
https://tos.mx/6si5qBI

 

[Pelonsax]

Made it MTF capable and set it to the higher time frame on the lower time frame chart

#
# FiniteVolumeElements_FVE
#
# Author: Kory Gill, [USER=212]@korygill[/USER]
#
# Created from idea on https://usethinkscript.com/threads/finite-volume-elements.593/
# Original idea is from http://mkatsanos.com/FVE.html
#
# VERSION HISTORY (sortable date and time (your local time is fine), and your initials
# 20190907-1200-KG    - Created.
# ...7/20/2020 Added MTF Capability in order to combat the fact that it does not appear on lower than 2 minute time frames### Ramon Del Villar AKA Pelonsax
# ...

declare lower;
input AGG = aggregationPeriod.FIVE_MIN;
input CutOff = 0.003;
input Samples_Used = 22;
def samples = Samples_Used * (AGG/60000);

def bn = BarNumber();
def nan = double.NaN;

def tp = hlc3(period = AGG);
def mf = (close(period = AGG) - (high(period = AGG)+low(period = AGG))/2) + tp - tp[1];
def fveFactor = if mf > (CutOff*Close(period = AGG))
                then 1
                else if mf < (-1*CutOff*Close(period = AGG)) then -1
                else 0;

def VolumePlusMinus = volume(period = AGG) * fveFactor;
def fveSum = Sum(VolumePlusMinus, Samples);
def fve = if bn > Samples
          then (fveSum / (Average(volume(period = AGG),Samples) * Samples)) * 100
          else nan;

plot pFVE = fve;

plot pFVE_MA = MovingAverage(AverageType.SIMPLE, fve, 30);
pFVE_MA.SetDefaultColor(Color.Gray);
PFVE_MA.SetPaintingStrategy(PaintingStrategy.DASHES);

plot zeroLine = 0;
zeroLine.SetDefaultColor(Color.White);

 

[Pelonsax]

I'VE DONE IT!!!!!!!! OMFG I CAN'T BELIEVE I DID IT!!! (Okay, truth is, this is a little over my head, but I think I did it. You be the judge)

Ladies and Gentlemen......

Spike_Dampened_Finite_Volume_Elements (I suppose another way of calling it could be "NORMALIZED_FINITE_VOLUME_ELEMENTS")

I took the logic from Volume Flow Indicator which is a normalized version of On Balance Volume and applied it here. Below are the indicators in question back to back. Previously, I had thought that the only way to show the original FVE study on a one minute chart was to change the aggregation, but as you can see, there is no need to do that with this "Normalized" Version (though it is possible if one were so inclined.

Here is the code to the dampened indicator:

# FiniteVolumeElements_FVE
#
# Author: Kory Gill, [USER=212]@korygill[/USER]
#
# Created from idea on https://usethinkscript.com/threads/finite-volume-elements.593/
# Original idea is from http://mkatsanos.com/FVE.html
#
# VERSION HISTORY (sortable date and time (your local time is fine), and your initials
# 20190907-1200-KG    - Created.

###############################################################################
### NORMALIZATION (Volume Damping adaptation) by Ramon Del Villar AKA PElonsax
### 7/20/2020 #################################################################
###############################################################################
# The damping logic is taken directly from VFI #

declare once_per_bar;
declare lower;

#
# inputs
#
input Samples = 22;

#
# logic
#
def bn = BarNumber();
def nan = double.NaN;


input maxVolumeCutOff = 2.5;
###Coefficient used in calculation of “Cut Off” value. Lower values mean stronger damping of volume spikes###

Assert(maxVolumeCutOff > 0, "'max volume cut off' must be positive: " + maxVolumeCutOff);

def cutOff = 0.2 * StDev(Log(hlc3) - Log(hlc3[1]), 30) * close;
def hlcChange = hlc3 - hlc3[1];
def avgVolume = Average(volume, 30)[1];
def minVolume = Min(volume, avgVolume * maxVolumeCutOff);
def dirVolume = if hlcChange > cutOff
    then minVolume
    else if hlcChange < -cutOff
        then -minVolume
        else 0;


def mf = (close - (high+low)/2) + hlc3 - hlc3 [1];
def fveSum = Sum(dirVolume, Samples);

def fve = if bn > Samples
          then (fveSum / (Average(avgVolume, Samples) * Samples)) * 100
          else nan;


#
# plots
#
plot pFVE = fve;

plot pFVE_MA = MovingAverage(AverageType.SIMPLE, fve, 30);
pFVE_MA.SetDefaultColor(Color.Gray);
PFVE_MA.SetPaintingStrategy(PaintingStrategy.DASHES);

plot zeroLine = 0;
zeroLine.SetDefaultColor(Color.White);

Here is a shareable link:

https://tos.mx/asxD578
ENJOY!!

 

[petey150]

@MerryDay Could you add another longer MA to it??

 

[MerryDay]

@petey150

# to chg the length of the moving average, change line#17: The "30" represents length
def FVE_MA = MovingAverage(AverageType.SIMPLE, fve, 30);

 

[cswu1211]

https://tos.mx/ZlHR6d
Version with reworked short/long signal and variableMA

Also for daily the default settings are fine. For weekly , 30m and 5m 13,21 are better

May not be a BIG question, however, pls advise why the "Title" of the studies were not shown on the top left corner of FVE studies?!