HOT ZONE - RSI with IV Percentile: Buy Stock or Sell Put Options Signal For ThinkOrSwim

[tdav2000]

Thanks for the indicator.

Regarding the watchlist, it seems it does not specify the lookback period? Would we specify the label to show up to a defined no. of bars?

Cheers

 

[chewie76]

Thanks for the indicator.

Regarding the watchlist, it seems it does not specify the lookback period? Would we specify the label to show up to a defined no. of bars?

Cheers

You can use the indicator in a scan. Then in the scan you can select a lookback period.

 

[Slippage]

I am looking for to add the background color when any label shows up and somehow its not working for the watchlist column.
Can someone please help with this as tried many version but no luck.
Currently its showing just label with for e.g. "UP" or "DOWN" or "HOT" or "CAUTION" but with black background. I can see the label are correctly colored but background cell also need to be colored.

Here the link to watchlist column :

https://usethinkscript.com/threads/...k-or-sell-put-options-signal.3989/#post-36678

Looking for a watchlist column? Here you go!
HOTZONE RSI Watchlist: http://tos.mx/wjdMkBz

AssignBackgroundColor(if DownSignal then color.RED else if Upsignal then color.GREEN else color.black);

AddLabel(yes, if Upsignal then "UP" else if Downsignal then "DOWN" else if RSIIV then “HOT” else if RSIIV1 then "CAUTION" else " ", if UPsignal then color.green else if Downsignal then color.red else if RSIIV then color.RED else if RSIIV1 then color.YELLOW else Color.black);

@BenTen @chewie76

Unfortunately, the scan right now is only giving me 2 results. One caution and one with no text. The caution has black bg which is correct per the code.

I modified your AssignBackgroundColor() call to use plum instead of black and it's still black.

Next, I commented out your call and I added these two lines:

def x = 1;
AssignBackgroundColor(if x then color.RED else if Upsignal then color.GREEN else color.black);

This correctly gave me yellow text on red background. Usually when you get weirdness like this something is Double.NaN. I don't see the problem here, though. Those variables were already used to determine the label text and that worked okay. I even printed them to labels and confirmed the up and down signal vars are both zero.

If I reverse the conditions so it checks Upsignal before x it fails. For some reason it's choking using those variables in this function call. I tried spelling out the condition again if RSI crosses above OverSold instead of using the variable and even that fails.

You might want to contact support on this one.

 

[woaitzsuperman]

Appreciate the amazing script. I have a couple questions. So I noticed that the IV percentile figures is different from when I look up the same ticker percentile on let's say barchart. Any idea the discrepancy? The difference varies widely.

EDIT: Ah this is tracking IV rank and not percentile. Is this indicator supposed to be used on daily timeframe only or can we use this for hourly?

 

[chewie76]

Appreciate the amazing script. I have a couple questions. So I noticed that the IV percentile figures is different from when I look up the same ticker percentile on let's say barchart. Any idea the discrepancy? The difference varies widely.

EDIT: Ah this is tracking IV rank and not percentile. Is this indicator supposed to be used on daily timeframe only or can we use this for hourly?

Any timeframe works, but I suggest 15-30 min for day trading. 4 hr for swing trading.

 

[poststreet]

do the yellow and red dots repaint?

 

[chewie76]

do the yellow and red dots repaint?

Once the candle closes, it will not repaint.

 

[Mindlessmentor]

So I really like this indicator but I don't know how to properly use it. Any videos that explain it? thank you

 

[chewie76]

So I really like this indicator but I don't know how to properly use it. Any videos that explain it? thank you

Don't have a video on it. Page 1 has some good description and pictures as example entries and exits.

 

[Ronathan Edwards]

You have to have multiple columns for each time frame. Each column needs to be labelled differently.

Forgive me please, but isn't that a different watchlist and not a different column? I don't see how you can have different column without changing the formula. Or else the hotzone column is dictated by the time on the scan itself and that would have to be a different watchlist for that scan? I know I'm wrong, but that's where I'm at...

 

[MerryDay]

@Ronathan Edwards There are many ways to skin this cat. Lets try another a step-by-step approach

HOTZONE RSI Watchlist: http://tos.mx/wjdMkBz

