Best way to determine last occurrence of a pattern without HighestAll()

[armybender]

Hi All,

I have a study that looks for peaks and valleys (i.e. high > high[1] and high > high[-1]). Of course, these occur quite often, and I'm interested in finding the LAST occurrence of the pattern WITHOUT USING HIGHESTALL().

Reason for not wanting to use HighestAll() is that I want it to update on every tick, and HighestAll() puts it into a once-per-bar mode.
https://usethinkscript.com/threads/...e-no-update-in-real-time-in-thinkorswim.8794/
I've tested this thoroughly and know that to be the case.

What's the best method for this?

Any help is appreciated.

Thanks!

 

[halcyonguy]

Hi All,

I have a study that looks for peaks and valleys (i.e. high > high[1] and high > high[-1]). Of course, these occur quite often, and I'm interested in finding the LAST occurrence of the pattern WITHOUT USING HIGHESTALL().

Reason for not wanting to use HighestAll() is that I want it to update on every tick, and HighestAll() puts it into a once-per-bar mode.
https://usethinkscript.com/threads/...e-no-update-in-real-time-in-thinkorswim.8794/
I've tested this thoroughly and know that to be the case.

What's the best method for this?

Any help is appreciated.
hal_last
Thanks!

find the last signal on a chart

define a signal
find the signal barnumbers
define a bar 50 bars from the last bar
jump to the last bar and find the highest signal barnumber
plot an arrow when highest signal barnumber = barnumber

draw cyan dots on all signals
draw arrow on last signal

# last_signal_0

#https://usethinkscript.com/threads/best-way-to-determine-last-occurrence-of-a-pattern-without-highestall.16768/
#find last signal

def bn = BarNumber();
def na = Double.NaN;

#def signal = (bn % 12 ) == 0;
#def signal = (high > high[1] and high > high[-1]);
def signal = (high >= high[1] and high >= high[-1]);

# use a number, same as negative offset in signal formula
def sig_offset = 1;

# running count of signal
def cnt = if bn == 1 then 0 else if signal then cnt[1] + 1 else cnt[1];

def sigbn = if bn == 1 then 0
 else if signal then bn
 else sigbn[1];

def n = 50;

def x = !IsNaN(close[-(n - 1)]) and
IsNaN(close[-n]);

input vert_line = no;
addverticalline(vert_line and x, "-", color.cyan);

def lastbn = if bn == 1 then 0
else if x then Highest(sigbn[-(n - 1 - sig_offset)], (n - sig_offset))
else lastbn[1];

def last = if lastbn == bn then 1 else 0;

plot z1 = if last then high*1.0001 else na;
z1.SetPaintingStrategy(PaintingStrategy.ARROW_down);
z1.SetDefaultColor(Color.green);
z1.setlineweight(3);
z1.hidebubble();

input show_all_signals = yes;
plot z2 = if show_all_signals and signal then low*0.999 else na;
z2.SetPaintingStrategy(PaintingStrategy.points);
z2.SetDefaultColor(Color.cyan);
z2.setlineweight(2);
z2.hidebubble();

input test1 = no;
addchartbubble(test1, low,
bn + "\n" +
signal + " s\n" +
sigbn + " sbn\n" +
x + " x\n" +
lastbn + " Lbn\n" +
last + " L\n" 
, (if signal then color.yellow else color.gray), no);
#

i randomly picked 50 because i guessed there should be at least 1 signal in the last 50 bars on chart. if not, make it bigger.