TTM Squeeze Histogram Backtester For ThinkOrSwim

[useThinkScript]

TTM Squeeze Histogram Backtester
https://tosindicators.com/backtesters/ttm-squeeze-histogram

input consecutiveHistogramBars = 7;
input RSIOverboughtVal = 60;
input RSIOversoldVal = 40;
input longEntries = yes;
input shortEntries = yes;

def histogram = TTM_Squeeze().histogram;

#Cyan, Blue, Yellow and Red Histogram Bar Definitions
def cyan = histogram > histogram[1] and histogram > 0;
def blue = histogram < histogram[1] and histogram > 0;
def red = histogram < histogram[1] and histogram < 0;
def yellow = histogram > histogram[1] and histogram < 0;

#Consecutive Momentum Histogram Bars
def minCyanBars = Sum(cyan, consecutiveHistogramBars) >= consecutiveHistogramBars;
def minRedBars = Sum(red, consecutiveHistogramBars) >= consecutiveHistogramBars;

#Momentum Shifts in Histogram
def momoDown = minCyanBars[1] and blue;
def momoUp = minRedBars[1] and yellow;

#RSI
def RSIOverbought = RSI() > RSIOverboughtVal;
def RSIOversold = RSI() < RSIOversoldVal;

AddOrder(OrderType.Buy_To_Open, longEntries and momoUp and RSIOversold, open[-1]);
AddOrder(OrderType.Sell_To_Close, histogram < histogram[1], open[-1]);

AddOrder(OrderType.Sell_To_Open, shortEntries and momoDown and RSIOverbought, open[-1]);
AddOrder(OrderType.Buy_To_Close, histogram > histogram[1], open[-1]);

 

[Squeeze]

So I have come across a back tester for TTM_Squeeze not my code but was wondering if the community can help tweak this below. This is were I found the code from the video link- https://tosindicators.com/indicators/ttm-squeeze-backtester

Original Code below:

input length = 20;
input nk = 1.5;
input nBB = 2.0;

def squeeze = TTM_Squeeze(close, length, nk, nBB).SqueezeAlert;

def EMA13 = ExpAverage(close, 13);
def EMA21 = ExpAverage(close, 21);
def EMA34 = ExpAverage(close, 34);

def bullish = EMA13 > EMA21 and EMA21 > EMA34;
def bearish = EMA13 < EMA21 and EMA21 < EMA34;

def fiveDotSqueeze = Sum(squeeze, 5) == 0;

def bullishSignal = if fiveDotSqueeze and bullish then 1 else 0;
def bearishSignal = if fiveDotSqueeze and bearish then 1 else 0;

def exitBullishTrade = if EMA13 < EMA21 and EMA13[1] >= EMA21[1] then 1 else 0;
def exitBearishTrade = if EMA13 > EMA21 and EMA13[1] <= EMA21[1] then 1 else 0;

AddOrder(OrderType.Buy_To_Open, BullishSignal, open[-1], 100);
AddOrder(OrderType.Sell_To_Close, exitBullishTrade,open[-1], 100);

AddOrder(OrderType.Sell_To_Open, bearishSignal,open[-1], 100);
AddOrder(OrderType.Buy_To_Close, exitBearishTrade,open[-1], 100);

Couple of things to insert below: need help with the code

Create:

1. alert when to buy to open is true
2. alert when to sell to close is true

Not sure how this can be done but the code below if true then override the alerts above ? In the image below you can see the purple trades means it was one or the codes below. I hope that makes sense if not let me know..

Send Alerts: to phone/email or forward the message log to txt sms? Would it be possible to send when an alert- buy to open vice verse sell to close? Or
if someone can help me create it in marketwatch and create an alert?

 

[BenTen]

Try this:

# Alerts
Alert(BullishSignal, " ", Alert.Bar, Sound.Chimes);
Alert(exitBullishTrade, " ", Alert.Bar, Sound.Bell);

 

