PPO (Price Percent Oscillator) for ThinkorSwim

[thedoc556]

This script for ToS was created by Mobius.

thinkScript Code

# PPO
# Mobius
# V01.03.2014

declare lower;

input c = close;
input AvgType = AverageType.Simple;
input nFast = 8;
input nSlow = 13;
input nSmooth = 5;

plot PPO = ((MovingAverage(AverageType = AvgType, c, nFast) -
             MovingAverage(AverageType = AvgType, c, nSlow)) /
             MovingAverage(AverageType = AvgType, c, nSlow));
PPO.SetPaintingStrategy(PaintingStrategy.Histogram);
PPO.AssignValueColor(if PPO > 0
                     then color.green
                     else color.red);

plot smooth = MovingAverage(AverageType = AvgType, PPO, nSmooth);
smooth.SetPaintingStrategy(PaintingStrategy.Line);
smooth.SetDefaultColor(Color.Cyan);
# End Code PPO

Shareable Link

https://tos.mx/hv8hVf

Thank you very much for your help. Stay safe

 

[thedoc556]

@thedoc556
Here is an example of when PPO crosses above 0 to begin trend.
You can change the middle column to greater than, less than, crosses below, etc...
You can change the right column to any value
Shared Scan Link: http://tos.mx/7tShl17 Click here for --> Easiest way to load shared links

View attachment 1037

Thank you very much for your help. Stay safe

 

[JRAY]

@grasshopper123 @wpwright I did was a simple google search, I am assuming that you did also and already saw this Easycator PPO w/ fast and slow lines and it wasn't what you wanted.

However here it is for anyone in the future that has this request:

#
# TD Ameritrade IP Company, Inc. (c) 2007-2016
#
## created by North Vanhooser

declare lower;

input fastPeriod   = 12;
input slowPeriod   = 26;
input signalPeriod = 9;
input price        = close;

def fastEma   = ExpAverage( price, fastPeriod );
def slowEma   = ExpAverage( price, slowPeriod );
def periodOK  = fastPeriod < slowPeriod;
AddLabel( !periodOK, "ERROR: fastPeriod MUST be less than slowPeriod" );
def _ppo      = if periodOK then ((fastEma - slowEma) / slowEma) * 100 else 0;
def _signal   = ExpAverage( _ppo, signalPeriod );

plot Ppo      = _ppo;
Ppo.SetDefaultColor( Color.BLUE );
Ppo.HideBubble();

plot PpoEma   = _signal;
PpoEma.SetDefaultColor( Color.CYAN );
PpoEma.HideBubble();

plot zeroLine = 0;
zeroLine.HideBubble();
zeroLine.AssignValueColor( Color.BLACK );

plot PpoH1    = _ppo - _signal;
PpoH1.SetPaintingStrategy( PaintingStrategy.HISTOGRAM );
PpoH1.DefineColor("Up", Color.UPTICK);
PpoH1.DefineColor("Down", Color.DOWNTICK);
PpoH1.DefineColor("Flat", Color.GRAY);
PpoH1.AssignValueColor( if PpoH1 > PpoH1[1] then
                           PpoH1.Color("Up")
                       else
                         if PpoH1 < PpoH1[1] then
                           PpoH1.Color("Down")
                       else
                           PpoH1.Color("Flat"));
PpoH1.HideBubble();
PpoH1.SetLineWeight( 3 );

View attachment 2001

Here is the shared link: http://tos.mx/zQ6P90

Thanks for sharing. Is it possible to add bullish/bearish arrows each time PPO (1) crosses above/below EMA (2) or when PPOH1 changes color from Down to UP (bullish) or from UP to Down (Bearish)? essentially , there will be two different set of arrows. (PPO/EMA) and PPOH1 UP/DOWN color change. Thanks again. Here is the shared link that indicator: http://tos.mx/zQ6P90

 

[csricksdds]