1. Hover your mouse over the above link
2. Right-click, chose copy link address
3. In TOS, click on gear icon at top of TOS app
4. Click on Open Shared Item
5. Ctrl-V to paste link address
6. Click on Preview
7. Name the study: HZ1
8. Click Import

Now lets do it again

1. In TOS, click on gear icon at top of TOS app
2. Click on Open Shared Item
3. Ctrl-V to paste link address
4. Click on Preview
5. Name the study: HZ15
6. Click Import

Ok Now Let's go to your watchlist
click on the gear to the right of your watchlist
click on Customize

Type the name HZ1 in the box
click on Add Item
click on OK
Lets do it again only this time type HZ15 in the box.

You now have your two columns BUT you need to fix the aggregations. So again
click on the gear to the right of your watchlist
click on Customize
Type the name HZ1 in the box. Click on the scroll to open the edit set the aggregation to 1min
Do the same thing for the HZ15 column

 

[bigshow3]

It's gonna get heated up with the Hot Zone indicator! Hope you like it. It is a combination of RSI with IV percentile. The red colored area where IV is greater than RSI is the Hot Zone. Inside the Hot Zone are some colored circles on the midline. A yellow circle is a caution warning. This means it could be a good buy, but be cautious because it is a weak signal. The red circle is the HOT warning. This means it's time to buy or sell put options.

NOTE: there may be a string of red circles, so the first one that appears may not be the best entry because more could follow. You'll want to see the RSI and IV come back together for extra confirmation. Another confirmation is the ZSCORE upper indicator on this forum. Below are a few examples.

This indicator works great with the BTD indicator. Enjoy heating up your account with the Hot Zone!

This is an example of CWH on a daily chart.

This is an example of SPY on 12/24/2019. It showed the EXACT low! Then it ripped higher for the next 4 months.

This is an example of TSLA. 3 days this year were HOT buys in the middle of March 2020.

There is another version of this indicator that @FateOwnzYou helped make. SHOUT OUT to you fellow scripter! You're awesome! This version is cleaner to the eye and basically subtracts the RSI from IV and makes one single line so the greater the distance between them the further down the Hot Zone goes. I added the yellow and red circles, but you may want to adjust these settings for your trading style. The only negative is you don't actually see the actual RSI indicator, and some people who already use RSI would probably prefer using the other version to keep the RSI. The clear advantage is it gives clear buy and sell areas. Under the green line is a buy area. Over the red line is a sell area shaded in green (collect your cash money!) . (Any area in red could be considered a buy area, but the closer to the green line, the better.)

Lets look at a DAY TRADE in /RTY. Look at both of these Hot Zone indicators. Notice the one on the bottom. Circled areas for buys and sells.

Here is an example of QQQ on a daily chart. Notice the HOT circles and buy area on lower indicator and the sell areas.

Added ARROWS to the indicator. See below.

Below is an example of day trading /RTY using a 2 min chart. Look at the sell signal arrow and the two red hot buy dots that are highlighted, both followed by green buy arrows.

Hot Zone-RSI

#HOTZONE-RSI: RSI-IV_percentile indicator
#developed by Chewie76 9-30-2020
### Global Variables ###
declare lower;
input length = 14;
input over_Bought2 = 80;
input over_Bought = 70;
input over_Sold = 30;
input over_Sold2 = 20;
input price = close;
input averageType = AverageType.WILDERS;
input showBreakoutSignals = yes;
input alertsOn = yes;
input ChartBubblesOn = yes;

### RSI ###
def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

plot RSI = 50 * (ChgRatio + 1);
plot MiddleLine = 50;
Middleline.SetDefaultColor(Color.YELLOW);
RSI.SetLineWeight(2);

plot OverSold = over_Sold;
plot OverBought = over_Bought;
plot UpSignal = if RSI crosses above OverSold then OverSold else Double.NaN;
plot DownSignal = if RSI crosses below OverBought then OverBought else Double.NaN;

AddCloud(Over_Bought2, OverBought, Color.dark_RED, Color.CURRENT);
AddCloud(OverSold, Over_Sold2, Color.dark_GREEN, Color.CURRENT);

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

