Join useThinkScript to post your question to a community of 21,000+ developers and traders.
check the below. I added some filters as well.
# Indicator for TOS
#study(title="Buy/Sell by Prakash EEE", overlay=true)
# Converted by Sam4Cok@Samer800 - 07/2024
input filterSelect = {Default "Moving Average", "VWAP", "MA & VWAP", "Don't use Filter"};
input source = close; #(defval=close, title="Source")
input fastPeriod = 27; #(defval=27, minval=1, title="Fast period")
input slowPeriod = 55; #, minval=1, title="Slow period")
input fastMultiplier = 1.6; #(defval=1.6, minval=0.1, title="Fast range")
input slowMultiplier = 2.0; #(defval=2, minval=0.1, title="Slow range")
input showRangeFilterLine= yes;
input showVwapLine = yes;
input vwapTimeFrame = {default DAY, WEEK, MONTH};
def na = Double.NaN;
def quickEMA = ExpAverage(source, 9);
def wap = Reference vwap(timeFrame = vwapTimeFrame).price;
DefineGlobalColor("blue" , CreateColor(33,150,243));
DefineGlobalColor("orange" , CreateColor(255,152,0));
#smoothrng(x, t, m)
script smoothrng {
input src = close;
input per = 100;
input mult = 3;
def wper = per * 2 - 1;
def srcDif = AbsValue(src - src[1]);
def avrng = ExpAverage(srcDif, per);
def smoothrng = ExpAverage(avrng, wper) * mult;
plot result = smoothrng;
}
#// Range Filter
#rngfilt(x, r) =>
script rngfilt {
input src = close;
input r = 0;
def rngfilt = CompoundValue(1, if !rngfilt[1] then src else
if src > rngfilt[1] then
if (src - r) < rngfilt[1] then rngfilt[1] else (src - r) else
if (src + r) > rngfilt[1] then rngfilt[1] else (src + r), src);
plot result = rngfilt;
}
def smrng1 = smoothrng(source, fastPeriod, fastMultiplier);
def smrng2 = smoothrng(source, slowPeriod, slowMultiplier);
def smrng = (smrng1 + smrng2) / 2;
def filt = rngfilt(source, smrng);
def filterUp; def filterDn;
Switch (filterSelect) {
Case "VWAP" :
filterUp = filt > wap;
filterDn = filt < wap;
Case "MA & VWAP" :
filterUp = filt > quickEMA and filt > wap;
filterDn = filt < quickEMA and filt < wap;
Case "Don't use Filter" :
filterUp = yes;
filterDn = yes;
Default :
filterUp = filt > quickEMA;
filterDn = filt < quickEMA;
}
def upward = if filt > filt[1] then upward[1] + 1 else
if filt < filt[1] then 0 else upward[1];
def downward = if filt < filt[1] then downward[1] + 1 else
if filt > filt[1] then 0 else downward[1];
def col = if upward > 0 then 1 else if downward > 0 then -1 else 0;
def longCond = source > filt and source > source[1] and upward > 0 and filterUp;
def shortCond = source < filt and source < source[1] and downward > 0 and filterDn;
def CondIni = if longCond then 1 else if shortCond then -1 else CondIni[1];
def long = longCond and CondIni[1] == -1;
def short = shortCond and CondIni[1] == 1;
plot rfLine = if showRangeFilterLine then filt else na;
plot vwapLine = if showVwapLine then wap else na;
rfLine.AssignValueColor(if col > 0 then GlobalColor("blue") else
if col < 0 then GlobalColor("orange") else Color.GRAY);
vwapLine.SetDefaultColor(Color.MAGENTA);
AddChartBubble(long, low, "BUY", Color.GREEN, no);
AddChartBubble(short, high, "Sell", Color.RED);
#-- END of CODE@samer800 great job. a quick question do you think its possible to add color candles with the signal, meaning if is a BUY paint the candles green and if is a SELL paint the candles red, also add a input to use the signal label and arrow. thank you in advance
. You are our rock star
.input showBubbles = no ;
input showArrows = yes;
input showLabel = yes;
AddChartBubble(showBubbles and long, low, "BUY", Color.GREEN, no);
AddChartBubble(showBubbles and short, high, "Sell", Color.RED);
plot upArrow = if showArrows then long else double.NaN ;
upArrow.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
upArrow.SetDefaultColor(color.cyan) ;
upArrow.SetLineWeight(3);
plot dnArrow = if showArrows then short else double.NaN ;
dnArrow.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
dnArrow.SetDefaultColor(color.magenta) ;
dnArrow.SetLineWeight(3);
AddLabel(showLabel and (long or short), if long then "buy" else "sell",
if long then color.green else color.red);
input SignalCandles = yes ;
AssignPriceColor(if !SignalCandles then color.current else
if long then color.green else
if short then color.red else color.gray);or
| Thread starter | Similar threads | Forum | Replies | Date |
|---|---|---|---|---|
| M | Trading BUY/SELL Signal For ThinkOrSwim | Custom | 2 | |
| D | Trend Trader Buy/Sell Signals For ThinkOrSwim | Custom | 4 | |
| F | Buy the dips - sell the tops For ThinkOrSwim | Custom | 6 | |
| A | Multi-Divergence Buy/Sell Indicator For ThinkOrSwim | Custom | 6 | |
| V | Repaints Rotation Factor: Buy/Sell Pressure For ThinkOrSwim | Custom | 1 |
useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.
We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.
If you are new, or just looking for guidance, here are some helpful links to get you started.