TOP Ultimate Breakout Indicator for ThinkorSwim

[Billions]

@Billions can you compare the two strategies?

I have been watching the breakout indicator on the side today. It does have false triggers, but it seems like it expects you to take all of them and cumulatively it will be positive at the end of the day. It will be nice to figure out how to filter out the false triggers, or show a confidence score so we can make the choice to take the risk or not.

side note: i don't like the trend reversal too much since it keeps repainting.

Im trying to test I thought maybe change to an 8 ema but not sure ill keep testing

 

[barbaros]

Im trying to test I thought maybe change to an 8 ema but not sure ill keep testing

This is going to be difficult. We are expecting the indicator to be early enough for entries, but also predict the future...I think at one point, trader needs to take the risk and enter a trade with enough stop loss and profit targets in place.

 

[wen]

hello! I try to scan #11. what time frame n how many bar you guys use? I am using 15 mins. don't know how bar I have to use for day trading. any Recommendations ?

 

[mansor]

@Billions can you compare the two strategies?

I have been watching the breakout indicator on the side today. It does have false triggers, but it seems like it expects you to take all of them and cumulatively it will be positive at the end of the day. It will be nice to figure out how to filter out the false triggers, or show a confidence score so we can make the choice to take the risk or not.

side note: i don't like the trend reversal too much since it keeps repainting.

I use heikin ashi and I opted to have those ticks hollow, instead of solid red and green. Easier to read tick.

Those green and red bubbles do disappear every now and then on 1m and 10m chart, shows it's processing real time data.

 

[mikeraya]

@RickKennedy Rick a couple of questions for you. 1) The candles in the referenced study include gray candles buy your chart does not. What study do you use to get just red and green candles? 2) Does the MACD the way you have it set up in your chart work on any security or just futures? Doesn't look quite as good on SPX on 5 minute. Just curious. Thanks in advance.

 

[ssara]

Hello i pasted the code and indicator nothing is plotting - i chose short - can someone share the shared link if that is not much trouble so we can test it in real life a bit - thanks in advance - you guys are Genius.

 

[GOS]

Hello i pasted the code and indicator nothing is plotting - i chose short - can someone share the shared link if that is not much trouble so we can test it in real life a bit - thanks in advance - you guys are Genius.

There are several versions through the pages, this ones worksmin different time frame or tick charts as well https://tos.mx/F0ix1CA

 

[Alex]

is there anyway to add audible alerts when a new signal pops up?

Edit:

alert(BuyEntry, "LONG", Alert.BAR, Sound.Ring);
alert(SellEntry, "SHORT", Alert.BAR, Sound.Ding);

 

[vkmath]

Sorry if this has already been covered, but does the TOP Ultimate Breakout Indicator Repaint? I've studied a week's worth of signals on the 5 and 10 minute charts and it looks almost too accurate. thx -Kevin

 

[BenTen]

@vkmath If I remember correctly the answer is yes

 

[vkmath]

I can confirm it does not. Works great with renko.

Thanks Alex. Renko charts are new to me. What box size and timeframe do you use? thx -Kevin

 

[Alex]

@vkmath 10 ticks , 2.5 points for /ES

 

[Martok]

@tomsk,

I have a question about the "bullish breakout scan", post #8 here, and have tried to install it into TOS for 2 days, however having trouble, - my TOS experience is lacking, check my "Signature", and I hate to ask, but I'm stuck.

I get stuck in TOS loading the scanner at this point:

I'm not sure what conditions on the right side it requires, so it can be saved.

Any help is much appreciated.


Regards,

Martok

 

[Chuck]

This is a fantastic system, by far one of the best I have used.

When trading /ES.....I use the 1000 tick chart to set up my orders and enter when confirmed on the 2000 chart.

I wait for confirmation ON BOTH charts of all colored trend labels, confirmation of the 8 and 20 crossing and to keep out of choppy situations only enter when both charts confirm "TRENNDING".

I noticed that it has the option to target buy ot=r sell orders, can someone add an option to show both?
Also the charts get cluttered when the price targets overlap and stay visible after the trend changes. Is it possible to make the price targets disappear after trend change?

This is a link tp the chart set up and the version of the code I use :

----------------------------------

http://tos.mx/SQsC8zv

----------------------------------

# Top Ultimate Breakout Indicator
# tomsk
# 1.22.2020

