Repaints Enhanced Trend Reversal Indicator for ThinkorSwim

[CLICKANDGRAB808]

Scanner doesn't work

 

[XeoNoX]

you failed to state what you are trying to scan for @CLICKANDGRAB808

 

[BenTen]

@CLICKANDGRAB808 Watch the video from this thread: https://usethinkscript.com/threads/how-to-use-the-stock-hacker-in-thinkorswim.284/

When setting up your scanner, make sure to change the within X bar field to any value higher than 1 because this is a repainting indicator, the signals are delayed.

 

[aceboogie_11]

Is there anyway to make a text bubble show up instead of an arrow?

plot bull_vwap = bullish_vwap;
bull_vwap.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
bull_vwap.SetDefaultColor(Color.CYAN);
bull_vwap.SetLineWeight(2);

 

[BenTen]

@aceboogie_11 You can do that using AddChartBubble()

 

[aceboogie_11]

This is what I got i just dont know the location. def x = barnumber();

addchartbubble(x, bull_vwap, "up", color.BLUE,no);

 

[CLICKANDGRAB808]

@BenTen thank you for the replay I know to scan however TOS tells me is to complex and does not allow for bull or bear vwap or engulf arrows I hope its clear thanks for your help in advance.

@XeoNoX thank you for the replay TOS tells me is to complex and does not allow for bull or bear vwap or engulf arrows i hope its clear thanks for your help in advance

 

[BenTen]

@CLICKANDGRAB808 In that case, it looks like this indicator is incompatible with the scanner due to its complexity.

 

[csrkk]

@BenTen Can you share the latest version of this indicator that includes AMM 2.0, VWAP and Engulfing candles?

 

[BenTen]

@csrkk We no longer distribute that code because it's a repainting indicator (caused by the trend reversal indicator).

 

[csrkk]

@BenTen Thanks for your response. Any suggested Trend Reversal indicator available to replace this?

 

[BenTen]

@csrkk You can try Supertrend or Half-Trend.

 

[Dperron01]

If we are a VIP member, How do we add the AMM code to the enhanced version as you mentioned?

"One way to increase the reliability of the signals is to implement additional trend reversal patterns. Included in the Enhanced version are:

• Bullish and Bearish Engulfing candles
• VWAP
• Advanced Market Moves (will not be included in the public release due to obvious reason)"

 

[BenTen]

@Dperron01 I don't distribute that code anymore because of the repainting factor caused by the trend reversal indicator. It makes the indicator completely useless in live trading.

 

[txchopper]

Vwap_Engulfing_Algo1


def price = close;

def superfast_length = 9;

def fast_length = 14;

def slow_length = 21;

def displace = 0;


def mov_avg9 = ExpAverage(price[-displace], superfast_length);

def mov_avg14 = ExpAverage(price[-displace], fast_length);

def mov_avg21 = ExpAverage(price[-displace], slow_length);


# MAs part of Trend Reversal

def Superfast = mov_avg9;

def Fast = mov_avg14;

def Slow = mov_avg21;


def buy = mov_avg9 > mov_avg14 and mov_avg14 > mov_avg21 and low > mov_avg9;

def stopbuy = mov_avg9 <= mov_avg14;

def buynow = !buy[1] and buy;

def buysignal = CompoundValue(1, if buynow and !stopbuy then 1 else if buysignal[1] == 1 and stopbuy then 0 else buysignal[1], 0);


def Buy_Signal = buysignal[1] == 0 and buysignal == 1;

def Momentum_Down = buysignal[1] == 1 and buysignal == 0;


def sell = mov_avg9 < mov_avg14 and mov_avg14 < mov_avg21 and high < mov_avg9;

def stopsell = mov_avg9 >= mov_avg14;

def sellnow = !sell[1] and sell;

def sellsignal = CompoundValue(1, if sellnow and !stopsell then 1 else if sellsignal[1] == 1 and stopsell then 0 else sellsignal[1], 0);

def Sell_Signal = sellsignal[1] == 0 and sellsignal;


input method = {default average, high_low};

def bubbleoffset = .0005;

def percentamount = .01;

def revAmount = .05;

def atrreversal = 2.0;

def atrlength = 5;

def pricehigh = high;

def pricelow = low;

def averagelength = 5;

def averagetype = AverageType.EXPONENTIAL;

def mah = MovingAverage(averagetype, pricehigh, averagelength);

def mal = MovingAverage(averagetype, pricelow, averagelength);

def priceh = if method == method.high_low then pricehigh else mah;

def pricel = if method == method.high_low then pricelow else mal;

def EI = ZigZagHighLow("price h" = priceh, "price l" = pricel, "percentage reversal" = percentamount, "absolute reversal" = revAmount, "atr length" = atrlength, "atr reversal" = atrreversal);

rec EISave = if !IsNaN(EI) then EI else GetValue(EISave, 1);

def chg = (if EISave == priceh then priceh else pricel) - GetValue(EISave, 1);

def isUp = chg >= 0;

def EIL = if !IsNaN(EI) and !isUp then pricel else GetValue(EIL, 1);

