Repaints Enhanced Trend Reversal Indicator for ThinkorSwim

[kingover]

@KennyN You did nothing wrong. It's because this is a re-painting/delaying indicator, the alerts may not be able to work properly.

Is there anyway we can change the delaying part for the alerts to work?
How about the AddOrder function? Is that going to be executed (if added) exactly when reversal is happening?

Thanks

 

[MerryDay]

Is there anyway we can change the delaying part for the alerts to work?
How about the AddOrder function? Is that going to be executed (if added) exactly when reversal is happening?

Thanks

It is a repainting indicator as a result the alerts may not be able to work properly

mod note:
This is a repainting indicator.
Backtesting of strategies that repaint have no value because all the intermittent signals were erased.
Because the results are not realistic, we ask that repainting strategies not be posted to the forum.

 

[Roho23]

@BenTen just wondering if you're still using the enhanced reversal script for TOS. I just downloaded it today to review it and noticed
that it didn't paint any arrows for today at all. Today there was a pretty hard reversal intraday. Just wondering why you think this is. As I see it
it should or could have painted a couple of reversal throughout today. thanks for all you do BenTen.

 

[wshao8]

Here is the Enhanced version of the popular Trend Reversal indicator available here for ThinkorSwim.

Before we jump into what's new, I just want to clarify that the new version will continue to repaint. Repainting was the problem with the original Trend Reversal. Though there is no way to fix that issue, we continue to find ways to improve it.

One way to increase the reliability of the signals is to implement additional trend reversal patterns. Included in the Enhanced version are:

• Bullish and Bearish Engulfing candles
• VWAP
• Advanced Market Moves (will not be included in the public release due to obvious reason)

Here’s How it Works:

From now on, the Trend Reversal Signals will only appear on your chart if it fits the following requirement:

The reversal candle (pulled from the original version) must either be an Engulfing candle, below/above VWAP, or matches with the signal given by the Advanced Market Moves.

We assume that if any of the three conditions match up in a single candle, most likely there would be a point of reversal in trend. Of course, since this indicator repaint, it’s impossible to backtest. Hopefully, this Enhanced version will work better since additional conditions have been added.

thinkScript Code

# Enhanced Trend Reversal Indicator with Signals
# Added VWAP and Engulfing Candles
# Assembled by BenTen at useThinkScript.com
# Original developer: Bayside of Enhanced Investor
# Original version: https://usethinkscript.com/threads/trend-reversal-indicator-with-signals-for-thinkorswim.183/
# Version 1.0 (read changelog in forum)

def price = close;
def superfast_length = 9;
def fast_length = 14;
def slow_length = 21;
def displace = 0;

def mov_avg9 = ExpAverage(price[-displace], superfast_length);
def mov_avg14 = ExpAverage(price[-displace], fast_length);
def mov_avg21 = ExpAverage(price[-displace], slow_length);

# MAs part of Trend Reversal
def Superfast = mov_avg9;
def Fast = mov_avg14;
def Slow = mov_avg21;

def buy = mov_avg9 > mov_avg14 and mov_avg14 > mov_avg21 and low > mov_avg9;
def stopbuy = mov_avg9 <= mov_avg14;
def buynow = !buy[1] and buy;
def buysignal = CompoundValue(1, if buynow and !stopbuy then 1 else if buysignal[1] == 1 and stopbuy then 0 else buysignal[1], 0);

def Buy_Signal = buysignal[1] == 0 and buysignal == 1;
def Momentum_Down = buysignal[1] == 1 and buysignal == 0;

def sell = mov_avg9 < mov_avg14 and mov_avg14 < mov_avg21 and high < mov_avg9;
def stopsell = mov_avg9 >= mov_avg14;
def sellnow = !sell[1] and sell;
def sellsignal = CompoundValue(1, if sellnow and !stopsell then 1 else if sellsignal[1] == 1 and stopsell then 0 else sellsignal[1], 0);
def Sell_Signal = sellsignal[1] == 0 and sellsignal;

input method = {default average, high_low};
def bubbleoffset = .0005;
def percentamount = .01;
def revAmount = .05;
def atrreversal = 2.0;
def atrlength = 5;
def pricehigh = high;
def pricelow = low;
def averagelength = 5;
def averagetype = AverageType.EXPONENTIAL;
def mah = MovingAverage(averagetype, pricehigh, averagelength);
def mal = MovingAverage(averagetype, pricelow, averagelength);
def priceh = if method == method.high_low then pricehigh else mah;
def pricel = if method == method.high_low then pricelow else mal;
def EI = ZigZagHighLow("price h" = priceh, "price l" = pricel, "percentage reversal" = percentamount, "absolute reversal" = revAmount, "atr length" = atrlength, "atr reversal" = atrreversal);
rec EISave = if !IsNaN(EI) then EI else GetValue(EISave, 1);
def chg = (if EISave == priceh then priceh else pricel) - GetValue(EISave, 1);
def isUp = chg >= 0;
def EIL = if !IsNaN(EI) and !isUp then pricel else GetValue(EIL, 1);
def EIH = if !IsNaN(EI) and isUp then priceh else GetValue(EIH, 1);
def dir = CompoundValue(1, if EIL != EIL[1] or pricel == EIL[1] and pricel == EISave then 1 else if EIH != EIH[1] or priceh == EIH[1] and priceh == EISave then -1 else dir[1], 0);
def signal = CompoundValue(1, if dir > 0 and pricel > EIL then if signal[1] <= 0 then 1 else signal[1] else if dir < 0 and priceh < EIH then if signal[1] >= 0 then -1 else signal[1] else signal[1], 0);

