Volume ROC 4hr:30min

[westonsloan]

#Error message tells me that I have provided 3 positional arguments where only two are needed. Help me show the label that encompasses the Power function without error
def xvolume4 = (volume(period = "4 hour")[1]);
def vvol4 = (volume(period = "4 hour"));
plot rvolx4 = Round((vvol4 / xvolume4), 1);
def rvolxapi4 = rvolx4;

def xvolume = (volume(period = "30 min")[1]);
def vvol = (volume(period = "30 min"));
plot rvolx = Round((vvol / xvolume), 1);
def rvolxapi = rvolx;

plot Power = (rvolxapi4 / rvolxapi);
AddLabel(yes, Concat("Fold: ", Power, Color.LIGHT_ORANGE));

 

[MerryDay]

#Error message tells me that I have provided 3 positional arguments where only two are needed. Help me show the label that encompasses the Power function without error

There were other syntax errors besides the label in your script.
Below find the corrected syntax and some suggested formatting styles which hopefully, will further your quest:

# ########################################################
# Volume ROC 4hr:30min
# @westonsloan 8/23
# ########################################################
declare lower ;
declare real_size;

def volume4 = volume(period = AggregationPeriod.FOUR_HOURS);
def volume30 = volume(period = AggregationPeriod.THIRTY_MIN);

plot rvol4  = volume4 / volume4[1];
     rvol4.SetDefaultColor(Color.DARK_ORANGE) ;
     rvol4.SetLineWeight(1);

plot rvol30 = volume30 / volume30[1];
     rvol30.SetDefaultColor(Color.PLUM) ;
     rvol30.SetLineWeight(1);

plot Power = rvol4 / rvol30 ;
     Power.SetDefaultColor(Color.BLUE) ;
     Power.SetLineWeight(2);
     Power.HideBubble() ;
     Power.HideTitle() ;
     Power.SetStyle(Curve.SHORT_DASH);

AddCloud(rvol4,  rvol30,  Color.LIGHT_ORANGE,  Color.VIOLET);
AddLabel(yes, "Fold: " + Power, if Power < rvol30 then color.dark_red else color.dark_green);