How can I determine what the Stock price is compared to the option price?

METAL

Active member
Plus
I hope I am asking this clearly. When I have two charts, One with the Option Call/Put and i have the stock on other chart, When I am trying to determine a good SL point based off the Stock chart, How do I know where that price is on the Options chart? I am using Active Trader at the moment and was wandering if there is a clear way to figure this out. Thanks in advance.
 
Solution
Stop levels are just support resistance levels based on how much risk your willing to take.

If you look at the “confirmation candles” study you will see a dashed line which is/or could be used as a trailing stop loss.

When you have an options chart open next to the underlying chart you go to settings and select the setting to show the crosshairs across all charts.

If you are looking at or near the money options they follow the underlying pretty well which is why most people don’t look at the option chart (in my opinion)

If your using the scalper study you could use the supply/demand zones for stops probably best to use a trailing stop I would image (idk I need to start using a stop so I’m still figuring it out)
Stop levels are just support resistance levels based on how much risk your willing to take.

If you look at the “confirmation candles” study you will see a dashed line which is/or could be used as a trailing stop loss.

When you have an options chart open next to the underlying chart you go to settings and select the setting to show the crosshairs across all charts.

If you are looking at or near the money options they follow the underlying pretty well which is why most people don’t look at the option chart (in my opinion)

If your using the scalper study you could use the supply/demand zones for stops probably best to use a trailing stop I would image (idk I need to start using a stop so I’m still figuring it out)
 
Solution
Thanks for the reply @HODL-Lay-HE-hoo! I am pretty familiar with what you suggested. What I am looking for is an accurate way to pinpoint the area at which I believe should be an out or and in from the "Stock" chart and know where that would be approximately on the options chart. Right now, if I place a stop on the options chart, it doesn't align with lets say a high/low on the "stock" chart.
My goal is to locate a point of interest on "stock" chart and know where that will be on and "options" chart. I believe I have seen a study that would give the options price from the "stock" chart but I cannot locate it.
 
I hope I am asking this clearly. When I have two charts, One with the Option Call/Put and i have the stock on other chart, When I am trying to determine a good SL point based off the Stock chart, How do I know where that price is on the Options chart? I am using Active Trader at the moment and was wandering if there is a clear way to figure this out. Thanks in advance.

maybe this can show you an option price close enough to what you need..


start out by adding an option symbol to a watchlist and selecting it.
i used this
.WMT220916C132 WMT 9/16 call $132

add this study, and enter your option parameters , that match what you added to the watchlist.

if needed, calibrate the option price by adjusting the interest number until the yellow line matches fairly closely to the other line. (i changed the example interest from 0.06 to 0.01)