[Squeeze]

Worked like a charm! Hey @BenTen is there anyway of making this strategy into a scanner ?

 

[BenTen]

@Squeeze What are you trying to scan for?

 

[Squeeze]

If this is true or vice verse if bearish

def bullishSignal = if fiveDotSqueeze and bullish then 1 else 0

I believe that is what makes an add order pop on the screen so in turn plot an arrow similar to what the add order does ? I am trying to replicate the strategy into a scan so I can make a watchlist, Then when a stock appears into scan watchlist I can send an txt to my phone. and can do the same when its a bearish signal to remove. Am i approaching this the right way @BenTen ?

 

[BenTen]

@Squeeze I'm going to assume that you want to scan for the following:

def bullishSignal = if fiveDotSqueeze and bullish then 1 else 0;
def bearishSignal = if fiveDotSqueeze and bearish then 1 else 0;

Here is the new script that you need to add as an indicator:

input length = 20;
input nk = 1.5;
input nBB = 2.0;

def squeeze = TTM_Squeeze(close, length, nk, nBB).SqueezeAlert;

def EMA13 = ExpAverage(close, 13);
def EMA21 = ExpAverage(close, 21);
def EMA34 = ExpAverage(close, 34);

def bullish = EMA13 > EMA21 and EMA21 > EMA34;
def bearish = EMA13 < EMA21 and EMA21 < EMA34;

def fiveDotSqueeze = Sum(squeeze, 5) == 0;

def bullishSignal = if fiveDotSqueeze and bullish then 1 else 0;
def bearishSignal = if fiveDotSqueeze and bearish then 1 else 0;

plot bull = bullishSignal;
bull.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
plot bear = bearishSignal;
bear.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);

This will plot up and down arrows on your chart. You can set up the scanner to something like this:

If you still need help with the scanner, watch the tutorial below:

In order to get alerts through your phone, you need to save your scanner as a watchlist and select the following option: Alerts when scan results change....

 

[MURFMURF]

I could use fresh pair of eyes why my code is not working.

Thanks in advance for anyone willing to help!

1) I'm using the code from the top post.
2) I'm trying to convert it to chart indicator and scanner. For some reason, it appears the match logic of the RSI levels and histogram are not matching as they did in the back tester.
Here is my version to change the order logic to chart bubble.

input consecutiveHistogramBars = 7;
input RSIOverboughtVal = 60;
input RSIOversoldVal = 40;
input longEntries = yes;
input shortEntries = yes;

def histogram = TTM_Squeeze().histogram;

#Cyan, Blue, Yellow and Red Histogram Bar Definitions
def cyan = histogram > histogram[1] and histogram > 0;
def blue = histogram < histogram[1] and histogram > 0;
def red = histogram < histogram[1] and histogram < 0;
def yellow = histogram > histogram[1] and histogram < 0;

#Consecutive Momentum Histogram Bars
def minCyanBars = Sum(cyan, consecutiveHistogramBars) >= consecutiveHistogramBars;
def minRedBars = Sum(red, consecutiveHistogramBars) >= consecutiveHistogramBars;

#Momentum Shifts in Histogram
def momoDown = minCyanBars[1] and blue;
def momoUp = minRedBars[1] and yellow;

#RSI
def RSIOverbought = RSI() > RSIOverboughtVal;
def RSIOversold = RSI() < RSIOversoldVal;

# Plot Chart Bubbles Instead of Orders
AddChartBubble(longEntries and momoUp and RSIOversold, close, "Long", Color.GREEN, yes);
AddChartBubble(histogram < histogram[1], close, "Sell Close", Color.RED, no);
AddChartBubble(shortEntries and momoDown and RSIOverbought, close, "Short", Color.ORANGE, yes);
AddChartBubble(histogram > histogram[1], close, "Buy Close", Color.CYAN, no);

I place arrow on the screenshot where the only bubble should be located.