Three Different ADSPD Adv/Dec Codes to Try Out

markos

markos

Well-known member
VIP
From TSL - Mobius posted 7-16-2019
# 10:11 Mobius: AD is an Intraday indicator. It's daily closing value isn't of any value since where it closes in relation to the closing price has no correlation

Code # 1 of 3

# 10:14 Mobius: here is an AD label that includes the open, high and low of the day with bubbles plotted at those price locations on the chart.

Code:
# AD Label
# Mobius
# V01

def RTH = getTime() >= regularTradingStart(getYYYYMMDD()) and
          getTime() <= regularTradingEnd(getYYYYMMDD());

def o = if RTH and !RTH[1]
        then open("$ADSPD")
        else o[1];

def c = if isNaN(close("$ADSPD"))
        then c[1]
        else close("$ADSPD");

def x = barNumber();
def sumx = if RTH and !RTH[1]
            then 1
            else if RTH then sumx[1] + 1
            else if !RTH
            then sumx[1]
            else sumx[1];

def sumAD = if RTH and !RTH[1]
            then c
            else if RTH
            then sumAD[1] + c
            else sumAD[1];

def h = if isNaN(high("$ADSPD", "DAY"))
        then h[1]
        else high("$ADSPD", "DAY");

def ADHighBar = if high("$ADSPD") == h
                  then x
                  else double.nan;

AddChartBubble(barNumber() == HighestAll(ADHighBar),
               high + (2 * TickSize()),
               "AD",
               color.cyan);        

def l = if isNaN(low("$ADSPD", "DAY"))
        then l[1]
        else low("$ADSPD", "DAY");

def ADLowBar = if low("$ADSPD") == l
                  then x
                  else double.nan;

AddChartBubble(barNumber() == HighestAll(ADLowBar),
               low - (2 * TickSize()),
               "AD",
               color.orange,
               no);

def Avg = Round(sumAD / sumx, 0);

addLabel(1, "AD open " + o +

          "  high " + h +

          "  low " + l +

          "  close " + c +

          "  Avg " + Avg, if c < 0

                              then color.red

                              else color.green);

# End Code AD Label

Code # 2 of 3

#10:18 Mobius: Here's AD Scaled to Price and plotted along with a plot of the AD zero line at price where crosses. Which is often a price pivot area.
Code:
# AD Scaled To Price
# Mobius
# Changed original code to use RegularTrading(Start, End) functions. Use RTH Only.
# V02 2019

script Scale {

    input h = high;
    input l = low;
    input c = close;
    def RTH = getTime() >= RegularTradingStart(getYYYYMMDD()) and
              getTime() <= RegularTradingEnd(getYYYYMMDD());
    def max = if RTH and !RTH[1]
              then high
              else if RTH and high > max[1]
              then high
              else max[1];
    def min = if RTH and !RTH[1]
              then low
              else if RTH and low < min[1]
              then low
              else min[1];
    def hh = if RTH and !RTH[1]
             then h
             else if RTH and h > hh[1]
             then h
             else hh[1];
     def ll = if RTH and !RTH[1]
              then l
              else if RTH and l < ll[1]
              then l
              else ll[1];
    plot Range = (((Max - Min) * (c - ll)) /  (hh - ll)) + Min;

}

plot Scaled_Symbol = scale(high("$ADSPD"), low("$ADSPD"), close("$ADSPD"));
     Scaled_Symbol.AssignValueColor(if Scaled_Symbol > Scaled_Symbol[1]
                                    then color.green
                                    else color.red);
     Scaled_Symbol.SetLineWeight(2);
     Scaled_Symbol.HideBubble();
     Scaled_Symbol.HideTitle();

def zero = if close("$ADSPD") crosses 0
           then close
           else zero[1];
def zero_bar = if close("$ADSPD") crosses 0
               then barNumber()
               else double.nan;

plot zeroLine = if barNumber() >= highestAll(zero_bar)
                then highestAll(if isNaN(close[-1])
                                then zero
                                else double.nan)
                else double.nan;
     zeroLine.SetDefaultColor(Color.Light_Gray);
     zeroLine.SetStyle(Curve.Points);
     zeroLine.SetLineWeight(2);
     zeroLine.HideBubble();
     zeroLine.HideTitle();

AddChartBubble(barNumber() == HighestAll(barNumber()),
               zeroLine,
               "AD 0",
               zeroLine.TakeValueColor());

# End Code
#10:22 MTS1: Thanks Mobius!
#10:26 binh4984: Thank you very much Mobius for your help.
#10:33 Mobius: yw And, bin... you might consider the fact that AD is an oscillator that ranges around 0. So taking a daily average of it's closing value would be that same as taking the daily closing average of any oscillator
#10:35 Mobius: won't tell you anything of value. Now you could write a binary momentum indicator using AD on a daily basis that would tell you when a trend is in place and the momentum of that trend
#10:36 Mobius: See the True Momentum Indicator for a method to do that and adding a weight adjusted by the closing value of AD might be useful
#10:37 MTS1: I guess an average on a cumulative AD could be some sort of signal line. I know some analysts look at longer term MI's like that, also # stocks above or below an MA, new highs/lows etc. But I think AD / VOLD etc are probably more useful intraday.