# V1.0 - 12.08.2019 - hoojsn - Initial release of Top Ultimate Breakout Indicator (syntax errors)
# V1.1 - 12.08.2019 - tomsk  - Cleared all syntax errors from initial hoojsn release
# V1.2 - 12.31.2019 - tomsk  - Removed all extraneous logic and variables not used by the study
# V1.3 - 01.02.2020 - tomsk  - Added ShowTodayOnly input selector to display current intraday levels
# V1.4 - 01.16.2020 - tomsk  - Added ShowEntryExitBands input selector, can be set to "no"
# v1.5 - 01.22.2020 - tomsk  - Added ShowBubbles input selector, to toggle display of bubbles

## Added supertrend - RCONNER7 03.30.2020 ##

# http://www.coinerpals.com/download-top-trade-tools-top-ultimate-breakout/
# https://bestforexfeatured.com/product/toptradetools-ultimate-breakout/

input BuyorSell = {default Buy, Sell};
input ShowTodayOnly = yes;
input ShowEntryExitBands = yes;
input ShowBubbles = yes;
input BuyEntry = 3;
input SellEntry = 3;
input BuyExit = 20;
input SellExit = 20;

input ATRLength = 50;
input TargetATRMult = 1;
input DisplayLines = yes;
input PriceDigit = 2;
#input OpenTime = 0940;
#input CloseTime = 1550;
#input notrades = 1550;
#def OpenGood = SecondsFromTime(OpenTime) >= 0 and SecondstillTime(notrades) >= 0;
#def CloseAllCondition = SecondstillTime(CloseTime) == 0;

def today = !showTodayOnly or getDay() == getLastDay() and SecondsFromTime(0930) >= 0;

# SuperTrend - YAHOO Finance ver.
input AtrMult = 1.2;
input nATR = 4;
input AvgType = AverageType.HULL;
input PaintBars = yes;

def ATR = ATR("length" = nATR, "average type" = AvgType);
def UP_Band_Basic = HL2 + (AtrMult * ATR);

def LW_Band_Basic = HL2 + (-AtrMult * ATR);

def UP_Band = if ((UP_Band_Basic < UP_Band[1]) or (close[1] > UP_Band[1])) then UP_Band_Basic else UP_Band[1];

def LW_Band = if ((LW_Band_Basic > LW_Band[1]) or (close[1] < LW_Band[1])) then LW_Band_Basic else LW_Band[1];

def ST = if ((ST[1] == UP_Band[1]) and (close < UP_Band)) then UP_Band else if ((ST[1] == UP_Band[1]) and (close > Up_Band)) then LW_Band else if ((ST[1] == LW_Band[1]) and (close > LW_Band)) then LW_Band else if ((ST[1] == LW_Band) and (close < LW_Band)) then UP_Band else LW_Band;

def ST_UP = ST < close;
def ST_DN = ST > close;

# High

def H1  = Highest(high, SellExit);
def H2  = fold i = 1 to SellExit
          with ip = 0.0
          do if GetValue(high, i) == H1 or GetValue(high, i) < ip
             then ip
             else GetValue(high, i);
def H3  = fold i1 = 1 to SellExit
          with ip1 = 0.0
          do if GetValue(high, i1) == H1 or GetValue(high, i1) == H2 or GetValue(high, i1) < ip1
             then ip1
             else GetValue(high, i1);
def HH  = (H2 + H3) / 2.0;

# Low

def L1  = Lowest(low, BuyExit);
def L2  = fold i2 = 1 to BuyExit
          with ip2 = 10000000.0
          do if GetValue(low, i2) == L1 or GetValue(low, i2) > ip2
             then ip2
             else GetValue(low, i2);
def L3  = Lowest(if low == L1 or low == L2 then 1000000 else low, BuyExit);
def LL  = (L2 + L2) / 2.0;

def QB = Highest(high, BuyEntry);
def QS = Lowest(low, SellEntry);

def ATRVal = ATR(length = ATRLength, averageType= AverageType.SIMPLE);
def mATR = Highest(ATRVal, ATRLength);


plot entry;
plot exit;

def EntryPr;
def pos;
def co = BarNumber() > Max(SellExit, BuyExit);

switch (BuyorSell) {

case Buy:
    entry = QB[1];
    exit = LL[1];
    pos = if ST_UP and co and high > QB[1] then 1 else if low < LL[1] then 0 else pos[1];
    EntryPr = if high > QB[1] and pos == 1 and pos[1] < 1
              then QB[1]
              else if pos == 0
                  then Double.NaN
              else EntryPr[1];
case Sell:
    entry = QS[1];
    exit = HH[1];
    pos = if ST_DN and co and low < QS[1] then -1 else if high[1] > HH[2] then 0 else pos[1];
    EntryPr = if low < QS[1] and pos == -1 and pos[1] > -1
              then QS[1]
              else if pos == 0
                  then Double.NaN
              else EntryPr[1];
}
entry.AssignValueColor(if BuyorSell == BuyorSell.Buy then Color.CYAN #GREEN
                       else if BuyorSell == BuyorSell.Sell then Color.RED
                       else Color.CURRENT);
