Here are some of the indicators I use every day

Status
Not open for further replies.

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

SIGN UP NOW LEARN MORE
J007RMC said:
Anyone looking for a good watchlist here it is. https://tos.mx/tsDIOMI
Also, a really good scan and you can pair it with an existing watchlist. https://tos.mx/sGWldH3
For this result.
https://imgur.com/LWn8OYE
Click to expand...
G'day J007 - Appreciate your sharing, amazing watchlist. I'm not able to import the scanner link that you provided, if you don't mind can you pls share the study so that I can add that to the custom study, seems it is not a function either I'm getting this error message "
No such function: AA_3_MAS_PPO_ARROWS at 1:1
No such function: AA_3_MAS_PPO_ARROWS at 1:1
No such function: AA_LIN_REGRESS_CHANNEL_SCAN at 1:1
No such function: AA_LIN_REGRESS_CHANNEL_SCAN at 1:1
 
kganesh1 said:
G'day J007 - Appreciate your sharing, amazing watchlist. I'm not able to import the scanner link that you provided, if you don't mind can you pls share the study so that I can add that to the custom study, seems it is not a function either I'm getting this error message "
No such function: AA_3_MAS_PPO_ARROWS at 1:1
No such function: AA_3_MAS_PPO_ARROWS at 1:1
No such function: AA_LIN_REGRESS_CHANNEL_SCAN at 1:1
No such function: AA_LIN_REGRESS_CHANNEL_SCAN at 1:1
Click to expand...
Copy the link.....choose settings upper right corner and choose to import study then cntr v to copy into the box then choose preview
 
A script I just came across I named it Valleys no pic but something to play with...good. Similar to zig-zag but from the bottom up Ive not run this yet and it probably repaints. I think when used with other indicators it has promise.

#McPerson posted 5/5
#Valleys


# ----- define a valley as any point which is lower than the three preceding lows and the three following lows
def Valley = low < Lowest(low[1], 3) and low < Lowest(low[-3], 3);

# ----- mark each valley with an up arrow -----
plot ArrowUP = Valley;
ArrowUP.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
ArrowUP.SetDefaultColor(Color.WHITE);
ArrowUP.SetLineWeight(4);

# ----- draw a straight line connecting each valley -----
plot line = if ArrowUP then low else Double.NaN;
line.EnableApproximation();
line.SetDefaultColor(Color.LIME);
line.SetLineWeight(2);
 
kganesh1 said:
J007- Thanks for your quick response, sorry I should have elaborated it. I'm able to import the link, however, if I go to those 2 custom studies(AA_3_MAS_PPO_ARROW & AA_LIN_REGRESS_CHANNEL_SCAN) in thinkscript editor to read the code and understand the scan details that is where I'm getting the error messages.
Click to expand...
I named this AA-1 and put it in the watchlist set to time 1 hr
input period = 10;
input smoothingPeriod = 3;
input priceChangeWeighted = YES;
DEF delta = absValue(close-close[1]);
DEF multiplier = if(priceChangeWeighted, delta,1);

DEF maxLine = 80.0;
DEF minLine = 20.0;

DEF up = if(close > close[1], volume*multiplier, 0);
DEF down = if(close < close[1], volume*multiplier, 0);
DEF upvol = sum(up, period);
DEF downvol = sum(down, period);
DEF ratio = (100.0*(upvol/(downvol+upvol)));
def UPDVR = HullMovingAvg(ratio,smoothingPeriod);

DEF lineColor = if(UPDVR >= 80.0, 6, if(UPDVR < 20.0,5,1));
DEF plotData = UPDVR;
DEF VolumeRatio = UPDVR;

DEF VolumeRatioLine = UPDVR;

PLOT UPSIG = if UPDVR crosses above 80 THEN 1 ELSE 0;
DEF DNSIG = if UPDVR crosses below 20 THEN 1 ELSE 0;

UPsig.AssignvalueColor(IF UPsig THEN COLOR.LIGHT_green ELSE if DNsig then color.PINK else Color.WHITE);

AssignbackgroundColor(IF UPsig THEN COLOR.LIGHT_green ELSE if DNsig then color.PINK else Color.WHITE);