The Percentage Price Oscillator (PPO) is similar to Moving Average Convergence Divergence (MACD).
They are both momentum indicators used to gauge the strength and direction of a trend in a stock's price. Many times, they present with the same signals.

The PPO is considered superior in that the PPO is expressed as a percentage, making it easier to compare across different stocks and timeframes. Whereas the MACD has little comparitive value.

View attachment 5664

This script for ToS was created by Mobius.

thinkScript Code

# PPO
# Mobius
# V01.03.2014

declare lower;

input c = close;
input AvgType = AverageType.Simple;
input nFast = 8;
input nSlow = 13;
input nSmooth = 5;

plot PPO = ((MovingAverage(AverageType = AvgType, c, nFast) -
             MovingAverage(AverageType = AvgType, c, nSlow)) /
             MovingAverage(AverageType = AvgType, c, nSlow));
PPO.SetPaintingStrategy(PaintingStrategy.Histogram);
PPO.AssignValueColor(if PPO > 0
                     then color.green
                     else color.red);

plot smooth = MovingAverage(AverageType = AvgType, PPO, nSmooth);
smooth.SetPaintingStrategy(PaintingStrategy.Line);
smooth.SetDefaultColor(Color.Cyan);
# End Code PPO

Shareable Link

https://tos.mx/hv8hVf

Nice oscillator

 

[LetsMakeMoney]

The idea here is that while the stocks may have greatly different prices, the percentage difference between the averages are comparable. A 5% spread between the 12 and 26 ema is the same relative difference by percentage, regardless of the price differences between stocks.

My intent is to do away with the problem of trying to compare the MACD of different stocks that have widely different price levels.

So I converted the difference between the fast and slow ema into a percentage difference.

Here's my script...

declare lower;

