#
# see https://usethinkscript.com/threads/how-to-get-current-days-premarket-high.695/
#
declare once_per_bar;
input PlotPreMktLinesHrsPastOpen = yes;
input ShowChartBubbles = yes;
def bar = BarNumber();
def nan = Double.NaN;
def vHigh = high;
def vLow = low;
def PMhrs = RegularTradingStart (GetYYYYMMDD()) > GetTime();
def RMhrs = RegularTradingStart (GetYYYYMMDD()) < GetTime();
def PMStart = RMhrs[1] and PMhrs;
def PMHigh = CompoundValue(1, if PMStart then vHigh else if PMhrs then Max(vHigh, PMHigh[1]) else PMHigh[1], nan);
def PMLow = CompoundValue(1, if PMStart then vLow else if PMhrs then Min(vLow, PMLow[1]) else PMLow[1], nan);
def highBar = if PMhrs and vHigh == PMHigh then bar else nan;
def lowBar = if PMhrs and vLow == PMLow then bar else nan;
def PMHighBar = if bar == HighestAll(highBar) then PMHigh else PMHighBar[1];
def PMLowBar = if bar == HighestAll(lowBar) then PMLow else PMLowBar[1];
plot PMH = if PlotPreMktLinesHrsPastOpen and PMHighBar != 0
then PMHighBar
else nan;
plot PML = if PlotPreMktLinesHrsPastOpen and PMLowBar != 0
then PMLowBar
else nan;
plot PMMid = if PlotPreMktLinesHrsPastOpen and PMHighBar != 0 and PMLowBar != 0
then (PMHighBar + PMLowBar) / 2
else nan;
def prevPMHigh = if PMStart[-1] then PMHigh[1] else prevPMHigh[1];
plot pPMH = if !IsNaN(prevPMHigh) and prevPMHigh != 0 then prevPMHigh else nan;
pPMH.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
pPMH.AssignValueColor(PMH.TakeValueColor());
def prevPMLow = if PMStart[-1] then PMLow[1] else prevPMLow[1];
plot pPML = if !IsNaN(prevPMLow) and prevPMLow != 0 then prevPMLow else nan;
pPML.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
pPML.AssignValueColor(PML.TakeValueColor());
def prevPMMid = if PMStart[-1] then ((PMHigh[1]+PMLow[1])/2) else prevPMMid[1];
plot pPMM = if !IsNaN(prevPMMid) and prevPMMid != 0 then prevPMMid else nan;
pPMM.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
pPMM.AssignValueColor(PMMid.TakeValueColor());
AddChartBubble(ShowChartBubbles and bar == HighestAll(highBar),
PMHigh,
"PM High",
Color.GRAY,
1);
AddChartBubble(ShowChartBubbles and bar == HighestAll(lowBar),
PMLow,
"PM Low",
Color.GRAY,
0);
AddChartBubble(ShowChartBubbles and bar == Max(HighestAll(highBar), HighestAll(lowBar)),
(PMHighBar + PMLowBar) / 2,
"PM Mid",
Color.GRAY,
1);
# end of script