I named this AA-2 and put it in my watchlist set to time 1 day

input period = 10;
input smoothingPeriod = 3;
input priceChangeWeighted = YES;
DEF delta = absValue(close-close[1]);
DEF multiplier = if(priceChangeWeighted, delta,1);

DEF maxLine = 80.0;
DEF minLine = 20.0;

DEF up = if(close > close[1], volume*multiplier, 0);
DEF down = if(close < close[1], volume*multiplier, 0);
DEF upvol = sum(up, period);
DEF downvol = sum(down, period);
DEF ratio = (100.0*(upvol/(downvol+upvol)));
def UPDVR = HullMovingAvg(ratio,smoothingPeriod);

DEF lineColor = if(UPDVR >= 80.0, 6, if(UPDVR < 20.0,5,1));
DEF plotData = UPDVR;
DEF VolumeRatio = UPDVR;

DEF VolumeRatioLine = UPDVR;

PLOT UPSIG = if UPDVR crosses above 80 THEN 1 ELSE 0;
DEF DNSIG = if UPDVR crosses below 20 THEN 1 ELSE 0;

UPsig.AssignvalueColor(IF UPsig THEN COLOR.LIGHT_green ELSE if DNsig then color.PINK else Color.WHITE);

AssignbackgroundColor(IF UPsig THEN COLOR.LIGHT_green ELSE if DNsig then color.PINK else Color.WHITE);


I named this EDGE and set the time to 1 hr and put it on my watchlist.......

plot trendup = close > ExpAverage(close, 8);
trendup.AssignValueColor(if trendup then Color.UPTICK else Color.DOWNTICK);
AssignBackgroundColor(if trendup then Color.UPTICK else Color.DOWNTICK);

# CCI
def CCI = CCI(7);
def CCIup = CCI crosses above -100;
def CCIdn = CCI crosses below 100;

# MFI
def MFIup = MoneyFlowIndex(length = 1).MoneyFlowIndex crosses above 20;
def MFIdn = MoneyFlowIndex(length = 1).MoneyFlowIndex crosses below 80;

# RMI
def emaInc = ExpAverage(Max(close - close[5], 0), 2);
def emaDec = ExpAverage(Max(close[5] - close, 0), 3);
def RMI = if emaDec == 0 then 0 else 100 - 100 / (1 + emaInc / emaDec);
def RMIob = RMI >= 70;
def RMIos = RMI <= 30;

# Signals
 
The labels to turn green in both the 1 hr and 1 day I watch the 30 min chart or can even watch a 5 min chart and even when the 1 hr chart turns green go there.
 
J007RMC said:
The labels to turn green in both the 1 hr and 1 day I watch the 30 min chart or can even watch a 5 min chart and even when the 1 hr chart turns green go there.
Click to expand...
In the 3rd column, the ECART represents 3 ma's up or down.
 
J007RMC said:
The labels to turn green in both the 1 hr and 1 day I watch the 30 min chart or can even watch a 5 min chart and even when the 1 hr chart turns green go there.
Click to expand...
you meant we looking for green tickers on scan results?
Screen-Shot-2021-05-05-at-3-50-04-PM.png
 
OK, watch for strength as the greens and red show. Personally, I run a 30 min - 1 hr chart because I watch a 3 min breakout OBR You can also watch a 5min your choice really up o you but watch for the hourly min and double green 1hr-1day might be a runner.
 
kganesh1 said:
J007-Thanks , I'm able to add the labels on the watchlist now and can see the color-coding. Much appreciated. Trying to figure out the scanner link that you provided.
Click to expand...
OK, watch for strength as the greens and red show. Personally, I run a 30 min - 1 hr chart because I watch a 3 min breakout OBR You can also watch a 5min your choice really up o you but watch for the hourly min and double green 1hr-1day might be a runner.
 
Pitsypan said:
Which indicators are used to build this custom columns or what is the use of these columns when both turns green? Sorry, could not figure it out after loading the columns. Which indicators you recommend while using these columns?
Click to expand...
AA-1, AA_2 belong in the watchlist also put the ECHART in the watchlist and I use my fav tickers a shortlist of favs. A-1 is set to hourly A-2 is set to daily. For instance, if A-1 lights green then you the 1 hour has momentum ideally if A-1 and A-2 light green the stock has strong upward momentum supply/demand.
 