input FastLength = 12; # Faster of the two moving averages
input SlowLength = 26; # Slower of the two moving averages
input FastAvgSmoothingLength = 9;
input FastEMA_Length = 8;
def FastEMAavg = ExpAverage(close,FastEMA_Length);
def P1L = 1;
def PP5L = 0.5;
def ZL = 0;
def MP5L = -0.5;
def M1L = -1;
def SlowAvg = ExpAverage(close,SlowLength); # ema of the slow moving average
def FastAvg = ExpAverage(close,FastLength); # ema of the fast moving average
plot FastSlowPctDiff = ((FastAvg-SlowAvg)/SlowAvg) * 100; # Percent difference between FastAvg and SlowAvg
def FastPctDiff = ((FastAvg - FastAvg[1])/FastAvg[1]) * 100; # Percent difference betwee current and previous bar
plot FastPctDiffAvg = ExpAverage(FastPctDiff,FastAvgSmoothingLength);
FastPctDiffAvg.SetDefaultColor(color.cyan);
def PDGTP = if FastSlowPctDiff > FastSlowPctDiff[1] then 1 else 0;
def PDLTP = if FastSlowPctDiff < FastSlowPctDiff[1] then 1 else 0;
FastSlowPctDiff.AssignValueColor(if PDGTP then Color.GREEN else if PDLTP then Color.RED else Color.YELLOW);
FastSlowPctDiff.SetLineWeight(2);
plot ZLine = ZL;
ZLine.SetDefaultColor(Color.white);
plot P1Line = P1L;
P1Line.SetDefaultColor(color.green);
Plot M1Line = M1L;
M1Line.SetDefaultColor(color.red);
Plot PP5Line = PP5L;
PP5Line.SetDefaultColor(Color.yellow);
PP5Line.SetPaintingStrategy(PaintingStrategy.DASHES);
Plot MP5Line = MP5L;
MP5Line.SetDefaultColor(color.yellow);
MP5Line.SetPaintingStrategy(PaintingStrategy.DASHES);
plot FastEMAImproving = if FastEMAavg > FastEMAavg[1] then 1 else 0;
FastEMAImproving.Hide();
AddLabel(yes,FastEMA_Length + " EMA Improving", if FastEMAImproving then color.green else if FastEMAavg == FastEMAavg[1]  then color.gray else color.red);
AddLabel(yes,FastLength + " EMA Improving",if FastAvg > FastAvg[1] then color.green else color.red);
def BullConditionGo = if FastPctDiffAvg > FastPctDiffAvg[1] and FastSlowPctDiff > FastSlowPctDiff[1] and FastAvg > FastAvg[1] then 1 else 0;
AddLabel(yes, if BullConditionGo then "   Bull Go   " else "Bull No Go",if BullConditionGo then color.green else color.red);
def BullConditionGoPlus = if BullConditionGo and FastSlowPctDiff > 0 then 1 else 0;
AddLabel(yes,if BullConditionGoPlus then "Bull Go Plus" else "          ", if BullConditionGoPlus then color.green else color.gray);
def BearConditionGo = if FastPctDiffAvg < FastPctDiffAvg[1] and FastSlowPctDiff < FastSlowPctDiff[1] and FastAvg < FastAvg[1] then 1 else 0;
AddLabel(yes, if BearConditionGo then "   Bear Go   " else "Bear No Go",if BearConditionGo then color.green else color.red);
def BearConditionGoPlus = if BearConditionGo and FastSlowPctDiff < 0 then 1 else 0;
AddLabel(yes,if BearConditionGoPlus then "Bear Go Plus" else "          ", if BearConditionGoPlus then color.green else color.gray);
# Conditions for scanning
plot BullGoPlus = if BullConditionGoPlus then 1 else 0;
BullGoPlus.Hide();
plot BearGoPlus = if BearConditionGoPlus then 1 else 0;
BearGoPlus.Hide();
plot highestPos = if Highest(FastSlowPctDiff,5) <= 1 then 1 else 0;
highestPos.Hide();
plot lowestPos = if Highest(FastSlowPctDiff,5) >= 0 then 1 else 0;
lowestPos.Hide();
def TanAngle = ATan(close);
AddLabel(yes,"'Angle Improving'", if (TanAngle > TanAngle[1]) then color.green else color.red);
AddLabel(yes,"Previous 'Angle': " + TanAngle[1],color.gray);
AddLabel(yes,"Current 'Angle': " + TanAngle,color.gray);

 

[Thinker]

Very interesting indicator. Good work! When I use your code, my red and green zigzag line showing what is happening turns out to be much thinner than the one you show. Is there a way to thicken that line?

 

[useThinkScript]

Very interesting indicator. Good work! When I use your code, my red and green zigzag line showing what is happening turns out to be much thinner than the one you show. Is there a way to thicken that line?

1. click on the beaker at the top of your chart
2. click on the gear icon to the right of your study
3. change the Width of the variable FastSlowPctDiff to your preference
4. click on Save as default to save your preference for all future charts

 

[Thinker]

1. click on the beaker at the top of your chart
2. click on the gear icon to the right of your study
3. change the Width of the variable FastSlowPctDiff to your preference
4. click on Save as default to save your preference for all future charts

Thanks! That works.

 

[wtf_dude]

The idea here is that while the stocks may have greatly different prices, the percentage difference between the averages are comparable. A 5% spread between the 12 and 26 ema is the same relative difference by percentage, regardless of the price differences between stocks.

My intent is to do away with the problem of trying to compare the MACD of different stocks that have widely different price levels.

So I converted the difference between the fast and slow ema into a percentage difference.

Here's my script...

declare lower;

