Market Phases Indicator for ThinkorSwim

[TechGuy]

Thanks for sharing. Here is the updated code that unplot the phases by default.

#Trend Advisor Market Phases;

#Credit to the Chuck Dukas for creating the system and for then author of the VolumeTrendLabels whose study was use to create this indicator. Ensure you set the correct aggregation period to then chart, this helps calculate the correct volume and price action.

def agg = getAggregationPeriod();
input vPeriod = AggregationPeriod.HOUR; #hint vPeriod: Enter the chart time you use here. Required to properly caluclate volume and price strength.

def O = open(period = vPeriod);
def H = high(period = vPeriod);
def C = close(period = vPeriod);
def L = low(period = vPeriod);
def V = volume(period = vPeriod);

def SV = V * (H - C) / (H - L);
def BV = V * (C - L) / (H - L);

# below determines if volume supports the move, adds conviction

AddLabel(yes, "Buyer Vol Strong ", if high > high[1] and low > low[1] and BV*1.05 > SV then Color.GREEN else color.black);

AddLabel(yes, "Seller Vol Strong", if high < high[1] and low < low[1] and SV*1.05 > BV then Color.MAGENTA else color.black);

# below determines if price supports the move

AddLabel(yes, "Price Strong ", if high > high[1] and high [1] > high[2] and low > low[1] and low[1] > low[2] then Color.GREEN else color.black);

AddLabel(yes, "Price Weak", if high < high[1] and high[1] < high[2] and low < low[1] and low[1] < low[2] then Color.MAGENTA else color.black);

declare upper;
input price = close;
input displace = 0;

input avglength = 10; #hint avgLength: Then exponential average length you want to use for your pullback entries.

def fastavg = 50;
def slowavg = 200;


plot fastsma = Average( price, fastavg);
fastsma.SetDefaultColor(Color.Green);

plot slowsma = Average(price, slowavg);
slowsma.SetDefaultColor(Color.Red);

# Bullish criteria define below

# Define criteria for Bullish Phase : close > 50 SMA, close > 200 SMA, 50 SMA > 200 SMA

def bullphase = fastsma > slowsma && price > fastsma && price > slowsma;

# Define criteria for Accumulation Phase : close > 50 SMA, close > 200 SMA, 50 SMA < 200 SMA

def accphase = fastsma < slowsma && price > fastsma && price > slowsma;

# Define criteria for Recovery Phase : close > 50 SMA, close < 200 SMA, 50 SMA < 200 SMA

def recphase = fastsma < slowsma && price < slowsma && price > fastsma;



# Bearish Criteria define below

# Define criteria for Bearish Phase : close < 50 SMA, close < 200 SMA, 50 SMA < 200 SMA

def bearphase = fastsma < slowsma && price < fastsma && price < slowsma;

# Define criteria for Distribution Phase : close < 50 SMA, close < 200 SMA, 50 SMA > 200 SMA

def distphase = fastsma > slowsma && price < fastsma && price < slowsma;

# Define criteria for Warning Phase : close < 50 SMA, close > 200 SMA, 50 SMA > 200 SMA

def warnphase = fastsma > slowsma && price > slowsma && price < fastsma;


# Below conditions are for a possible entry when price touches the fastema

#def pbavg = MovingAverage(Average, price, avglength);

def pbavg = ExpAverage(data = price[-displace], length = avglength);

input bullpullback = yes;  #hint bullpullback: Do you want to display the pullback arrows for bullish fast ema entries.
input bearpullback = yes; #hint bearpullback: Do you want to display the pullback arrows for bearish fast ema entries.

def bullishpb = low < pbavg && open > pbavg;
def bearishpb = high > pbavg && open < pbavg;

def bullpb = bullphase is true && bullishpb is true;
def bearpb = bearphase is true && bearishpb is true;

# Plot Signals
plot bullpb1 = if bullpullback then bullpb else 0;
bullpb1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
bullpb1.SetDefaultColor(Color.CYAN);
bullpb1.SetLineWeight(1);

plot bearpb1 = if bearpullback then bearpb else 0;
bearpb1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
bearpb1.SetDefaultColor(Color.red);
bearpb1.SetLineWeight(1);



#plot buphase = bullphase is true;
#plot acphase = accphase is true;
#plot rephase = recphase is true;

#plot bephase = bearphase is true;
#plot dphase = distphase is true;
#plot wphase = warnphase is true;