RSI.DefineColor("OverBought", color.red);
RSI.DefineColor("Normal", GetColor(9));
RSI.DefineColor("OverSold", color.green);
RSI.AssignValueColor(if RSI > over_Bought then RSI.Color("OverBought") else if RSI < over_Sold then RSI.Color("OverSold") else RSI.Color("Normal"));
OverSold.SetDefaultColor(color.green);
OverBought.SetDefaultColor(color.red);
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

AddCloud(RSI, OverBought, Color.RED, Color.CURRENT);
AddCloud(OverSold, RSI, Color.GREEN, Color.CURRENT);

### IVPercentile ###
def vol = imp_volatility();
input TimePeriod = 252;

def data = if !isNaN(vol) then vol else vol[-1];
def hi = highest(data, TimePeriod);
def lo = lowest(data, TimePeriod);
plot Percentile = (data - lo) / (hi - lo) * 100;
def lowend = Percentile < 25;
def highend = Percentile > 50;

input over_Bought1 = 98;
input over_Sold1 = 2;

Percentile.DefineColor("OverBought", Color.red);
Percentile.DefineColor("Normal", color.magenta);
Percentile.DefineColor("OverSold", Color.GREEN);
Percentile.AssignValueColor(if Percentile > over_Bought1 then Percentile.color("OverBought") else if Percentile < over_Sold1 then Percentile.color("OverSold") else Percentile.color("Normal"));

AddCloud(percentile, rsi, Color.RED, Color.CURRENT);

### Squeeze Relationship (RSI and IV) ###
def RSIIV = if percentile - RSI >= 40 and RSI < 32 then 1 else 0;
plot HOT = if RSIIV then 50 else Double.nan;
HOT.SetPaintingStrategy(PaintingStrategy.POINTS);
HOT.SetLineWeight(4);
HOT.SetDefaultColor(Color.RED);

def RSIIV1 = if (percentile - RSI >= 30 and RSI > 32 and RSI < 40, 1, Double.NaN);
plot CAUTION = if RSIIV1 then 50 else Double.nan;
CAUTION.SetPaintingStrategy(PaintingStrategy.POINTS);
CAUTION.SetLineWeight(4);
CAUTION.SetDefaultColor(Color.YELLOW);

#Label

def bullish = if RSI > MiddleLine then 1 else 0;
def bearish = if RSI < MiddleLine then 1 else 0;

AddLabel(ChartBubblesOn, if bullish then "BULLISH" else if bearish then "BEARISH" else if RSI > 100 then "hi" else "low", if bullish then color.green else if bearish then color.red else color.black);


def condition1 = percentile - RSI >= 40 and RSI < 32;
def condition2 = percentile - RSI >= 30 and RSI > 32 and RSI < 40;

# Alert
Alert(alertsOn and condition1, "HOT", Alert.BAR, Sound.Chimes);
Alert(alertsOn and condition2, "CAUTION", Alert.BAR, Sound.bell);

Shareable link: http://tos.mx/9zhE6eE

Hot Zone line

#HOTZONE LINE: RSI-IV_percentile indicator
#developed by Chewie76 with help from FateOwnzYou 9-30-2020

### Global Variables ###
declare lower;
input length = 14;
input price = close;
input averageType = AverageType.WILDERS;
input showBreakoutSignals = yes;
input alertsOn = yes;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

def RSI = (50 * (ChgRatio + 1))*-1;
plot MiddleLine = 0;
plot TakeProfit = 60;
plot BUY = -60;
TakeProfit.SetLineWeight(1);
TakeProfit.SetDefaultColor(Color.RED);
BUY.SetLineWeight(1);
BUY.SetDefaultColor(Color.GREEN);

def vol = imp_volatility();
input TimePeriod = 252;

def data = if !isNaN(vol) then vol else vol[-1];
def hi = highest(data, TimePeriod);
def lo = lowest(data, TimePeriod);
def Percentile = ((data - lo) / (hi - lo) * 100)*-1;
def lowend = Percentile < 25;
def highend = Percentile > 50;

plot HotZone = percentile - rsi;
HotZone.SetLineWeight(1);
HotZone.SetDefaultColor(Color.MAGENTA);

