Modify Script so as to not display the inputs

[Mike]

Does anyone know how I can change the partially modified script below so as to not display the inputs. I received the following errors:

Incompatible parameter: "XLRE" at 10:5
Expected double at 10:5
Expected class com.devexperts.tos.thinkscript.data.SymbolType at 17:29
Expected class com.devexperts.tos.thinkscript.data.SymbolType at 17:76

#
# TD Ameritrade IP Company, Inc. (c) 2015-2023
#

declare lower;

def price1 = FundamentalType.CLOSE;
def price2 = FundamentalType.CLOSE;
def symbol1 = ("SPY");
def symbol2 = ("XLRE");
def multiplier1 = 1.0;
def multiplier2 = 1.0;
def fastLength = 4;
def slowLength = 40;
def averageType = AverageType.SIMPLE;

plot Ratio = (multiplier1 * Fundamental(price1, symbol1)) / (multiplier2 * Fundamental(price2, symbol2));
plot FastAvg = MovingAverage(averageType, Ratio, fastLength);
plot SlowAvg = MovingAverage(averageType, Ratio, slowLength);

Ratio.DefineColor("Up", Color.UPTICK);
Ratio.DefineColor("Down", Color.DOWNTICK);
Ratio.AssignValueColor(if Ratio >= Ratio[1] then Ratio.Color("Up") else Ratio.Color("Down"));
FastAvg.SetDefaultColor(GetColor(1));
SlowAvg.SetDefaultColor(GetColor(4));

Thanks!

 

[BenTen]

You are supposed to use "input" not "def" and remove the parenthesis for symbol1 and symbol2.

#
# TD Ameritrade IP Company, Inc. (c) 2015-2023
#

declare lower;

def price1 = FundamentalType.CLOSE;
def price2 = FundamentalType.CLOSE;
input symbol1 = "SPY";
input symbol2 = "XLRE";
def multiplier1 = 1.0;
def multiplier2 = 1.0;
def fastLength = 4;
def slowLength = 40;
def averageType = AverageType.SIMPLE;

plot Ratio = (multiplier1 * Fundamental(price1, symbol1)) / (multiplier2 * Fundamental(price2, symbol2));
plot FastAvg = MovingAverage(averageType, Ratio, fastLength);
plot SlowAvg = MovingAverage(averageType, Ratio, slowLength);

Ratio.DefineColor("Up", Color.UPTICK);
Ratio.DefineColor("Down", Color.DOWNTICK);
Ratio.AssignValueColor(if Ratio >= Ratio[1] then Ratio.Color("Up") else Ratio.Color("Down"));
FastAvg.SetDefaultColor(GetColor(1));
SlowAvg.SetDefaultColor(GetColor(4));

I'm unsure why you would want to use "def" and not "input." That would create the error you see above.

 

[Mike]

@BenTen I actually modified the code by changing all of the lines containing "input" to "def" and added the parenthesis for symbol1 and symbol2 with the objective that input values would not be displayed in the chart title. I have changed "input" to "def" with other indicators that I have modified and been successful. Couldn't get it to work with this indicator. Any help would be appreciated. Thanks....

 

[BenTen]

@Mike For some, it will work and for some, it won't. Just depends on the use case, I guess. But so far, I've tried multiple variations and everything took me back to "input"

 

[Mike]

@Mike For some, it will work and for some, it won't. Just depends on the use case, I guess. But so far, I've tried multiple variations and everything took me back to "input"

Thanks. I tried several variations also before posting my request. Given your exceptional script knowledge, coupled with your attempts, guess I'll go back to "input" also

 

[ApeX Predator]

@Mike I am guessing what you are asking is not to display the Indicator name or the parameters on TOS screen or screenshots. if that is what you are looking we do not have the ability to mask those with scripting. However, you can do this with TOS settings though.

Click on the Wheel Icon, next to Studies, on General Tab, Under DataBox, Select "Fixed" and the "Autohide Status String".

Now there will be a pop-up window where all the stings, input values will go, but you can minimize that window, not close.

Let me know if that helps.

But I like leaving most of the definitions as Input, so that way I can customize the parameters based on my need as input instead of editing the scripts.

-Surya

 

[halcyonguy]

Does anyone know how I can change the partially modified script below so as to not display the inputs. I received the following errors:

Incompatible parameter: "XLRE" at 10:5
Expected double at 10:5
Expected class com.devexperts.tos.thinkscript.data.SymbolType at 17:29
Expected class com.devexperts.tos.thinkscript.data.SymbolType at 17:76

#
# TD Ameritrade IP Company, Inc. (c) 2015-2023
#

declare lower;

def price1 = FundamentalType.CLOSE;
def price2 = FundamentalType.CLOSE;
def symbol1 = ("SPY");
def symbol2 = ("XLRE");
def multiplier1 = 1.0;
def multiplier2 = 1.0;
def fastLength = 4;
def slowLength = 40;
def averageType = AverageType.SIMPLE;

plot Ratio = (multiplier1 * Fundamental(price1, symbol1)) / (multiplier2 * Fundamental(price2, symbol2));
plot FastAvg = MovingAverage(averageType, Ratio, fastLength);
plot SlowAvg = MovingAverage(averageType, Ratio, slowLength);

Ratio.DefineColor("Up", Color.UPTICK);
Ratio.DefineColor("Down", Color.DOWNTICK);
Ratio.AssignValueColor(if Ratio >= Ratio[1] then Ratio.Color("Up") else Ratio.Color("Down"));
FastAvg.SetDefaultColor(GetColor(1));
SlowAvg.SetDefaultColor(GetColor(4));

Thanks!

def can only assign a number to a variable, not text.
so you can't assign a stock symbol with def.
you can hard code the symbol, by putting a symbol inside a price function, to read a price.
. Fundamental(price1, "SPY"))
or
. def price1 = close("SPY");


this version has the symbol inside the fundamental function

declare lower;

def price1 = FundamentalType.CLOSE;
def price2 = FundamentalType.CLOSE;
#def symbol1 = ("SPY");
#def symbol2 = ("XLRE");
def multiplier1 = 1.0;
def multiplier2 = 1.0;
def fastLength = 4;
def slowLength = 40;
def averageType = AverageType.SIMPLE;
#plot Ratio = (multiplier1 * Fundamental(price1, symbol1)) / (multiplier2 * Fundamental(price2, symbol2));
plot Ratio = (multiplier1 * Fundamental(price1, "SPY")) / (multiplier2 * Fundamental(price2, "XLRE"));

#====================
# alt method
#def price1 = close("SPY");
#def price2 = close("XLRE");
#plot Ratio = (multiplier1 * price1) / (multiplier2 * price2);
#====================


plot FastAvg = MovingAverage(averageType, Ratio, fastLength);
plot SlowAvg = MovingAverage(averageType, Ratio, slowLength);

Ratio.DefineColor("Up", Color.UPTICK);
Ratio.DefineColor("Down", Color.DOWNTICK);
Ratio.AssignValueColor(if Ratio >= Ratio[1] then Ratio.Color("Up") else Ratio.Color("Down"));
FastAvg.SetDefaultColor(GetColor(1));
SlowAvg.SetDefaultColor(GetColor(4));
#