entry.SetHiding(!ShowEntryExitBands);
exit.SetDefaultColor(Color.CYAN);
exit.SetHiding(!ShowEntryExitBands);

def BTarget;
def BTarget2;
def EntryLine;
def TradeRisk;

switch (BuyorSell) {

case Buy:
    BTarget  = if pos == 1 and pos[1] < 1
                   then (EntryPr + (TargetATRMult * 2 * mATR))
               else if pos == 1
                   then BTarget[1]
               else Double.NaN;
    BTarget2 = if pos == 1 and pos[1] < 1
                   then (EntryPr + 2 * (TargetATRMult * 2 * mATR))
               else if pos == 1
                   then BTarget2[1]
               else Double.NaN;
    EntryLine = if LL < EntryPr then EntryPr else Double.NaN;
    TradeRisk = (EntryPr - LL) / mATR;

case Sell:
    BTarget  = if pos == -1 and pos[1] > -1
                   then (EntryPr - (TargetATRMult * 2 * mATR))
               else if pos == -1
                   then BTarget[1]
               else Double.NaN;
    BTarget2 = if pos == -1 and pos[1] > -1
                   then (EntryPr - 2 * (TargetATRMult * 2 * mATR))
               else if pos == -1
                   then BTarget2[1]
               else Double.NaN;
    EntryLine = if HH > EntryPr then EntryPr else Double.NaN;
    TradeRisk = (HH - EntryPr ) / mATR;
}

plot pBTarget = if today and DisplayLines and co then BTarget else Double.NaN;
pBTarget.SetDefaultColor(Color.YELLOW);

plot pBTarget2 = if today and DisplayLines and co then BTarget2 else Double.NaN;
pBTarget2.SetDefaultColor(Color.MAGENTA);

plot pEntryLine = if today and DisplayLines and co then EntryLine else Double.NaN;
pEntryLine.SetDefaultColor(Color.WHITE);

def valco = DisplayLines and co and (pos == 1 or pos == -1) and pos[1] == 0;
def rBTarget = Round(BTarget, PriceDigit);
def rBTarget2 = Round(BTarget2, PriceDigit);
def rEntryPr = Round(EntryPr, PriceDigit);

AddChartBubble(ShowBubbles and today and valco, BTarget, rBTarget, Color.YELLOW);
AddChartBubble(ShowBubbles and today and valco, BTarget2, rBTarget2, Color.MAGENTA);
AddChartBubble(ShowBubbles and today and valco, EntryPr, rEntryPr, Color.WHITE);

def exv=if BuyorSell == BuyorSell.Buy then LL else HH;
def rexv = Round(exv, PriceDigit);
def rTradeRisk = Round(TradeRisk, PriceDigit);

AddChartBubble(ShowBubbles and today and valco, exv, rexv + "(" + rTradeRisk + "ATR)", Color.CYAN);
# End Top Ultimate Breakout Indicator

 

[barbaros]

@Chuck Thanks for sharing. Do you enter with the 1000t or 2000t?

 

[Chuck]

@tomsk, is it possible to add an option to show both BUY and SELL, also having the option to have previous targets disappear when trend changes?

That will make the system so much cleaner and easyer to navigate.

http://tos.mx/SQsC8zv

 

[Chuck]

barbaros, I set up and prepair for entry with the 1000 and enter once all the conditions are meet on the 2000, then depending on my risk tolerance I exit with the 1000 when it hits the ATR or if I can hang in their ....I prefer to exit on the 2000 as it hits the levels of tags the ATR, Just depends on if I think it is a continuation or reversal. I know I miss some of the body of the move, but I feel a probability of a longer run is better than being chopped up. Sometimes I will exit on the 1000 and wait it out to see if I will re-enter. To me the commission on a contract like /ES is worth sitting it out until confirmation of continuation. To each his own.

 

[barbaros]

@Chuck Sounds good. I'll watch this on the side on Monday. I like how you set up everything but colors are not my favorite. It's too busy. If it works well, I may clean it up a little and share the update.

 

[Chuck]

@Chuck Sounds good. I'll watch this on the side on Monday. I like how you set up everything but colors are not my favorite. It's too busy. If it works well, I may clean it up a little and share the update.

barbaros,

Have you used it any? Just curious I have been doing very well with it all week.

 

[barbaros]

barbaros,

Have you used it any? Just curious I have been doing very well with it all week.

I haven't had time to watch it on the side yet. Since there is a lot of action going on, I have been using my other screens. I'll let you know if I get to use it. Colors are a little blinding