# Below adds labels to the chart to identify what phase the underlying is in


AddLabel(bullphase, " Bull Phase" , if bullphase is true then Color.GREEN else Color.BLACK);

AddLabel(accphase, " Accumation Phase ", if accphase is true then Color.lIGHT_GREEN else Color.BLACK);

AddLabel(recphase, " Recovery Phase ", if recphase is true then Color.lIGHT_ORANGE else Color.BLACK);

AddLabel(warnphase, " Warning Phase ", if warnphase is true then Color.orANGE else Color.BLACK);

AddLabel(distphase, " Distribution Phase ", if distphase is true then Color.light_red else Color.BLACK);

AddLabel(bearphase, " Bear Phase ", if bearphase is true then Color.red else Color.BLACK);


assignPriceColor(if bullphase then Color.GREEN else if bearphase then Color.RED else Color.orange);

Hi BenTen. Just set this great study up on a chart. I also put it in a bullish scan for stocks in accumulation mode. Can you take a look at my set up in the photo below and see if this is correct? Many thanks

 

[useThinkScript]

Hi BenTen. Just set this great study up on a chart. I also put it in a bullish scan for stocks in accumulation mode. Can you take a look at my set up in the photo below and see if this is correct? Many thanks

The best way to check your scans is to verify the results by looking at the charts.

In answer to your question:

acphase is true

should return stocks where accumulation phase is true.

 

[TechGuy]

The best way to check your scans is to verify the results by looking at the charts.

In answer to your question:


should return stocks where accumulation phase is true.

many thanks for your help and quick reply

 

[greekstrader]

@MerryDay @rewardiaz how about the labels in the "Market Phase Indicator located here:

https://usethinkscript.com/threads/market-phases-indicator-for-thinkorswim.1025/

I see labels that says "Buyer Volume Strong", "Seller Volume Strong" etc. on the chart labels, should I not take that in face value as well, and are they just broad and not very good assumptions?

 

[useThinkScript]

@MerryDay @rewardiaz how about the labels in the "Market Phase Indicator located here:

https://usethinkscript.com/threads/market-phases-indicator-for-thinkorswim.1025/

I see labels that says "Buyer Volume Strong", "Seller Volume Strong" etc. on the chart labels, should I not take that in face value as well, and are they just broad and not very good assumptions?

There is NO VOLUME ANALYSIS in the indicator in this thread.
ANY reference to buyer or seller volume is actually analyzing PRICE via lagging moving averages.

Wyckoff's Phases describes the behavior of price action not volume as it moves through periods of accumulation, markup, distribution, and markdown.

Google Wyckoff's Phases to understand more about the fundamental concept of accumulation-distribution.

VIP members can view Wyckoff's Phases applied to volume analysis here:
https://usethinkscript.com/threads/market-phase-vsa-candle-painting-indicator-for-thinkorswim.9275/

 

[DLCjr]

I edited the code so that the 'current phase' is permantly recorded in the candle color and so I could look back over the chart and see what the phase was during each candle of the day:

starting with line 135 the code needs to read:

input colorbars = yes;
assignPriceColor(
if !colorbars then color.current else
if bullphase then Color.GREEN else
if accphase then color.light_green else
if recphase then color.light_orange else
if warnphase then color.orange else
if distphase then color.light_red else
if bearphase then Color.RED else Color.current);

 

[Fortune99]

How do I change script to use different moving averages other than sma?

 

[useThinkScript]

How do I change script to use different moving averages other than sma?

Modified Market Phases with Moving Average Selectable In Settings

# Trend Advisor Market Phases (MA type selectable)

declare upper;
input price = close;
input displace = 0;

# ---- MA length inputs ----
input fastavg = 50;
input slowavg = 200;
input avglength = 10; # pullback average length

# ---- MA type inputs (choose Simple, Exponential, Weighted, Wilders, Hull) ----
input fastAvgType = AverageType.SIMPLE;    # default can be changed
input slowAvgType = AverageType.SIMPLE;
input pbAvgType   = AverageType.EXPONENTIAL;

# ---- compute moving averages using the chosen types ----
def fastMA = MovingAverage(fastAvgType, price[-displace], fastavg);
plot fastmaPlot = fastMA;
fastmaPlot.SetDefaultColor(Color.Green);

