Madrid Bull Bear Sentiment For ThinkOrSwim

[petergluis]

Madrid Bull Bear Sentiment provides the overall bull bear sentiment. It will be nice to have ThinkorSwim version. Thank you very much for your help.

Here is the link of the indicator with Pinescript.
https://www.tradingview.com/script/f9OdIHQf-Madrid-Bull-Bear-Sentiment/

 

[ApeX Predator]

Madrid Bull Bear Sentiment provides the overall bull bear sentiment. It will be nice to have ThinkorSwim version. Thank you very much for your help.

Here is the link of the indicator with Pinescript.

https://www.tradingview.com/script/f9OdIHQf-Madrid-Bull-Bear-Sentiment/

@petergluis Try this and let me know.

#Madrid Bull Bear Sentiment
#Coverted by @SuryaKiranC
#Requested by @petergluis
#Requested at https://usethinkscript.com/threads/madrid-bull-bear-sentiment-for-thinkorswim.9254
#Original Source https://www.tradingview.com/script/f9OdIHQf-Madrid-Bull-Bear-Sentiment/

declare lower;
declare real_size;
input src = close;
input len = 18;

def OB = 76.4;
def OS = 23.6;

input smooth = yes;
input lowerBand = 5;

script nz {
    input data = 0;
    def ret_val = if isNaN(data) then 0 else data;
    plot return = ret_val;
}

script ssFilter {
    input price = close;
    input lowerBand = 5;
    def PI= 3.14159265358979;

    def angle = sqrt(2) *PI/lowerBand;
    def a1= exp(-angle);
    def b1 = 2*a1*cos(angle);
    def c2 = b1;
    def c3 = -a1*a1;
    def c1 = 1 - c2 -c3;
    def filt = c1*(price + nz(price[1]))/2 + c2*nz(filt[1]) + c3*nz(filt[2]);
    plot c = filt;
};

script sentiment {
    input lowerBand = 5;
    input len = 18;
    input src = close;
    def lowest = lowest(src,len);
    def highest = highest(src,len);
    def diffBull = (src-lowest)*100/lowest;
    def diffBear = (highest-src)*100/highest;
    def bbs = diffBull*100/(diffBear + diffBull);

plot bbSentiment = ssFilter(bbs,lowerBand = lowerBand);
};

plot sentiment = sentiment(len = len);

plot OverBought = OB ;
OverBought.SetDefaultColor(Color.WHITE);
plot mid = 50;
mid.SetDefaultColor(Color.WHITE);
plot OverSold = OS;
OverSold.SetDefaultColor(Color.WHITE);
AddCloud(sentiment,lowestall(sentiment), Color.GREEN);
AddCloud(highestall(sentiment),sentiment, Color.RED);
#End

Add the below code at the end of the main study script. For scan set a custom study filter, with MadridBulBearSentiment()."Bear" or MadridBulBearSentiment()."Bull" as a string.

def Bull = if sentiment > OverSold and sentiment > sentiment[1] then 1 else Double.NaN;
def Bear = if sentiment < OverBought and sentiment < sentiment[1] then -1 else Double.NaN;

plot scan = (Bull or Bear);
scan.SetHiding(1);

If you want audible alerts, add the following too.

input audibleAlerts = yes;

AddLabel(Yes,Sentiment,Color.Yellow);
Alert(audibleAlerts and Bull, "Sentiment Bullish", Alert.BAR, Sound.Ding);
Alert(audibleAlerts and Bear, "Sentiment Bearish", Alert.BAR, Sound.Ring);

 

[petergluis]

It is very nice. Thank you very much for this wonderful job. I would like to know whether you can have a scan feature based on this indicator.

 

[mashume]

It is very nice. Thank you very much for this wonderful job. I would like to know whether you can have a scan feature based on this indicator.

How, out of curiosity, are you using this... primary signals, confirmation, it looks interesting but there isn't much around on how it's being used. Any thoughts you'd want to share with us all?

thanks
-mashume

 

[petergluis]

I often use it to find when a stock or an ETF to reach short-term bottoms or tops. I modified this indicator by adding more signal lines so that we detect whether the uptrend can continue. I will learn how to insert images to this reply later as I tried a couple of times and failed by using inserting icon above.

 

[ApeX Predator]

if you are looking for a scanner or alerts look for edit in https://usethinkscript.com/threads/madrid-bull-bear-sentiment-for-thinkorswim.9254/post-86769

 

[petergluis]

if you are looking for a scanner or alerts look for edit in https://usethinkscript.com/threads/madrid-bull-bear-sentiment-for-thinkorswim.9254/post-86769

Thank you very much for the excellent information.