(I would not endorse #3 of 3 as I don't see it's utility: markos)

Code #3 of 3

Code:
#10:42 Mobius:
# Cumulative AD

declare lower;
plot Data = TotalSum(close("$ADSPD"));
plot "0" = 0;

#EOC#
 
Last edited:
T

tomsk

Well-known member
VIP
@markos Without a doubt, your posted code #1 is always on my charts whenever I trade. I know the forum participants would find this a very helpful tool!
 
S

San

Member
2019 Donor
@markos/ @tomsk, Thanks for sharing valuable information and your supports...
 
markos

markos

Well-known member
VIP
Yup @tomsk I don't know how a day trader can operate without it. Knowing the daily bias is important to know whether to work the put or call side.
 
T

Trading51

Active member
2019 Donor
Yup @tomsk I don't know how a day trader can operate without it. Knowing the daily bias is important to know whether to work the put or call side.
Are there any other posts about this that I could read up on to better understand what this is saying? thanks

How would i read that ?

 
Last edited by a moderator:
T

tomsk

Well-known member
VIP
@Trading51 The important takeaway for you is that always pay attention to the market. Index component stocks are essentially "pawns". If the market is bearish, most index component stocks get bought up while if the scenario is bearish, most index component stocks get sold down.
 
T

Trading51

Active member
2019 Donor
Building it out



@markos any other insight that you could add thanks
 
markos

markos

Well-known member
VIP
@Trading51 There are a pile of market internals. Don't get hung up, keep it simple. ADSPD is the Daily Advance Decline Line for the S&P 500.
In the pic above, both the green and white label shows that there are currently 89 more stocks up than down. In the white label 'close' is the current price so that also says 89.

Why the high and low of the Green Label vs the Highest and lowest of the White Label are different because of the math in the codes. I won't take the time to figure it out as I use a simple label that just shows the current ADSPD, I don't day trade. It's up to you to decide which way to go.

If it shows a current level of 400, then 400 of the 500 S&P 500 stocks are currently up. If your position is moving down, there may OR may not be a reason.

Intraday price movement is considered random, keep that in mind.
 
markos

markos

Well-known member
VIP
@tomsk I got this from the TSL. Why might Mobius use aggWK on a daily chart? This is what I have on my chart.
Code:
# AD Label
# Mobius
# Chat Room Request 04.26.2016

input SYMB = "$ADSPD";

def Data = close(symbol = "$ADSPD", period = AggregationPeriod.WEEK);
addLabel(1, "AD = " + Data, if Data < 0
then color.red
else color.green);
# End Code
 
T

tomsk

Well-known member
VIP
@markos I just checked my files, not sure where you obtained your study from - directly from the chat or from JQ's archives or from somewhere else. Perhaps someone was playing with it and forgot to reset it. Even some of the variable names seem to be different. Here's what I have on mine, directly from the chat archives from 2016

Code:
# AD Label
# Mobius
# Chat Room Request 04.26.2016

input SYMB = "$ADSPD";

def AD = close(symbol = SYMB, period = AggregationPeriod.Day);
addLabel(1, "AD = " + AD, if AD < 0 then Color.RED else Color.GREEN);
# End Code
 
T

Trading51

Active member
2019 Donor
@Trading51 There are a pile of market internals. Don't get hung up, keep it simple. ADSPD is the Daily Advance Decline Line for the S&P 500.
In the pic above, both the green and white label shows that there are currently 89 more stocks up than down. In the white label 'close' is the current price so that also says 89.

Why the high and low of the Green Label vs the Highest and lowest of the White Label are different because of the math in the codes. I won't take the time to figure it out as I use a simple label that just shows the current ADSPD, I don't day trade. It's up to you to decide which way to go.

If it shows a current level of 400, then 400 of the 500 S&P 500 stocks are currently up. If your position is moving down, there may OR may not be a reason.

Intraday price movement is considered random, keep that in mind.
Thank you!
 
T

tomsk

Well-known member
VIP
Not sure why you would have problems accessing it - perhaps @BenTen could have a look at it?
 
markos

markos

Well-known member
VIP
@tomsk Thanks for checking your archives. I don't know where I got it.
Maybe JQ's or UTC's OneNotes or StanL's Treepad files. Not sure, but thanks for straightening that out!
 
BenTen

BenTen

Administrative
Staff
VIP
@tomsk @San I see what happen. That link is only viewable for Warehouse members.
 
T

tomsk

Well-known member
VIP
@tomsk @San I see what happen. That link is only viewable for Warehouse members.

@BenTen Thanks for catching that fine detail. Since market internals is an integral piece of the trading journey, I'll rehash what I mentioned earlier for benefit of @San Much obliged for clearing that one up!

@San There are a group of ticker symbols that measure the underlying sentiment and health of the financial markets. Collectively these are known as market internals. Here is an analogy. If you are a pilot of a commercial jet airliner or even a captain of a passenger cruise liner, you absolutely need to have instrumentation to tell you the speed and other factors that help you make decisions for the duration of your journey so that your passengers remain safe on board. In a similar fashion, market internals gives traders information about the underlying state of the market, when it is safe to wander out and when it is best to stay defensive when trading the markets.

I found a relatively easy article on the Internet for beginners to understand market internals. It has easy to understand examples. Please note that there are a lot more that the article does not discuss but this should be sufficient to get you started in understanding the concept. Stay safe out there!

https://www.traderslog.com/market-internals
 

Similar threads

Top