DPO Mobo for ThinkorSwim

[maverickmitch]

Hey all,
I really enjoying on demand trading with FW_DPO_mobo, those arrows and the cloud changing from green to red is very helpful, but I don't have time to sit and watch my 2 hour candles all day. Is there any way to create an alert with the thinkScript on the mobo indicator when the arrow changes from up to down or vice versa? I'm at a loss.

Any help would be greatly appreciated.

This should do it for you.

def BottomBandUp;
def Break_Down = FW_DPO_MOBO().BreakDownArrow;
def Break_Out = FW_DPO_MOBO().BreakOutArrow;
if Break_Out is true {
BottomBandUp = yes;
} else if Break_Down is true {
BottomBandUp = no;
} else {
BottomBandUp = BottomBandUp[1];
}
def BB_Buy = BottomBandUp;

#RED
def BottomBandDown;
def Breakdown = FW_DPO_MOBO()."breakdownArrow";

def Breakout = FW_DPO_MOBO().BreakOutArrow;

if Breakdown is true {
BottomBandDown = yes;
} else if Breakout is true {
BottomBandDown = no;
} else {
BottomBandDown = BottomBandDown[1];
}
def BB_Sell = BottomBandDown;

plot buy = BB_Buy and !BB_Buy[1];
plot sell = BB_Sell and !BB_Sell[1];

Buy.setpaintingStrategy(paintingStrategy.BOOLEAN_ARROW_UP);
Sell.setpaintingStrategy(paintingStrategy.BOOLEAN_ARROW_DOWN);

Alert(Buy[1], "BUY", Alert.BAR, Sound.Bell);
Alert(Sell[1], "Sell", Alert.BAR, Sound.Bell);

 

[ckidd63]

How do I convert an AddCloud Statement into a variable TOS?

AddCloud(if DPO > lower then upper else nan,
if DPO > lower then lower else nan, Color.Green, Color.Current);

 

[MerryDay]

How do I convert an AddCloud Statement into a variable TOS?

AddCloud(if DPO > lower then upper else nan,
if DPO > lower then lower else nan, Color.Green, Color.Current);

Your request is: Create a definition for when your cloud is green? Which indicates that the DPO is greater than the lower boundary.

def variable = DPO > Lower ;

If you are looking for a signal for when the cloud begins to turn green:

plot trigger = if DPO crosses above Lower then Lower else double.NaN;
trigger.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
trigger.SetDefaultColor(color.yellow) ;
trigger.SetLineWeight(3);[

#https://www.tradingview.com/script/s2yv2eub-Mobo-Bands/
declare lower;
def price  = hl2;
def colorNormLength = 3;
def dpoLength       = 13;
def moboDisplace    = 0;
def moboLength    = 10;
def numDevDn  = -0.8;
def numDevUp  = 0.8;
script nz {
    input data = 0;
    def ret_val = if IsNaN(data) then 0 else data;
    plot return = ret_val;
}
def coloredMobo     = yes;
def coloredFill     =  yes;
def breakArrows     = yes;
def moboShowMid     = yes;


#def DPO = price - Average(price[DPO_length / 2 + 1], DPO_length);
def xsma = Average(price[dpoLength / 2 + 1], dpoLength);
#def xsma = sma(price, dpoLength);
def DPO = price - xsma;


def Midline = Average(DPO, moboLength);

def sDev = StDev(DPO, moboLength);

def Lower = Midline + numDevDn * sDev;
def Upper = Midline + numDevUp * sDev;

plot line_dpo = DPO;
line_dpo.AssignValueColor(if  line_dpo>  line_dpo[1] then Color.cyan else Color.red);
line_dpo.SetLineWeight(5);
plot Line_mid = Midline;
Line_mid.AssignValueColor(if MidLine < dpo then Color.green else Color.magenta);
Line_mid.SetLineWeight(3);

AddCloud(if DPO > Lower then Upper else double.NaN,
if DPO > Lower then Lower else double.NaN, Color.Green, Color.Current);

plot trigger = if DPO crosses above Lower then Lower else double.NaN;
trigger.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
trigger.SetDefaultColor(color.yellow) ;
trigger.SetLineWeight(3);

 

[ckidd63]

Great. Thank You MD

 

[UncleTerry]

Would anyone happen to know if the FW_DPO_MOBO has an upper chart open thinkscript code?

 

[Thinker]

Would anyone happen to know if the FW_DPO_MOBO has an upper chart open thinkscript code?

If I understand what you want (just to put the indicator in the upper portion of the chart), you can just drag it from the indicators in the lower portion to the upper part of the chart, and it will appear with the price candles.