Last edited:
You've seen this MACD on my charts nice macd

declare lower;

input period = 10;
input smoothingPeriod = 3;
input priceChangeWeighted = YES;
def delta = absValue(close-close[1]);
def multiplier = if(priceChangeWeighted, delta,1);

plot maxLine = 80.0;
plot minLine = 20.0;
maxLine.setDefaultColor(color.BLUE);
maxLine.setLineWeight(2);
minLine.setDefaultColor(color.BLUE);
minLine.setLineWeight(2);
plot midLine = 50.0;
midLine.setDefaultColor(color.WHITE);
midLine.setLineWeight(2);

DEF up = if(close > close[1], volume*multiplier, 0);
DEF down = if(close < close[1], volume*multiplier, 0);
DEF upvol = sum(up, period);
DEF downvol = sum(down, period);
DEF ratio = (100.0*(upvol/(downvol+upvol)));
DEF UPDVR = HullMovingAvg(ratio,smoothingPeriod);

DEF lineColor = if(UPDVR >= 80.0, 6, if(UPDVR < 20.0,5,1));
DEF plotData = UPDVR;
plot VolumeRatio = UPDVR;
VolumeRatio.AssignValueColor(getColor(linecolor));
VolumeRatio.setLineWeight(3);
VolumeRatio.setPaintingStrategy(paintingStrategy.HISTOGRAM);
plot VolumeRatioLine = UPDVR;
VolumeRatioLine.AssignValueColor(getColor(if(linecolor != 1, linecolor, 9)));
VolumeRatioLine.setLineWeight(2);

#
 
Fibs display right side of the chart.

V1.0 - 12.18.2018 - BenTen - Initial release of Auto Fib, created by Ryan Hendricks
# V1.1 - 11.15.2019 - theelderwand - As the script was difficult to read, made the following enhancements
# Expands to right
# Doesn't expand to left
# Custom colors for Fibonacci bars (0.618 is GOLD color)
# Custom line weights
# Code is modularized so you can add extra plots as needed
# V1.2 - 11.15.2019 - tomsk - Added an input selector for the colors of the label. You
# can select from any of the colors listed - red, orange,
# green, etc and bubbles for all the fib retracements will
# utilize that color.
# V1.3 - 11.19.2019 - tomsk - Modified the AddChartBubbles to be displayed on the right
# side of the chart. Please ensure that you increase the
# expansion area to that the bubbles have room to be displayed
# Chart Settings > Time Axis > Expansion Area

#hint Price: Price used in the alerts on crossing retracement lines. <b>(Default is Close)</b>

#hint coefficient_0: Retracement Line 0: Retracement from the highest high to the lowest low.<b>(Default is 0%)</b>
#hint Coefficient_1: Retracement Line 1: Retracement from the highest high to the lowest low.<b>(Default is 23.6%)</b>
#hint Coefficient_2: Retracement Line 2: Retracement from the highest high to the lowest low.<b>(Default is 38.2%)</b>
#hint Coefficient_3: Retracement Line 3: Retracement from the highest high to the lowest low.<b>(Default is 50%)</b>
#hint Coefficient_4: Retracement Line 4: Retracement from the highest high to the lowest low.<b>(Default is 61.8%)</b>
#hint Coefficient_5: Retracement Line 5: Retracement from the highest high to the lowest low.<b>(Default is 78.6%)</b>
#hint Coefficient_6: Retracement Line 6: Retracement from the highest high to the lowest low.<b>(Default is 100%)</b>

#wizard input: Price
#wizard text: Inputs: Price:
#wizard input: coefficient_0
#wizard text: coefficient_0:
#wizard input: Coefficient_1
#wizard text: Coefficient_1:
#wizard input: Coefficient_2
#wizard text: Coefficient_2:
#wizard input: Coefficient_3
#wizard text: Coefficient_3:
#wizard input: Coefficient_4
#wizard text: Coefficient_4:
#wizard input: Coefficient_5
#wizard text: Coefficient_5:
#wizard input: Coefficient_6
#wizard text: Coefficient_6:

input price = close;
input high = high;
input low = low;
input coefficient_0 = 0.000;
input coefficient_1 = .236;
input Coefficient_2 = .382;
input Coefficient_3 = .500;
input Coefficient_4 = .618;
input Coefficient_5 = .786;
input Coefficient_6 = 1.000;

input LabelColor = {default "MAGENTA", "CYAN", "PINK", "LIGHT_GRAY", "ORANGE", "RED", "GREEN", "GRAY", "WHITE"};
input n = 3;

def n1 = n + 1;
def a = HighestAll(high);
def b = LowestAll(low);
def barnumber = BarNumber();
def c = if high == a then barnumber else Double.NaN;
def d = if low == b then barnumber else Double.NaN;
rec highnumber = CompoundValue(1, if IsNaN(c) then highnumber[1] else c, c);
def highnumberall = HighestAll(highnumber);
rec lownumber = CompoundValue(1, if IsNaN(d) then lownumber[1] else d, d);
def lownumberall = LowestAll(lownumber);

def upward = highnumberall > lownumberall;
def downward = highnumberall < lownumberall;

def x = AbsValue(lownumberall - highnumberall );

def slope = (a - b) / x;
def slopelow = (b - a) / x;

def day = GetDay();
def month = GetMonth();
def year = GetYear();
def lastDay = GetLastDay();
def lastmonth = GetLastMonth();
def lastyear = GetLastYear();
def isToday = If(day == lastDay and month == lastmonth and year == lastyear, 1, 0);
def istodaybarnumber = HighestAll(if isToday then barnumber else Double.NaN);
def line = b + (slope * (barnumber - lownumber));
def linelow = a + (slopelow * (barnumber - highnumber));
def currentlinelow = if barnumber <= lownumberall then linelow else Double.NaN;
def currentline = if barnumber <= highnumberall then line else Double.NaN;

plot FibFan = if downward then currentlinelow else if upward then currentline else Double.NaN;
FibFan.SetStyle(Curve.SHORT_DASH);
FibFan.AssignValueColor(Color.RED);
FibFan.HideBubble();

def range = a - b;

def value0 = range * coefficient_0;
def value1 = range * coefficient_1;
def value2 = range * Coefficient_2;
def value3 = range * Coefficient_3;
def value4 = range * Coefficient_4;
def value5 = range * Coefficient_5;
def value6 = range * Coefficient_6;

def condition1 = downward and barnumber >= highnumberall;
def condition2 = upward and barnumber >= lownumberall;

plot Retracement0 = if condition1 then HighestAll(b + value0) else if condition2 then HighestAll(a - value0) else Double.NaN;
plot Retracement1 = if condition1 then HighestAll(b + value1) else if condition2 then HighestAll(a - value1) else Double.NaN;
plot Retracement2 = if condition1 then HighestAll(b + value2) else if condition2 then HighestAll(a - value2) else Double.NaN;
plot Retracement3 = if condition1 then HighestAll(b + value3) else if condition2 then HighestAll(a - value3) else Double.NaN;
plot Retracement4 = if condition1 then HighestAll(b + value4) else if condition2 then HighestAll(a - value4) else Double.NaN;
plot Retracement5 = if condition1 then HighestAll(b + value5) else if condition2 then HighestAll(a - value5) else Double.NaN;
plot Retracement6 = if condition1 then HighestAll(b + value6) else if condition2 then HighestAll(a - value6) else Double.NaN;