# Define original signals
def bullish2 = signal > 0 and signal[1] <= 0;
def bearish2 = signal < 0 and signal[1] >= 0;

# VWAP
input numDevDn = -2.0;
input numDevUp = 2.0;
input timeFrame = {default DAY, WEEK, MONTH};

def cap = GetAggregationPeriod();
def errorInAggregation =
    timeFrame == timeFrame.DAY and cap >= AggregationPeriod.WEEK or
    timeFrame == timeFrame.WEEK and cap >= AggregationPeriod.MONTH;
Assert(!errorInAggregation, "timeFrame should be not less than current chart aggregation period");

def yyyyMmDd = GetYYYYMMDD();
def periodIndx;
switch (timeFrame) {
case DAY:
    periodIndx = yyyyMmDd;
case WEEK:
    periodIndx = Floor((DaysFromDate(First(yyyyMmDd)) + GetDayOfWeek(First(yyyyMmDd))) / 7);
case MONTH:
    periodIndx = RoundDown(yyyyMmDd / 100, 0);
}
def isPeriodRolled = CompoundValue(1, periodIndx != periodIndx[1], yes);

def volumeSum;
def volumeVwapSum;
def volumeVwap2Sum;

if (isPeriodRolled) {
    volumeSum = volume;
    volumeVwapSum = volume * vwap;
    volumeVwap2Sum = volume * Sqr(vwap);
} else {
    volumeSum = CompoundValue(1, volumeSum[1] + volume, volume);
    volumeVwapSum = CompoundValue(1, volumeVwapSum[1] + volume * vwap, volume * vwap);
    volumeVwap2Sum = CompoundValue(1, volumeVwap2Sum[1] + volume * Sqr(vwap), volume * Sqr(vwap));
}
def priceVWAP = volumeVwapSum / volumeSum;
def deviation = Sqrt(Max(volumeVwap2Sum / volumeSum - Sqr(priceVWAP), 0));

def VWAP = priceVWAP;
#plot UpperBand = priceVWAP + numDevUp * deviation;
#plot LowerBand = priceVWAP + numDevDn * deviation;
def UpVWAP = price > VWAP;
def DownVWAP = price < VWAP;

# Engulfing Candles. Snippets from @ConfluenceCptl
def BodyMax = Max(open, close);
def BodyMin = Min(open, close);
def IsEngulfing = BodyMax > BodyMax[1] and
BodyMin < BodyMin[1];

# Define Signals with VWAP
def bullish_vwap = UpVWAP and bullish2;
def bearish_vwap = DownVWAP and bearish2;

# Plot Signals with VWAP
plot bull_vwap = bullish_vwap;
bull_vwap.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
bull_vwap.SetDefaultColor(Color.CYAN);
bull_vwap.SetLineWeight(2);
plot bear_vwap = bearish_vwap;
bear_vwap.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
bear_vwap.SetDefaultColor(Color.CYAN);
bear_vwap.SetLineWeight(2);

# Define Signals with Engulfing Candles
def bullish_engulf = bullish2 and Isengulfing and close > open;
def bearish_engulf = bearish2 and Isengulfing and close < open;

# Plot Signals with Engulfing Candles
plot bull_engulf = bullish_engulf;
bull_engulf.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
bull_engulf.SetDefaultColor(Color.WHITE);
bull_engulf.SetLineWeight(2);
plot bear_engulf = bearish_engulf;
bear_engulf.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
bear_engulf.SetDefaultColor(Color.WHITE);
bear_engulf.SetLineWeight(2);

AddLabel(yes,"Signals w/ VWAP",color.CYAN);
AddLabel(yes,"Signals w/ Engulfing",color.WHITE);

# Configurations
input bEngulf = yes;
input sEngulf = yes;
input bVWAP = yes;
input sVWAP = yes;
bull_engulf.SetHiding(!bEngulf);
bear_engulf.SetHiding(!sEngulf);
bull_vwap.SetHiding(!bVWAP);
bear_vwap.SetHiding(!sVWAP);

Shareable Link: https://tos.mx/1we0QW

Configurations

There will be a lot of signals on your chart, however, I have color-coded them. You can also disable any type of arrows right from the indicator’s settings page. You don’t have to edit anything in the source code.

Changelog

Feel free to test it out and let me know. I heard a lot of positive feedback from members using the original version.

Video Tutorial

what is Advanced Market Moves?

 

[MerryDay]

what is Advanced Market Moves?

https://usethinkscript.com/threads/advanced-market-moves-2-0-released.1797/

 