input FastLength = 12; # Faster of the two moving averages
input SlowLength = 26; # Slower of the two moving averages
input FastAvgSmoothingLength = 9;
input FastEMA_Length = 8;
def FastEMAavg = ExpAverage(close,FastEMA_Length);
def P1L = 1;
def PP5L = 0.5;
def ZL = 0;
def MP5L = -0.5;
def M1L = -1;
def SlowAvg = ExpAverage(close,SlowLength); # ema of the slow moving average
def FastAvg = ExpAverage(close,FastLength); # ema of the fast moving average
plot FastSlowPctDiff = ((FastAvg-SlowAvg)/SlowAvg) * 100; # Percent difference between FastAvg and SlowAvg
def FastPctDiff = ((FastAvg - FastAvg[1])/FastAvg[1]) * 100; # Percent difference betwee current and previous bar
plot FastPctDiffAvg = ExpAverage(FastPctDiff,FastAvgSmoothingLength);
FastPctDiffAvg.SetDefaultColor(color.cyan);
def PDGTP = if FastSlowPctDiff > FastSlowPctDiff[1] then 1 else 0;
def PDLTP = if FastSlowPctDiff < FastSlowPctDiff[1] then 1 else 0;
FastSlowPctDiff.AssignValueColor(if PDGTP then Color.GREEN else if PDLTP then Color.RED else Color.YELLOW);
FastSlowPctDiff.SetLineWeight(2);
plot ZLine = ZL;
ZLine.SetDefaultColor(Color.white);
plot P1Line = P1L;
P1Line.SetDefaultColor(color.green);
Plot M1Line = M1L;
M1Line.SetDefaultColor(color.red);
Plot PP5Line = PP5L;
PP5Line.SetDefaultColor(Color.yellow);
PP5Line.SetPaintingStrategy(PaintingStrategy.DASHES);
Plot MP5Line = MP5L;
MP5Line.SetDefaultColor(color.yellow);
MP5Line.SetPaintingStrategy(PaintingStrategy.DASHES);
plot FastEMAImproving = if FastEMAavg > FastEMAavg[1] then 1 else 0;
FastEMAImproving.Hide();
AddLabel(yes,FastEMA_Length + " EMA Improving", if FastEMAImproving then color.green else if FastEMAavg == FastEMAavg[1]  then color.gray else color.red);
AddLabel(yes,FastLength + " EMA Improving",if FastAvg > FastAvg[1] then color.green else color.red);
def BullConditionGo = if FastPctDiffAvg > FastPctDiffAvg[1] and FastSlowPctDiff > FastSlowPctDiff[1] and FastAvg > FastAvg[1] then 1 else 0;
AddLabel(yes, if BullConditionGo then "   Bull Go   " else "Bull No Go",if BullConditionGo then color.green else color.red);
def BullConditionGoPlus = if BullConditionGo and FastSlowPctDiff > 0 then 1 else 0;
AddLabel(yes,if BullConditionGoPlus then "Bull Go Plus" else "          ", if BullConditionGoPlus then color.green else color.gray);
def BearConditionGo = if FastPctDiffAvg < FastPctDiffAvg[1] and FastSlowPctDiff < FastSlowPctDiff[1] and FastAvg < FastAvg[1] then 1 else 0;
AddLabel(yes, if BearConditionGo then "   Bear Go   " else "Bear No Go",if BearConditionGo then color.green else color.red);
def BearConditionGoPlus = if BearConditionGo and FastSlowPctDiff < 0 then 1 else 0;
AddLabel(yes,if BearConditionGoPlus then "Bear Go Plus" else "          ", if BearConditionGoPlus then color.green else color.gray);
# Conditions for scanning
plot BullGoPlus = if BullConditionGoPlus then 1 else 0;
BullGoPlus.Hide();
plot BearGoPlus = if BearConditionGoPlus then 1 else 0;
BearGoPlus.Hide();
plot highestPos = if Highest(FastSlowPctDiff,5) <= 1 then 1 else 0;
highestPos.Hide();
plot lowestPos = if Highest(FastSlowPctDiff,5) >= 0 then 1 else 0;
lowestPos.Hide();
def TanAngle = ATan(close);
AddLabel(yes,"'Angle Improving'", if (TanAngle > TanAngle[1]) then color.green else color.red);
AddLabel(yes,"Previous 'Angle': " + TanAngle[1],color.gray);
AddLabel(yes,"Current 'Angle': " + TanAngle,color.gray);