def slowMA = MovingAverage(slowAvgType, price[-displace], slowavg);
plot slowmaPlot = slowMA;
slowmaPlot.SetDefaultColor(Color.Red);

# ---- pullback average (used for entries) ----
def pbavg = MovingAverage(pbAvgType, price[-displace], avglength);


# price/volume defs & labels
def O = open;
def H = high;
def C = close;
def L = low;
def V = volume;
def SV = V * (H - C) / (H - L);
def BV = V * (C - L) / (H - L);

AddLabel(yes, "Buyer Vol Strong ", if high > high[1] and low > low[1] and BV*1.05 > SV then Color.GREEN else color.black);
AddLabel(yes, "Seller Vol Strong", if high < high[1] and low < low[1] and SV*1.05 > BV then Color.MAGENTA else color.black);
AddLabel(yes, "Price Strong ", if high > high[1] and high [1] > high[2] and low > low[1] and low[1] > low[2] then Color.GREEN else color.black);
AddLabel(yes, "Price Weak", if high < high[1] and high[1] < high[2] and low < low[1] and low[1] < low[2] then Color.MAGENTA else color.black);

# Phases using fastMA & slowMA
def bullphase = fastMA > slowMA && price > fastMA && price > slowMA;
def accphase  = fastMA < slowMA && price > fastMA && price > slowMA;
def recphase  = fastMA < slowMA && price < slowMA && price > fastMA;

def bearphase = fastMA < slowMA && price < fastMA && price < slowMA;
def distphase = fastMA > slowMA && price < fastMA && price < slowMA;
def warnphase = fastMA > slowMA && price > slowMA && price < fastMA;

# pullback signals (use pbavg)
input bullpullback = yes;
input bearpullback = yes;

def bullishpb = low < pbavg && open > pbavg;
def bearishpb = high > pbavg && open < pbavg;

def bullpb = bullphase and bullishpb;
def bearpb = bearphase and bearishpb;

plot bullpb1 = if bullpullback and bullpb then 1 else Double.NaN;
bullpb1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
bullpb1.SetDefaultColor(Color.CYAN);
bullpb1.SetLineWeight(1);

plot bearpb1 = if bearpullback and bearpb then 1 else Double.NaN;
bearpb1.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
bearpb1.SetDefaultColor(Color.RED);
bearpb1.SetLineWeight(1);

# phase plots (hidden) + labels
plot buphase = bullphase; buphase.Hide();
plot acphase = accphase; acphase.Hide();
plot rephase = recphase; rephase.Hide();
plot bephase = bearphase; bephase.Hide();
plot dphase = distphase; dphase.Hide();
plot wphase = warnphase; wphase.Hide();

AddLabel(bullphase, " Bull Phase" , if bullphase then Color.GREEN else Color.BLACK);
AddLabel(accphase, " Accumation Phase ", if accphase then Color.LIGHT_GREEN else Color.BLACK);
AddLabel(recphase, " Recovery Phase ", if recphase then Color.LIGHT_ORANGE else Color.BLACK);
AddLabel(warnphase, " Warning Phase ", if warnphase then Color.ORANGE else Color.BLACK);
AddLabel(distphase, " Distribution Phase ", if distphase then Color.LIGHT_RED else Color.BLACK);
AddLabel(bearphase, " Bear Phase ", if bearphase then Color.RED else Color.BLACK);

input colorbars = yes;
assignPriceColor(
    if !colorbars then color.current else
    if  bullphase then Color.GREEN else
    if bearphase then Color.RED else Color.current);

Alert(condition = bullphase[1] and !bullphase, text = "Bull Phase", sound = Sound.Bell, "alert type" = Alert.BAR);
Alert(condition = accphase[1] and !accphase, text = "Accumation Phase", sound = Sound.Bell, "alert type" = Alert.BAR);
Alert(condition = recphase[1] and !recphase, text = "Recovery Phase", sound = Sound.Bell, "alert type" = Alert.BAR);
Alert(condition = warnphase[1] and !warnphase, text = "Warning Phase", sound = Sound.Bell, "alert type" = Alert.BAR);
Alert(condition = distphase[1] and !distphase, text = "Distribution Phase", sound = Sound.Bell, "alert type" = Alert.BAR);
Alert(condition = bearphase[1] and !bearphase, text = "Bear Phase", sound = Sound.Bell, "alert type" = Alert.BAR);