AddCloud(middleline, HotZone, Color.red, Color.CURRENT);
AddCloud(takeprofit,HotZone, Color.CURRENT, Color.GREEN);


### Caution Relationship (RSI and IV) ###
plot CAUTION = if(HotZone <-45 and HotZone > -60,1,double.nan);
#plot CAUTION = if RSIIV1 then 0 else Double.nan;
CAUTION.SetPaintingStrategy(PaintingStrategy.POINTS);
CAUTION.SetLineWeight(4);
CAUTION.SetDefaultColor(Color.YELLOW);

### HOT Relationship (RSI and IV) ###
def RSIIV2 = if HotZone <= -60 then 1 else 0;
plot HOT = if RSIIV2 then 0 else Double.nan;
HOT.SetPaintingStrategy(PaintingStrategy.POINTS);
HOT.SetLineWeight(4);
HOT.SetDefaultColor(Color.RED);

#Arrows#
plot UpSignal = if HotZone crosses above BUY then BUY else Double.NaN;
plot DownSignal = if HotZone crosses below TakeProfit then TakeProfit else Double.NaN;

UpSignal.SetHiding(!showBreakoutSignals);
DownSignal.SetHiding(!showBreakoutSignals);

UpSignal.SetDefaultColor(Color.GREEN);
DownSignal.SetDefaultColor(Color.RED);
UpSignal.SetDefaultColor(Color.UPTICK);
UpSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignal.SetDefaultColor(Color.DOWNTICK);
DownSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

def condition1 = HotZone <= -60;
def condition2 = HotZone < -45 and HotZone > -60;

# Alert
Alert(alertsOn and condition1, "HOT", Alert.BAR, Sound.Chimes);
Alert(alertsOn and condition2, "CAUTION", Alert.BAR, Sound.bell);

Shareable link: http://tos.mx/ZaOhpnv

There are some traders who don't like to use lower indicators. Good news for YOU!!! I created an UPPER indicator that uses BOTH of these into one!!! You can turn on/off the arrows. You can turn on/off the hot and caution dots for the Hotzone and Hotzone line indicators. NOTE: IF you display dots for BOTH indicators, the Hotzone Line dots will plot over the Hotzone indicator dots. If you want to have the opposite, I believe you would just have to move their order within the code.

Below is an example of using the arrows from the HotZone Line indicator with the dots from the HotZone indicator on /ES 15 min chart.

Here is the link to the Hotzone UPPER indicator: http://tos.mx/6Co9B16

Do you want to make some serious long term cash?? Monitor the WEEKLY chart and set alerts in the scan for the weekly timeframe. Take a look at the below example of NDX. Hotzone will tell you when to get back into the market after a significant crash!

Looking for a watchlist column? Here you go!

HOTZONE RSI Watchlist: http://tos.mx/wjdMkBz
CODE:
#HOTZONE-RSI: WATCHLIST
#developed by Chewie76 9-30-2020
### Global Variables ###
input length = 14;
input over_Bought2 = 80;
input over_Bought = 70;
input over_Sold = 30;
input over_Sold2 = 20;
input price = close;
input averageType = AverageType.WILDERS;
input showBreakoutSignals = yes;

### RSI ###
def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

DEF RSI = 50 * (ChgRatio + 1);
def MiddleLine = 50;

def OverSold = over_Sold;
def OverBought = over_Bought;
def UpSignal = if RSI crosses above OverSold then 1 else 0;
def DownSignal = if RSI crosses below OverBought then 2 else 0;

### IVPercentile ###
def vol = imp_volatility();
input TimePeriod = 252;

def data = if !isNaN(vol) then vol else vol[-1];
def hi = highest(data, TimePeriod);
def lo = lowest(data, TimePeriod);
def Percentile = (data - lo) / (hi - lo) * 100;
def lowend = Percentile < 25;
def highend = Percentile > 50;

input over_Bought1 = 98;
input over_Sold1 = 2;

### Squeeze Relationship (RSI and IV) ###
def RSIIV = if percentile - RSI >= 40 and RSI < 32 then 1 else 0;
def HOT = if RSIIV then 50 else Double.nan;