just as an fyi, your conversion to the percentage basis is an old indicator called the PPO (price percent oscillator) just in case you want to see what others have done with that in the past

@Thinker

 

[antwerks]

I really like the


I'm not sure why but my scan is always empty unless I set the parameters to within 3 bars. 2 and 1 bar gets zero results. Please help.

Here is my version of the scan https://tos.mx/!8x7f3iCT

 

[antwerks]

I added some other confirmations and labelling - very cool original from Mobius and @BenTen !!! https://tos.mx/!PK3dRaD1
Both scripts implement PPO (Percentage Price Oscillator) — a normalized version of MACD — but they are structurally and functionally different in purpose and flexibility.

Major Differences Between the Two PPO Scripts

Feature	New Script (PPO + ROC Dashboard)	TD Ameritrade Default PPO (BenTen, Mobius)
Normalization	PPO shown as raw decimal (e.g., 0.08)	PPO scaled as percentage (e.g., 8%)
Signal Smoothing Options	Customizable smoothing via nSmooth, ROC	Fixed exponential smoothing for signal
ROC Integration	Integrated ROC (Rate of Change)	No ROC
Momentum Labels	Dashboard labels (PPO, signal, ROC, etc.)	None
Momentum Arrows	Bullish/Bearish signal arrows on crossover	None
Scan/Strategy Ready	Designed with conditional logic for scanning	Not optimized for scanner/strategy use
Color Customization	Clean histogram coloring + user toggles	Uses default uptick/downtick/gray
Zero Line Handling	Implicit	Explicit zero line plot
Error Catching (Invalid Inputs)	None	Checks if fast < slow and warns
PPO Display	Clean modernized label-based dashboard	Classic MACD-style histogram display

Interpretation Style Differences

	New (Dashboard)	TD Mobius, BenTen PPO Script
Designed for	Modern trader: multi-confirmation setup	Classic MACD/PPO traders
Readability	Faster at-a-glance interpretation	Better for studying histogram momentum shifts
Volatility Sensitivity	More sensitive due to ROC	More stable as it's just PPO

So the core signal is the same — but the new version is better suited (I feel) for:

• Swing or intraday traders looking for trend confirmation
• Strategy building or scanning
• Reduced chart clutter with actionable labels

Which One to Use?

Use Case	Recommended Script
You want multi-confirmation trend analysis	New PPO + ROC dashboard
You want a basic PPO display only	TDA PPO by Mobius, BenTen
You're building scans or automated strategy	New PPO version

 

[j102491]

@grasshopper123 @wpwright I did was a simple google search, I am assuming that you did also and already saw this Easycator PPO w/ fast and slow lines and it wasn't what you wanted.

However here it is for anyone in the future that has this request:

#
# TD Ameritrade IP Company, Inc. (c) 2007-2016
#
## created by North Vanhooser

declare lower;

input fastPeriod   = 12;
input slowPeriod   = 26;
input signalPeriod = 9;
input price        = close;

def fastEma   = ExpAverage( price, fastPeriod );
def slowEma   = ExpAverage( price, slowPeriod );
def periodOK  = fastPeriod < slowPeriod;
AddLabel( !periodOK, "ERROR: fastPeriod MUST be less than slowPeriod" );
def _ppo      = if periodOK then ((fastEma - slowEma) / slowEma) * 100 else 0;
def _signal   = ExpAverage( _ppo, signalPeriod );

plot Ppo      = _ppo;
Ppo.SetDefaultColor( Color.BLUE );
Ppo.HideBubble();

plot PpoEma   = _signal;
PpoEma.SetDefaultColor( Color.CYAN );
PpoEma.HideBubble();

