Morgan Visual Trend Indicator for ThinkorSwim

[BenTen]

The MVTI was published in the May 2019 issue of Technical Analysis of Stocks and Commodities magazine.

Morgan Visual Trend shows the current trend condition of the market. It paints on top of the candles. The indicator uses CCI, ADX, Overbought, and Oversold levels.

Notes:

• Dark Green is Strong Up Trend
• Light Green is Mild Up Trend
• White is Neutral
• Light Red is Mild Down Trend
• Dark Red is Strong Down Trend

Besides changing the color of the candles and volume bars based on how it sees the trend, there are no additional features.

thinkScript Code

# Morgan Visual Trend Indicator

input CCILength = 21;
input CCILimit = 100;
input ADXLength = 8;
input ADXTrend = 15;
def ADX = reference ADX(length = ADXLength);
def DIPlus = reference DIPlus(length = ADXLength);
def DIMinus = reference DIMinus(length = ADXLength);

def Tr = if ADX < ADXTrend then 0 else
  if Tr[1] == 1 and DIPlus > DIMinus then 1 else
  if Tr[1] <= 0 and DIPlus > DIMinus and ADX > ADX[1] then 1 else
  if Tr[1] == -1 and DIMinus > DIPlus then -1 else
  if Tr[1] >= 0 and DIMinus > DIPlus and ADX > ADX[1] then -1
  else 0;

def CCI = CCI(21, CCILimit, CCILimit).CCI;
def OverBought = CCILimit;
def OverSold = -CCILimit;

def OB = if (CCI > OverBought) then 1 else 0;
def OS = if (CCI < OverSold) then 1 else 0;

DefineGlobalColor("StrongUp", Color.DARK_GREEN);
DefineGlobalColor("Up", Color.LIGHT_GREEN);
DefineGlobalColor("Neutral", Color.WHITE);
DefineGlobalColor("Down", Color.LIGHT_RED);
DefineGlobalColor("StrongDown", Color.DARK_RED);

AssignPriceColor(
if (Tr == 1 and OB == 1) then
  GlobalColor("StrongUp")
else if Tr == 1 then
  GlobalColor("Up")
else if Tr == -1 and OS == 0 then
  GlobalColor("Down")
else if (Tr == -1 and OS == 1) then
  GlobalColor("StrongDown")
else
  GlobalColor("Neutral"));

Shareable Link

https://tos.mx/ts7kUw

Credit:

• alan.shrock

 

[J007RMC]

Thanks! This study it does a great job of coloring candles based on candle strength.