SuperTrend TradingView Look-A-Like For ThinkOrSwim

[merryDay]

Merry, Does SuperTrend repaint?

No, the Supertrend is not a "repainter"
For prior candles, the calculations used in Supertrends are set and final and do not repaint.

However, this study, like the majority of indicators on this forum, will continually update the current bar until it is closed.
Think about it, we can not know, as a candle is forming, what the final close, high, low, of the current bar is going to be, so of course, it updates with the most recent tick.

Find out more about Supertrends:
https://usethinkscript.com/threads/supertrend-indicator-by-mobius-for-thinkorswim.7/#post-77876

 

[xxentre]

Thanks a lot .. This is really helpful
Also is below code is correct way to setup a scan

# SuperTrend Yahoo Finance Replica - Modified from Modius SuperTrend
# Modified Modius ver. by RConner7
# Modified by Barbaros to replicate look from TradingView version
# v3.0

input AtrMult = 1.00;
input nATR = 6;
input AvgType = AverageType.HULL;
input PaintBars = no;
input ShowBubbles = no;

def ATR = ATR("length" = nATR, "average type" = AvgType);
def UP_Band_Basic = HL2 + (AtrMult * ATR);
def LW_Band_Basic = HL2 + (-AtrMult * ATR);
def UP_Band = if ((UP_Band_Basic < UP_Band[1]) or (close[1] > UP_Band[1])) then UP_Band_Basic else UP_Band[1];
def LW_Band = if ((LW_Band_Basic > LW_Band[1]) or (close[1] < LW_Band[1])) then LW_Band_Basic else LW_Band[1];

def ST = if ((ST[1] == UP_Band[1]) and (close < UP_Band)) then UP_Band
else if ((ST[1] == UP_Band[1]) and (close > Up_Band)) then LW_Band
else if ((ST[1] == LW_Band[1]) and (close > LW_Band)) then LW_Band
else if ((ST[1] == LW_Band) and (close < LW_Band)) then UP_Band
else LW_Band;

def Long = if close > ST then ST else Double.NaN;


def LongTrigger = isNaN(Long[1]) and !isNaN(Long);

plot LongDot = if LongTrigger then 1 else 0;

How do I have this Scan for the SuprerTrend on the next candle after the initial start of the SuperTrend?

 

[useThinkScript]

How do I have this Scan for the SuprerTrend on the next candle after the initial start of the SuperTrend?

Scan for the SuprerTrend on the next candle after the initial start of the SuperTrend

# SuperTrend Yahoo Finance Replica - Modified from Modius SuperTrend
# Modified Modius ver. by RConner7
# Modified by Barbaros to replicate look from TradingView version
# v3.0

input AtrMult = 1.00;
input nATR = 6;
input AvgType = AverageType.HULL;
input PaintBars = no;
input ShowBubbles = no;

def ATR = ATR("length" = nATR, "average type" = AvgType);
def UP_Band_Basic = HL2 + (AtrMult * ATR);
def LW_Band_Basic = HL2 + (-AtrMult * ATR);
def UP_Band = if ((UP_Band_Basic < UP_Band[1]) or (close[1] > UP_Band[1])) then UP_Band_Basic else UP_Band[1];
def LW_Band = if ((LW_Band_Basic > LW_Band[1]) or (close[1] < LW_Band[1])) then LW_Band_Basic else LW_Band[1];

def ST = if ((ST[1] == UP_Band[1]) and (close < UP_Band)) then UP_Band
else if ((ST[1] == UP_Band[1]) and (close > Up_Band)) then LW_Band
else if ((ST[1] == LW_Band[1]) and (close > LW_Band)) then LW_Band
else if ((ST[1] == LW_Band) and (close < LW_Band)) then UP_Band
else LW_Band;

def Long = if close > ST then ST else Double.NaN;


def LongTrigger = isNaN(Long[2]) and !isNaN(Long[1]) and !isNaN(Long);

plot LongDot = if LongTrigger then 1 else 0;

 

[Stan615]

Hi Ben,
Is there a scanner available for this SuperTrend/TradingView look alike? Thank you
S

 