def EIH = if !IsNaN(EI) and isUp then priceh else GetValue(EIH, 1);

def dir = CompoundValue(1, if EIL != EIL[1] or pricel == EIL[1] and pricel == EISave then 1 else if EIH != EIH[1] or priceh == EIH[1] and priceh == EISave then -1 else dir[1], 0);

def signal = CompoundValue(1, if dir > 0 and pricel > EIL then if signal[1] <= 0 then 1 else signal[1] else if dir < 0 and priceh < EIH then if signal[1] >= 0 then -1 else signal[1] else signal[1], 0);


# Define original signals

def bullish2 = signal > 0 and signal[1] <= 0;

def bearish2 = signal < 0 and signal[1] >= 0;


# VWAP

input numDevDn = -2.0;

input numDevUp = 2.0;

input timeFrame = {default DAY, WEEK, MONTH};


def cap = GetAggregationPeriod();

def errorInAggregation =

    timeFrame == timeFrame.DAY and cap >= AggregationPeriod.WEEK or

    timeFrame == timeFrame.WEEK and cap >= AggregationPeriod.MONTH;

Assert(!errorInAggregation, "timeFrame should be not less than current chart aggregation period");


def yyyyMmDd = GetYYYYMMDD();

def periodIndx;

switch (timeFrame) {

case DAY:

    periodIndx = yyyyMmDd;

case WEEK:

    periodIndx = Floor((DaysFromDate(First(yyyyMmDd)) + GetDayOfWeek(First(yyyyMmDd))) / 7);

case MONTH:

    periodIndx = RoundDown(yyyyMmDd / 100, 0);

}

def isPeriodRolled = CompoundValue(1, periodIndx != periodIndx[1], yes);


def volumeSum;

def volumeVwapSum;

def volumeVwap2Sum;


if (isPeriodRolled) {

    volumeSum = volume;

    volumeVwapSum = volume * vwap;

    volumeVwap2Sum = volume * Sqr(vwap);

} else {

    volumeSum = CompoundValue(1, volumeSum[1] + volume, volume);

    volumeVwapSum = CompoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);

    volumeVwap2Sum = CompoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));

}

def priceVWAP = volumeVwapSum / volumeSum;

def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(priceVWAP), 0));


def VWAP = priceVWAP;

#plot UpperBand = priceVWAP + numDevUp * deviation;

#plot LowerBand = priceVWAP + numDevDn * deviation;

def UpVWAP = price > VWAP;

def DownVWAP = price < VWAP;


# Engulfing Candles. Snippets from @ConfluenceCptl

def BodyMax = Max(open, close);

def BodyMin = Min(open, close);

def IsEngulfing = BodyMax > BodyMax[1] and

BodyMin < BodyMin[1];


# Define Signals with VWAP

def bullish_vwap = UpVWAP and bullish2;

def bearish_vwap = DownVWAP and bearish2;


# Plot Signals with VWAP

plot bull_vwap = bullish_vwap;

bull_vwap.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);

bull_vwap.SetDefaultColor(Color.CYAN);

bull_vwap.SetLineWeight(2);

plot bear_vwap = bearish_vwap;

bear_vwap.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

bear_vwap.SetDefaultColor(Color.CYAN);

bear_vwap.SetLineWeight(2);


# Define Signals with Engulfing Candles

def bullish_engulf = bullish2 and Isengulfing and close > open;

def bearish_engulf = bearish2 and Isengulfing and close < open;


# Plot Signals with Engulfing Candles

plot bull_engulf = bullish_engulf;

bull_engulf.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);

bull_engulf.SetDefaultColor(Color.WHITE);

bull_engulf.SetLineWeight(2);

plot bear_engulf = bearish_engulf;

bear_engulf.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

bear_engulf.SetDefaultColor(Color.WHITE);

bear_engulf.SetLineWeight(2);


AddLabel(yes,"Signals w/ VWAP",color.CYAN);

AddLabel(yes,"Signals w/ Engulfing",color.WHITE);


# Configurations

input bEngulf = yes;

input sEngulf = yes;

input bVWAP = yes;

input sVWAP = yes;

bull_engulf.SetHiding(!bEngulf);

bear_engulf.SetHiding(!sEngulf);

bull_vwap.SetHiding(!bVWAP);

bear_vwap.SetHiding(!sVWAP);

 

[generic]

@txchopper Add this to the bottom of the code. You can also split it into 4 different Alerts if you want by copy and paste and removing 3 of the 4 conditions.

Alert(bull_engulf or bull_vwap or bear_engulf or bear_vwap, "", Alert.BAR, Sound.Chimes);

 

[BenTen]

@txchopper That is the indicator we posted on the first page of this thread and it's going to repaint.

 

[txchopper]

@generic Pasted the code of the Alert above it did not alert. tried numerous stocks that the arrows alert as Bullish engulfing and it was a no go.

 

[BenTen]

@txchopper Probably not going to work due to the lagging/repainting factor of the trend reversal indicator.

 

[txchopper]

I thought it was because I'm using the script on 5min 10 min 15 min time frame and the script is wrote only for Day Week and Monthly Time frames. but your probably right