def RSIIV1 = if (percentile - RSI >= 30 and RSI > 32 and RSI < 40, 1, Double.NaN);
def CAUTION = if RSIIV1 then 50 else Double.nan;


AssignBackgroundColor(if DownSignal then color.RED else if Upsignal then color.GREEN else color.black);

AddLabel(yes, if Upsignal then "UP" else if Downsignal then "DOWN" else if RSIIV then “HOT” else if RSIIV1 then "CAUTION" else " ", if UPsignal then color.green else if Downsignal then color.red else if RSIIV then color.RED else if RSIIV1 then color.YELLOW else Color.black);

HOTZONE LINE Watchlist: http://tos.mx/lFkTO2b
CODE:
#HOTZONE LINE: WATCHLIST COLUMN
#developed by Chewie76 with help from FateOwnzYou 9-30-2020

### Global Variables ###

input length = 14;
input price = close;
input averageType = AverageType.WILDERS;

def NetChgAvg = MovingAverage(averageType, price - price[1], length);
def TotChgAvg = MovingAverage(averageType, AbsValue(price - price[1]), length);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;

def RSI = (50 * (ChgRatio + 1)) * -1;
def MiddleLine = 0;
def TakeProfit = 60;
def BUY = -60;
def vol = imp_volatility();
input TimePeriod = 252;

def data = if !IsNaN(vol) then vol else vol[-1];
def hi = Highest(data, TimePeriod);
def lo = Lowest(data, TimePeriod);
def Percentile = ((data - lo) / (hi - lo) * 100) * -1;
def lowend = Percentile < 25;
def highend = Percentile > 50;

plot HotZone = Percentile - RSI;

def H = HotZone < -60;
def C = HotZone < -45 and HotZone > -60;

def UpSignal = if HotZone crosses above BUY then 1 else 0;
def DownSignal = if HotZone crosses below TakeProfit then 2 else 0;

AddLabel(yes, if Upsignal then "UP" else if Downsignal then "DOWN" else if H then “HOT” else if C then "CAUTION" else " ", if Upsignal then color.green else if Downsignal then color.red else if H then color.RED else if C then color.YELLOW else Color.BLACK);

AssignBackgroundColor(if H then color.RED else if C then color.YELLOW else color.black);


Adjust the timeframe on it. It will look like the below. It will have a yellow CAUTION for the yellow dot and a red HOT for red dot. The reason there are two columns is because they are set to different timeframes.

Looking for a Scan? The below links alert for yellow and red dots along with arrows.

Here is a BUY scan. http://tos.mx/Qh32soR
Here is a SELL scan. http://tos.mx/87AySW1

Let me know what you think!!!!!

thanks for this indicator!!! can you please tell me what triggers the red dot vs what triggers the yellow dot? @chewie76

 

[chewie76]

thanks for this indicator!!! can you please tell me what triggers the red dot vs what triggers the yellow dot? @chewie76

Its the difference in volatility and RSI. There are different settings for each one.

 

[rwfarrell]

I just applied this indicator for upper and lower chart. Is there another shareable link for colored candles? what do the different colors candles represent? Thank you!

 

[chewie76]

I just applied this indicator for upper and lower chart. Is there another shareable link for colored candles? what do the different colors candles represent? Thank you!

The colored candles is a paid indicator. It is based on the RSI strength.

 

[BerryMcCawkiner]

ive been using this for almost a year now ive found it to be a very reliable indicator for bounces ive also noticed it doesnt always work with imp volatility because i think thats something that only applies to options so i swapped it for historical volatility and it works a little better but i still find its blacked out on alot of stocks especially nyse stocks

 

[KCali]

I ran this on a daily chart and I get lots of down arrows and very few up arrows. Additionally, I get yellow and red dots on the bottoms, but none on the tops. Is there a setting I need to change? Thank you.

 

[chewie76]

I ran this on a daily chart and I get lots of down arrows and very few up arrows. Additionally, I get yellow and red dots on the bottoms, but none on the tops. Is there a setting I need to change? Thank you.

The dots only appear when stocks are at their weakest.

 

[kentsoi]

is this indicator available in Tradingview?

 

[chewie76]

is this indicator available in Tradingview?

Not that I'm aware of.