plot zeroLine = 0;
zeroLine.HideBubble();
zeroLine.AssignValueColor( Color.BLACK );

plot PpoH1    = _ppo - _signal;
PpoH1.SetPaintingStrategy( PaintingStrategy.HISTOGRAM );
PpoH1.DefineColor("Up", Color.UPTICK);
PpoH1.DefineColor("Down", Color.DOWNTICK);
PpoH1.DefineColor("Flat", Color.GRAY);
PpoH1.AssignValueColor( if PpoH1 > PpoH1[1] then
                           PpoH1.Color("Up")
                       else
                         if PpoH1 < PpoH1[1] then
                           PpoH1.Color("Down")
                       else
                           PpoH1.Color("Flat"));
PpoH1.HideBubble();
PpoH1.SetLineWeight( 3 );

View attachment 2001

Here is the shared link: http://tos.mx/zQ6P90

what is the yellow bar?

 

[useThinkScript]

what is the yellow bar?

Good question!
There is no candle painting in the PPO script, so it must have been another script added to the chart.
The post to too old to know what the conversation was back then.

However, did you notice that the painted orange candles "seem" to coincide with the cross of the fast & slow lines?
If you wanted to test that theory and find out if it contributes toward your analysis; you can add the following code snippet to the bottom of your script.

input paintCandles = yes;
AssignPriceColor(if !paintCandles then color.current else
if slowEMA crosses fastEma then color.orange else color.current);

If you are looking for a specific candle-painting condition. Please articulate the specification in detail and provide an image highlighting the congruence.


Keep in mind, ToS supports ONLY one script attempting to paint candles. Multiple painting scripts in your setup will result in an error exclamation point in the upper left-hand corner and provide screwy candle painting.

 

[Splinter]

Very nice work! I use the PPO and your additions are indeed welcome ones! I was hoping in order to see the trend more clearly, and quickly, you would be able to have the RoC line change color when going up or down.

I added some other confirmations and labelling - very cool original from Mobius and @BenTen !!! https://tos.mx/!PK3dRaD1
Both scripts implement PPO (Percentage Price Oscillator) — a normalized version of MACD — but they are structurally and functionally different in purpose and flexibility.

Major Differences Between the Two PPO Scripts

Feature	New Script (PPO + ROC Dashboard)	TD Ameritrade Default PPO (BenTen, Mobius)
Normalization	PPO shown as raw decimal (e.g., 0.08)	PPO scaled as percentage (e.g., 8%)
Signal Smoothing Options	Customizable smoothing via nSmooth, ROC	Fixed exponential smoothing for signal
ROC Integration	Integrated ROC (Rate of Change)	No ROC
Momentum Labels	Dashboard labels (PPO, signal, ROC, etc.)	None
Momentum Arrows	Bullish/Bearish signal arrows on crossover	None
Scan/Strategy Ready	Designed with conditional logic for scanning	Not optimized for scanner/strategy use
Color Customization	Clean histogram coloring + user toggles	Uses default uptick/downtick/gray
Zero Line Handling	Implicit	Explicit zero line plot
Error Catching (Invalid Inputs)	None	Checks if fast < slow and warns
PPO Display	Clean modernized label-based dashboard	Classic MACD-style histogram display

Interpretation Style Differences

	New (Dashboard)	TD Mobius, BenTen PPO Script
Designed for	Modern trader: multi-confirmation setup	Classic MACD/PPO traders
Readability	Faster at-a-glance interpretation	Better for studying histogram momentum shifts
Volatility Sensitivity	More sensitive due to ROC	More stable as it's just PPO

So the core signal is the same — but the new version is better suited (I feel) for:

• Swing or intraday traders looking for trend confirmation
• Strategy building or scanning
• Reduced chart clutter with actionable labels

Which One to Use?