[wshao8]

https://usethinkscript.com/threads/advanced-market-moves-2-0-released.1797/

Looks very useful. After I upgraded to VIP member, so, I can load this script into my TOS system? Is the script encrypted that I have to do something extra to use it, or it is just like other script for personal use?

 

[MerryDay]

Looks very useful. After I upgraded to VIP member, so, I can load this script into my TOS system? Is the script encrypted that I have to do something extra to use it, or it is just like other script for personal use?

• Yes, VIP members can load the AMM2 script to their ToS app
• No, the script is not encrypted
• Nothing extra has to be done to cut & paste the study.
• Yes, it is just like any other script for personal use.

 

[CloverCapital]

@MerryDay For premium members how can the we incorporate the Advanced Market Moves 2 into the Reversal script as the original developer indicated? He did not post it to the public forum for obvious reasons, but how can VIP Members access it or add it?

 

[MerryDay]

@MerryDay For premium members how can the we incorporate the Advanced Market Moves 2 into the Reversal script as the original developer indicated? He did not post it to the public forum for obvious reasons, but how can VIP Members access it or add it?

The reversal script was abandoned as a companion to AMM2 because the repainting issues can not be overcome.

 

[iMauiC]

@BenTen , I am trying to place this code in the Enhanced Trend post #83 or #87 of this thread,....I cannot figure out why I am not successful? or Anyone who can assist.....the "colorbars," were generating errors....

def revLineTop;
def revLineBot;

if barnumber and D1 {
revLineBot = Double.NaN;
revLineTop = high[1];
} else if barnumber and U1 {
revLineTop = Double.NaN;
revLineBot = low[1];
} else if !IsNaN(revLineBot[1]) and (Colorbars[2] == 2 or Colorbars[1] == 2) {
revLineBot = revLineBot[1];
revLineTop = Double.NaN;
} else if !IsNaN(revLineTop[1]) and (Colorbars[2] == 1 or Colorbars[1] == 1) {
revLineTop = revLineTop[1];
revLineBot = Double.NaN;
} else {
revLineTop = Double.NaN;
revLineBot = Double.NaN;
}

plot botLine = revLineBot[-1];
botLine.SetDefaultColor(Color.GREEN);
plot topLine = revLineTop[-1];
topLine.SetDefaultColor(Color.RED);

Did a little copying and pasting from the old trend reversal indicator to pop those lines up. Took a little bit of reverse engineering, but i hope this helps. https://tos.mx/wmbJBTJ.

 

[iMauiC]

Great indicator by the way! Having the reversal line sure comes in handy on the Option Charts as a Stop Loss level when entering long/naked contracts.

 

[lalkattil]

@anty That's correct.

Why ot is not working on SPX???
. It's working on every other stocks.

 

[MerryDay]

Why ot is not working on SPX???
. It's working on every other stocks.

This script includes a VWAP calculation. The V in VWAP stands for VOLUME.
SPX is an index, it doesn't have volume.
You can not use any scripts that contain volume calculations with the SPX

 

[Nsureman65]

@KevinSammy That's correct. The regular version which is included in this post will only include the trend reversal with VWAP and Engulfing candles.

Where can I find the version

@KevinSammy That's correct. The regular version which is included in this post will only include the trend reversal with VWAP and Engulfing candles.

where can I find this trend reversal with the “advanced market moves” included?

 

[MerryDay]

Where can I find the version

where can I find this trend reversal with the “advanced market moves” included?

No, there is no repainting VIP Trend Reversal Indicators.
VIP does not encourage their use.

But yes, there is a VIP Advance Market Moves Indicator:
https://usethinkscript.com/threads/understanding-the-amm-2-0-signals.1831/
https://usethinkscript.com/threads/getting-started-with-the-advanced-market-moves-2-0.1795/
https://usethinkscript.com/threads/download-advanced-market-moves-2-0.4733/
It does not repaint.

 

[Joshuam3194]

@MerryDay Is there still no way for this indicator or parts of it to work in a scanner?

 

[MerryDay]

@js3256 @ClintC06 @Joshuam3194
The enhanced Trend Reversal throws a too complicated error in the Scan Hacker

 

[Joshuam3194]

@js3256 @ClintC06 @Joshuam3194
The enhanced Trend Reversal throws a too complicated error in the Scan Hacker

And we can't set alerts for bullish VWAP signal on the daily time frame?

 

[MerryDay]

And we can't set alerts for bullish VWAP signal on the daily time frame?

https://usethinkscript.com/threads/...dicator-for-thinkorswim.393/page-5#post-60701

 

[adamdesigns3d]

By far this is the best indicator I have been using for the last 3 years, thanks!
Combining it with sequence counter (DeMarks) is even better with a higher success rate.
Can you add a little extra code that adds an extra arrow on top or bottom of the "repaint" arrows that stays there permanently even if the repaint one vanishes? other solutions were to take a screen shot every time a repaint arrow shows up.. but that's tedious.
I would like to have that history to study it and find other indicators to explain or avoid falling for the reversal.