change the study to a lower , ( remove the # in front of declare lower; )

go to edit studies and enter a stop loss price. ( ex. 132)
it will draw a horizontal line on each day for the estimated option price, based on a stock price equal to the stoploss.


Code:
# option_stop_price_01

# https://usethinkscript.com/threads/how-can-i-determine-what-the-stock-price-is-compared-to-the-option-price.12446/
# How can I determine what the Stock price is compared to the option price?
# METAL  8/31  #1

# I hope I am asking this clearly. When I have two charts, One with the Option Call/Put and i have the stock on other chart, When I am trying to determine a good SL point based off the Stock chart, How do I know where that price is on the Options chart? I am using Active Trader at the moment and was wandering if there is a clear way to figure this out. Thanks in advance.

# declare lower;

# wmt  #132.60  on 8/31

input underlying = "WMT";
#def stock_price = close;
def stock_price = close(underlying);

addlabel(1, " ", color.black);
addlabel(1, underlying, color.yellow);
addlabel(1, "stock $ " + round(stock_price, 2), color.yellow);


input strike = 132.0;
input expiration_date = 20220916;
input is_put = no;
#input interest_rate = 0.06;
input interest_rate = 0.01;
input yield = 0.0;
input is_european = no;


def iv;
if GetAggregationPeriod() < AggregationPeriod.DAY {
    iv = imp_volatility(underlying, AggregationPeriod.DAY);
} else {
    iv = imp_volatility(underlying);
}

# actual
plot TheoOptPrice = OptionPrice(strike, is_put, DaysTillDate(expiration_date), stock_price, iv, is_european, yield, interest_rate);
TheoOptPrice.setdefaultcolor(color.yellow);


# +- stop loss
input stk_stop_loss = 132.0;

addlabel(1, " ", color.black);
addlabel(1, "stoploss " + stk_stop_loss, color.cyan);

def stk_price2 = stk_stop_loss;
plot TheoOptPrice2 = OptionPrice(strike, is_put, DaysTillDate(expiration_date), stk_price2, iv, is_european, yield, interest_rate);
TheoOptPrice2.setdefaultcolor(color.cyan);
#

.WMT220916C132 WMT 9/16 call $132
stoploss set to 132
aBWYgRS.jpg


https://tlc.thinkorswim.com/center/reference/thinkScript/Functions/Option-Related/OptionPrice
 
Last edited:
@METAL well first off DONT YELL AT ME METAL!…. Jay kay…. Ok so you are not referring to like when you put your mouse over a candle at 2:00pm on spy then being able to see that same place on the chart for the spy option?
 
@METAL also the study (shared with the grid I posted in confirmation candles) “ATM call/put” plots the atm call and put price as a horizontal line on the chart which I’m sure could be adjusted to show any specific option strike exp etc.
 
Can the Mobius study below be altered to obtain the option price as opposed to adjusting the interest or yield? (it plots a line on any underlying and shows the price of the at the money strike call and put)


Code:
# Black Scholes Option Plot Series 2 Weekly
# ATM Strike Call and Put
# Mobius at MyTrade

input series = 2; #hint series: 2 is weekly. Anything else and change DaysToExpiration to match.
input DaysToExpiration = 0; #hint DaysToExpiration: 0 = Weekly. For all others change Series to match.
input showLabel = yes;

addLabel(DaysToExpiration != 0, "Change series to match Days To Expiration", color.pink);

def RTHopen = getTime() crosses above RegularTradingStart(getYYYYMMDD());
def c = close;
def DOW = getDayOfWeek(getYYYYMMDD());
def DTE = if DaysToExpiration == 0
          then (if DOW == 5
                then 3
                else if DOW == 4
                then 4
                else if DOW == 3
                then 3
                else if DOW == 2
                then 3
                else if DOW == 1
                then 3
                else 1)
          else DaysToExpiration;
def Strike = if c < 300 and Average(volume(period = AggregationPeriod.DAY), 10) > 20000000
             then RoundDown(c / .5, 0) * .5
             else if c < 300 and Average(volume(period = AggregationPeriod.DAY)[1], 10) < 20000000
                  then Floor(c)
                  else if Between(Floor(c), 300, 500)
                       then Round(Floor(c) / 5, 0) * 5
                       else if Between(Floor(c), 500, 1000)
                            then Round(Floor(c) / 5, 0) * 5
                            else if c > 1000
                                 then Round(Floor(c) / 10, 0) * 10
                            else Floor(c);
def strike_ = if isNaN(strike)
              then strike_[1]
              else strike;
def t = DTE / 365;
def seriesIV = if IsNaN(SeriesVolatility(series = series))
               then seriesIV[1]
               else SeriesVolatility(series = series);
def rate  = ((GetInterestRate() / 365) * DTE);
def CurrDivi = if IsNaN(GetDividend())
               then CurrDivi[1]
               else GetDividend();
def LastDividend = if CurrDivi != CurrDivi[1]
                   then CurrDivi[1]
                   else LastDividend[1];
def YearlyDiv = if LastDividend == 0
                then CurrDivi * 4
                else if LastDividend < CurrDivi
                     then (LastDividend * 3) + CurrDivi
                     else YearlyDiv[1];
def DivYeild = YearlyDiv / c;
def LogR = Log(c / Strike);
def Denominator = LogR + (rate - DivYeild + Power(seriesIV, 2) / 2) * t;
def Divisor = seriesIV * Sqrt(t);
def D1 = Denominator / Divisor;
def D2 = D1 - seriesIV * Sqrt(t);
# Abramowiz Stegun Approximation for Cumulative Normal Distribution
script cnd
    {
     input data  = 1;
     def a = AbsValue(data);
     def b1 =  .31938153;
     def b2 = -.356563782;
     def b3 = 1.781477937;
     def b4 = -1.821255978;
     def b5 = 1.330274429;
     def b6 =  .2316419;
     def e = 1 / (1 + b6 * a);
     def i = 1 - 1 / Sqrt(2 * Double.Pi) * Exp(-Power(a, 2) / 2) *
            (b1 * e + b2 * e * e + b3 * Power(e, 3) + b4 * Power(e, 4) + b5 * Power(e, 5));
     plot CND = if data < 0
                then 1 - i
                else i;
    }
def Call = (c * cnd(D1) - Strike * Exp(-rate * t) * cnd(D2));
def call_ = if isNaN(call)
            then call_[1]
            else call;
def put = (Strike * Exp(-rate * t) * cnd(-D2) - c * cnd(-D1));
def put_ = if isNaN(put)
           then put_[1]
           else put;
def tBar = if isNaN(close[-1]) and !isNaN(close)
           then barNumber()
           else tBar[1];
plot StrikeLine = if barNumber() >= highestAll(tBar)
                  then highestAll(if isNaN(close[-1])
                                  then Strike_
                                  else double.nan)
                  else double.nan;
addChartBubble(barNumber() == HighestAll(barNumber()),
               StrikeLine,
              "C " + AsDollars(Call_),
               color.green,
               yes);
addChartBubble(barNumber() == HighestAll(barNumber()),
               StrikeLine,
              "P " + AsDollars(Put_),
               color.red,
               no);
addLabel(showLabel, "D.O.W. = " + DOW +
                  " | Day to Expiry on B.S. Study = " + DTE +
                  " | Series " + series + " IV = " + AsPercent(seriesIV), color.white);
# End Code
 

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
491 Online
Create Post

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top