Premarket Sweep Scan

[OutsideTrades]

Hi everyone! I'm looking to make a simple scan for stocks where the first 15m bar (9:30 to 9:45) has a low below the pre market low but then closes back above the pre market low, and vice versa for the opposite direction. This is the code that I have and I feel like it should work but its not turning up any results for some reason. Am I missing something obvious?

input RTHStart = 0930;
input RTHEnd = 1600;
input PremktStart = 0000;
input PremktEnd = 0929;

def isPremkt = SecondsFromTime(PremktStart) >= 0 and SecondsTillTime(PremktEnd) > 0;
def isFirstBar = SecondsFromTime(RTHStart) >= 0 and SecondsTillTime(RTHStart + 15) > 0;

def premktHigh = if isPremkt then Max(high, premktHigh[1]) else premktHigh[1];
def premktLow = if isPremkt then Min(low, premktLow[1]) else premktLow[1];

// Only on 9:30–9:45 bar
def sweepUp = isFirstBar and low < premktLow and close > premktLow;
def sweepDown = isFirstBar and high > premktHigh and close < premktHigh;

plot scan = sweepUp or sweepDown;

Thanks a bunch in advance!!

 

[Svanoy]

Since premktHigh and premktLow are not being initialized on the first bar of premarket they are by default zero. This isn't a big deal for premktHigh as the first premarket bar high will be greater than zero and premktHigh will update to that value. However there will never be a premarket bar low below zero so premktLow never changes from zero.

Try this for your definitions of premktHigh and premktLow instead:

def premktHigh = if isPremkt && !isPremkt[1] then high
    else if isPremkt then Max(high, premktHigh[1]) else premktHigh[1];
def premktLow = if isPremkt && !isPremkt[1] then low
    else if ispremkt then Min(low, premktLow[1]) else premktLow[1];

Also, unless you are running this scan during the first 15 min bar of RTH it will not return any results without increasing 'within _ bars' condition to the amount of bars you are currently past the first 15 min bar.
I believe it would be better to use:

def defscan = if isPremkt then 0 else if sweepUp or sweepDown then 1 else defscan[1];
plot scan = defscan;