Use Case	Recommended Script
You want multi-confirmation trend analysis	New PPO + ROC dashboard
You want a basic PPO display only	TDA PPO by Mobius, BenTen
You're building scans or automated strategy	New PPO version

View attachment 24998

Very nice work! I use the PPO and your additions are indeed welcome ones! I was hoping in order to see the trend more clearly, and quickly, you would be able to have the RoC line change color when going up or down? I know it seems trivial but at a quick glance it would be a big help. Thanks again for the time you put in to this indicator!

 

[antwerks]

Very nice work! I use the PPO and your additions are indeed welcome ones! I was hoping in order to see the trend more clearly, and quickly, you would be able to have the RoC line change color when going up or down? I know it seems trivial but at a quick glance it would be a big help. Thanks again for the time you put in to this indicator!

# PPO + ROC Momentum Dashboard with Arrows
# Created by ANTWERKS from Mobius and BENTEN | June 2025
# Enhanced: Color-coded ROC trend (June 2025)

declare lower;

# === INPUTS ===
input price = close;
input avgType = AverageType.Simple;
input nFast = 8;
input nSlow = 13;
input nSmooth = 5;

input rocLength = 10;
input rocSmoothingLength = 3;
input rocOB = 5.0;
input rocOS = -5.0;

input showDashboard = yes;
input showArrows = yes;

# === PPO CALCULATION ===
def maFast = MovingAverage(avgType, price, nFast);
def maSlow = MovingAverage(avgType, price, nSlow);

def PPO = (maFast - maSlow) / maSlow;
plot PPOhist = PPO * 200;
PPOhist.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
PPOhist.AssignValueColor(if PPO > 0 then Color.GREEN else Color.RED);
PPOhist.SetLineWeight(3);

def PPOsignal = MovingAverage(avgType, PPO, nSmooth);
plot SignalLine = PPOsignal;
SignalLine.SetDefaultColor(Color.CYAN);
SignalLine.SetLineWeight(1);

# === ROC CALCULATION ===
def ROCraw = (price - price[rocLength]) / price[rocLength] * 100;
def ROCsmoothed = Average(ROCraw, rocSmoothingLength);
plot ROCplot = ROCsmoothed;

# NEW COLORING: green if rising, red if falling, gray if flat
ROCplot.AssignValueColor(
if ROCsmoothed > ROCsmoothed[1] then Color.GREEN
else if ROCsmoothed < ROCsmoothed[1] then Color.RED
else Color.GRAY);
ROCplot.SetLineWeight(2);

# === MOMENTUM SIGNAL LOGIC ===
def isBullish = PPO > PPOsignal and ROCsmoothed > 0;
def isBearish = PPO < PPOsignal and ROCsmoothed < 0;

# === ARROWS ON CHART ===
plot BullArrow = if showArrows and isBullish and !isBullish[1] then 0 else Double.NaN;
BullArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
BullArrow.SetDefaultColor(Color.GREEN);
BullArrow.SetLineWeight(2);

plot BearArrow = if showArrows and isBearish and !isBearish[1] then 0 else Double.NaN;
BearArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
BearArrow.SetDefaultColor(Color.RED);
BearArrow.SetLineWeight(2);

# === LABELS ===
AddLabel(showDashboard, "PPO: " + Round(PPO, 2), if PPO > 0 then Color.GREEN else Color.RED);
AddLabel(showDashboard, "Signal: " + Round(PPOsignal, 2), Color.CYAN);
AddLabel(showDashboard, "ROC: " + Round(ROCsmoothed, 2) + "%",
if ROCsmoothed >= rocOB then Color.LIGHT_GREEN
else if ROCsmoothed <= rocOS then Color.PINK
else Color.GRAY);

AddLabel(showDashboard,
if isBullish then "Momentum: Bullish"
else if isBearish then "Momentum: Bearish"
else "Momentum: Neutral",
if isBullish then Color.GREEN
else if isBearish then Color.RED
else Color.YELLOW);