[merryDay]

Hi Ben,
Is there a scanner available for this SuperTrend/TradingView look alike? Thank you
S

https://usethinkscript.com/threads/...a-like-for-thinkorswim.7719/page-3#post-96580

 

[5rings]

When i load the ST script in TOS , nothing shows up!

 

[merryDay]

When i load the ST script in TOS , nothing shows up!

Hard to say what’s causing that without seeing your chart or settings. If you provide a shared chart link, I can take a look.
https://usethinkscript.com/threads/how-to-share-a-chart-in-thinkorswim.14221/

If your question is: "Why are there no buy/sell bubbles" or "Why are the candles not being painted with trend"
It is because you need to turn on those preferences in settings.
If those are your permanent preferences, be sure to "Save as default"

In the meantime, here’s a shared chart with settings that work with this indicator—you can compare to see what’s different.
shared chart link: http://tos.mx/!AOm7QspY MUST follow these instructions for loading shared links.

 

[csricksdds]

SuperTrend TradingView Look-A-Like For ThinkOrSwim

I modified a version of SuperTrend that is already available for Thinkorswim to imitate the style.

View attachment 11716

You can adjust the look from the options. Labels are turned off by default.
View attachment 11717

It also has alerts for trend change.
View attachment 11718

# SuperTrend Yahoo Finance Replica - Modified from Modius SuperTrend
# Modified Modius ver. by RConner7
# Modified by Barbaros to replicate look from TradingView version
# v3.0

input AtrMult = 1.00;
input nATR = 6;
input AvgType = AverageType.HULL;
input PaintBars = no;
input ShowBubbles = no;

def ATR = ATR("length" = nATR, "average type" = AvgType);
def UP_Band_Basic = HL2 + (AtrMult * ATR);
def LW_Band_Basic = HL2 + (-AtrMult * ATR);
def UP_Band = if ((UP_Band_Basic < UP_Band[1]) or (close[1] > UP_Band[1])) then UP_Band_Basic else UP_Band[1];
def LW_Band = if ((LW_Band_Basic > LW_Band[1]) or (close[1] < LW_Band[1])) then LW_Band_Basic else LW_Band[1];

def ST = if ((ST[1] == UP_Band[1]) and (close < UP_Band)) then UP_Band
else if ((ST[1] == UP_Band[1]) and (close > Up_Band)) then LW_Band
else if ((ST[1] == LW_Band[1]) and (close > LW_Band)) then LW_Band
else if ((ST[1] == LW_Band) and (close < LW_Band)) then UP_Band
else LW_Band;

plot Long = if close > ST then ST else Double.NaN;
Long.AssignValueColor(Color.GREEN);
Long.SetLineWeight(2);

plot Short = if close < ST then ST else Double.NaN;
Short.AssignValueColor(Color.RED);
Short.SetLineWeight(3);

def LongTrigger = isNaN(Long[1]) and !isNaN(Long);
def ShortTrigger = isNaN(Short[1]) and !isNaN(Short);

plot LongDot = if LongTrigger then ST else Double.NaN;
LongDot.SetPaintingStrategy(PaintingStrategy.POINTS);
LongDot.AssignValueColor(Color.GREEN);
LongDot.SetLineWeight(4);

plot ShortDot = if ShortTrigger then ST else Double.NaN;
ShortDot.SetPaintingStrategy(PaintingStrategy.POINTS);
ShortDot.AssignValueColor(Color.RED);
ShortDot.SetLineWeight(4);

AddChartBubble(ShowBubbles and LongTrigger, ST, "BUY", Color.GREEN, no);
AddChartBubble(ShowBubbles and ShortTrigger, ST, "SELL", Color.RED, yes);

AssignPriceColor(if PaintBars and close < ST
               then Color.RED
               else if PaintBars and close > ST
                    then Color.GREEN
                    else Color.CURRENT);

Alert(LongTrigger, "Long", Alert.BAR, Sound.Ding);
Alert(ShortTrigger, "Short", Alert.BAR, Sound.Ding);

# End Code SuperTrend Yahoo Finance Replica

Nice