Retracement0.AssignValueColor(CreateColor(255, 255, 255));
Retracement0.SetLineWeight(4);
Retracement0.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement0, Concat( (coefficient_0 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement0, Concat( (coefficient_0 * 100), "%"), GetColor(LabelColor), yes);

Retracement1.AssignValueColor(CreateColor(173, 216, 230));
Retracement1.SetLineWeight(2);
Retracement1.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement1, Concat( (coefficient_1 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement1, Concat( (coefficient_1 * 100), "%"), GetColor(LabelColor), yes);

Retracement2.AssignValueColor(CreateColor(0, 197, 49));
Retracement2.SetLineWeight(2);
Retracement2.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement2, Concat( (Coefficient_2 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement2, Concat( (Coefficient_2 * 100), "%"), GetColor(LabelColor), yes);

Retracement3.AssignValueColor(CreateColor(255, 64, 64));
Retracement3.SetLineWeight(3);
Retracement3.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement3, Concat( (Coefficient_3 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement3, Concat( (Coefficient_3 * 100), "%"), GetColor(LabelColor), yes);

Retracement4.AssignValueColor(CreateColor(255, 215, 0));
Retracement4.SetLineWeight(5);
Retracement4.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement4, Concat( (Coefficient_4 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement4, Concat( (Coefficient_4 * 100), "%"), GetColor(LabelColor), yes);

Retracement5.AssignValueColor(CreateColor(0, 255, 255));
Retracement5.SetLineWeight(2);
Retracement5.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement5, Concat( (Coefficient_5 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement5, Concat( (Coefficient_5 * 100), "%"), GetColor(LabelColor), yes);

Retracement6.AssignValueColor(CreateColor(255, 255, 255));
Retracement6.SetLineWeight(4);
Retracement6.HideBubble();
AddChartBubble((downward and close[n1]) and IsNaN(close[n]), Retracement6, Concat( (Coefficient_6 * 100), "%"), GetColor(LabelColor), yes);
AddChartBubble((upward and close[n1]) and IsNaN(close[n]), Retracement6, Concat( (Coefficient_6 * 100), "%"), GetColor(LabelColor), yes);

Alert((price crosses below Retracement0) , "Price crosses below Retracement Line 0");
Alert((price crosses above Retracement0) , "Price crosses above Retracement Line 0");
Alert((price crosses below Retracement1) , "Price crosses below Retracement Line 1");
Alert((price crosses above Retracement1) , "Price crosses above Retracement Line 1");
Alert((price crosses below Retracement2) , "Price crosses below Retracement Line 2");
Alert((price crosses above Retracement2) , "Price crosses above Retracement Line 2");
Alert((price crosses below Retracement3) , "Price crosses below Retracement Line 3");
Alert((price crosses above Retracement3) , "Price crosses above Retracement Line 3");
Alert((price crosses below Retracement4) , "Price crosses below Retracement Line 4");
Alert((price crosses above Retracement4) , "Price crosses above Retracement Line 4");
Alert((price crosses below Retracement5) , "Price crosses below Retracement Line 5");
Alert((price crosses above Retracement5) , "Price crosses above Retracement Line 5");
Alert((price crosses below Retracement6) , "Price crosses below Retracement Line 6");
Alert((price crosses above Retracement6) , "Price crosses above Retracement Line 6");
# End Auto Fib v1.3
 
And here is the code for the ECHART upper study this uses 3 moving averages a 5,10,20. I believe the credit is to Robert Payne and is now public domain.

declare upper;
input short_average = 5;
input medium_average = 10;
input long_average = 20;
input average_type = {default "SMA", "EMA"};
input showArrows = yes;

def MA1;
def MA2;
def MA3;
switch (average_type) {
case "SMA":
MA1 = Average(close, short_average);
MA2 = Average(close, medium_average);
MA3 = Average(close, long_average);
case "EMA":
MA1 = ExpAverage(close, short_average);
MA2 = ExpAverage(close, medium_average);
MA3 = ExpAverage(close, long_average);
}

# define e-signal and crossover point
def Eup = MA1 > MA2 && MA2 > MA3;
def Edn = MA1 < MA2 && MA2 < MA3;

def CrossUp = close > MA1 && Eup && !Eup[1];
def CrossDn = close < MA1 && Edn && !Edn[1];

# Define up and down signals
def higherHigh = close > Highest(Max(open, close), 3)[1];
def lowerLow = close < Lowest(Min(open, close), 3)[1];
def SignalUp = if (CrossUp && higherHigh)
then 1
else if (CrossUp[1] && higherHigh && !higherHigh[1])
then 1
else if (CrossUp[2] && higherHigh && !higherHigh[1] && !higherHigh[2])
then 1
else Double.NaN;
def SignalDn = if (CrossDn && lowerLow)
then 1
else if (CrossDn[1] && lowerLow && !lowerLow[1])
then 1
else if (CrossDn[2] && lowerLow && !lowerLow[1] && !lowerLow[2])
then 1
else Double.NaN;

# Plot the moving average lines
plot ln1 = MA1;
ln1.SetDefaultColor(CreateColor(145, 210, 144));
ln1.SetLineWeight(2);
plot ln2 = MA2;
ln2.SetDefaultColor(CreateColor(111, 183, 214));
ln2.SetLineWeight(2);
plot ln3 = MA3;
ln3.SetDefaultColor(CreateColor(249, 140, 182));
ln3.SetLineWeight(2);

# Show an arrow
plot ArrowUp = if SignalUp and showArrows then low * 0.997 else Double.NaN;
ArrowUp.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
ArrowUp.SetLineWeight(4);
ArrowUp.SetDefaultColor(Color.YELLOW);
plot ArrowDn = if SignalDn and showArrows then high * 1.003 else Double.NaN;
ArrowDn.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
ArrowDn.SetLineWeight(4);
ArrowDn.SetDefaultColor(Color.CYAN);

# Add label for Eup or Edn
AddLabel(Eup, "E Up", CreateColor(134, 202, 93));
AddLabel(Edn, "E Dn", CreateColor(232, 148, 157));

# Calculate Meter Values
def sl1 = ma1 > ma1[1];
def sl2 = ma2 > ma2[1];
def sl3 = ma3 > ma3[1];
def p1 = close > ma1;
def p2 = close > ma2;
def p3 = close > ma3;
def u1 = 2 * (close > open);
def u2 = 2 * (close > high[1]);
def d1 = 2 * (close < open);
def d2 = 2 * (close < low[1]);

def UPstr = sl1 + sl2 + sl3 + p1 + p2 + p3 + u1 + u2;
def DNstr = !sl1 + !sl2 + !sl3 + !p1 +!p2 + !p3 + d1 + d2;

# Add Strength Meter
AddLabel(Eup or Edn, " ", if Eup and UPstr >= 3 then CreateColor(128, 199, 94) else if Edn and DNstr >= 3 then CreateColor(232, 143, 153) else CreateColor(177,177,166));
AddLabel(Eup or Edn, " ", if Eup and UPstr >= 6 then CreateColor(99, 197, 72) else if Edn and DNstr >= 6 then CreateColor(238, 123, 136) else CreateColor(177,177,166));
AddLabel(Eup or Edn, " ", if Eup and UPstr >= 8 then CreateColor(65, 195, 50) else if Edn and DNstr >= 8 then CreateColor(245, 101, 117) else CreateColor(177,177,166));
AddLabel(Eup or Edn, " ", if Eup and UPstr == 10 then CreateColor(41, 192, 36) else if Edn and DNstr == 10 then CreateColor(249, 81, 101) else CreateColor(177,177,166));
 
The simple script adds bubbles to your moving averages moved 5 bars forward o not to cover the bars. I set mine to 50 and 20

input length = 50;
input AvgType = AverageType.SIMPLE;
input price = close;

plot Avg = MovingAverage(AvgType, price, length);
Avg.SetDefaultColor(Color.DARK_ORANGE);

def lastbar = IsNaN(close[-1]) and !IsNaN(close);
AddChartBubble(lastbar[-5], Avg, "MA" + length, Color.DARK_ORANGE);
 
Last edited:
Status
Not open for further replies.
Thread starter Similar threads Forum Replies Date
H I admit it- I am one of the "Takers" here at UseThinkScript Playground 0
R Daniel Shay Indicators Playground 1
I …make a Volume indicator that blows away other indicators? Playground 4
armybender Warning: Shortcomings of Trending Indicators Playground 0
Mr_Wheeler Do you have any success or failure stories regarding setting up buy or sell conditional orders based on you indicators? Playground 1

Similar threads

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
198 Online
Create Post

Similar threads

Similar threads

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support
Try VIP Club Today

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top