Help Drawing fib level lines

[agent]

Hi all, this is too complicated for me, I need an indicator that uses the hi and low of the close of the 1st candle on the 5 minute chart. The indicator would draw a box or lines across the chart to the end of the day at the fib levels 61.8 and 38.2 based on the open and close of the 5 minute candle.

Thanks in advance for any help.

 

[agent]

Hi all, this is too complicated for me, I need an indicator that uses the hi and low of the close of the 1st candle on the 5 minute chart. The indicator would draw a box or lines across the chart to the end of the day at the fib levels 61.8 and 38.2 based on the open and close of the 5 minute candle.

Thanks in advance for any help.

 

[SleepyZ]

Hi all, this is too complicated for me, I need an indicator that uses the hi and low of the close of the 1st candle on the 5 minute chart. The indicator would draw a box or lines across the chart to the end of the day at the fib levels 61.8 and 38.2 based on the open and close of the 5 minute candle.

Thanks in advance for any help.

View attachment 20044

The fib plots will start after rangeEnd bar.
It will also work on chart's with timeframes ending before rangeEnd time. See image with a 1m example
There are various options at the input screen

#Auto Fib Levels After Bar @rangeEnd Closes
#Using Mobius' OR logic for Range
#Plots limited to RTHrs

input rangeStart    = 0930;
input rangeEnd      = 0935;
input ShowTodayOnly = no;

def A     = if SecondsTillTime(rangeEnd) > 0 and SecondsFromTime(rangeStart) >= 0
            then 1
            else 0;
def today = if ShowTodayOnly == no or
               GetDay() == GetLastDay() and  SecondsFromTime(rangeStart) >= 0
            then 1
            else 0;
def H     = if H[1] == 0 or
               A[1] == 0 and A == 1
            then high
            else if A and high > H[1]
            then high
            else H[1];
def L     = if L[1] == 0  or
               A[1] == 0 and A == 1
            then low
            else if A and low < L[1]
            then low
            else L[1];
def Range = H - L;

def HA    = if A or today < 1
            then Double.NaN
            else H;
def LA    = if A or today < 1
            then Double.NaN
            else L;


plot f382 = if SecondsFromTime(1600)[1] >= 0 or
              (SecondsFromTime(0000) > 0 and SecondsFromTime(rangeStart) < 0)
            then Double.NaN
            else LA + Range * .382;
plot f618 = if SecondsFromTime(1600)[1] >= 0 or
              (SecondsFromTime(0000) > 0 and SecondsFromTime(rangeStart) < 0)
            then Double.NaN
            else LA + Range * .618;
f382.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
f618.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

input bubble = yes;
input bubblemover = 3;
def b = bubblemover;
def b1 = b + 1;
AddChartBubble(bubble and IsNaN(f382[b]) and !IsNaN(f382[b1]), f382[b1], "38.2%\n" + AsDollars(f382[b1]), f382.TakeValueColor());
AddChartBubble(bubble and IsNaN(f618[b]) and !IsNaN(f618[b1]), f618[b1], "61.8%\n" + AsDollars(f618[b1]), f618.TakeValueColor());

#

 

[agent]

The fib plots will start after rangeEnd bar.
It will also work on chart's with timeframes ending before rangeEnd time. See image with a 1m example
There are various options at the input screen

Wow SleepyZ thanks for the quick response and it works great.

Is it possible to plot the levels to the end of the current day as opposed to following the time of day? I use it as a support/resistance zone.

 

[SleepyZ]

Wow SleepyZ thanks for the quick response and it works great.

Is it possible to plot the levels to the end of the current day as opposed to following the time of day? I use it as a support/resistance zone.

This will extend the lines to the end of the current day. You need to enter enough bars in chart settings/time axis/Expansion bars to the right to show the display in the image below.

#Auto Fib Levels After Bar @rangeEnd Closes
#Using Mobius' OR logic for Range
#Plots limited to RTHrs

input rangeStart    = 0930;
input rangeEnd      = 0935;
input ShowTodayOnly = no;

def A     = if SecondsTillTime(rangeEnd) > 0 and SecondsFromTime(rangeStart) >= 0
            then 1
            else 0;
def today = if ShowTodayOnly == no or
               GetDay() == GetLastDay() and  SecondsFromTime(rangeStart) >= 0
            then 1
            else 0;
def H     = if H[1] == 0 or
               A[1] == 0 and A == 1
            then high
            else if A and high > H[1]
            then high
            else H[1];
def L     = if IsNaN(low) then L[1] else if L[1] == 0  or
               A[1] == 0 and A == 1
            then low
            else if A and low < L[1]
            then low
            else L[1];

def Range = H - L;

def HA    = if A or today < 1
            then Double.NaN
            else H;

def LA    = if A or today < 1
            then Double.NaN
            else L;

def fib382 = if IsNaN(close) and SecondsTillTime(1600) > 0 then fib382[1]
             else if SecondsFromTime(1600)[1] >= 0 or
              (SecondsFromTime(0000) > 0 and SecondsFromTime(rangeStart) < 0)
            then Double.NaN
            else LA + Range * .382;
plot f382 = fib382;
f382.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
def fib618 = if IsNaN(close)  and SecondsTillTime(1600) > 0 then fib618[1]
             else if SecondsFromTime(1600)[1] >= 0 or
              (SecondsFromTime(0000) > 0 and SecondsFromTime(rangeStart) < 0)
            then Double.NaN
            else LA + Range * .618;
plot f618 = fib618;
f618.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);

input bubble = yes;
input bubblemover = 3;
def b = bubblemover;
def b1 = b + 1;
AddChartBubble(bubble and IsNaN(f382[b]) and !IsNaN(f382[b1]) , f382[b1], "38.2%\n" + AsDollars(f382[b1]), f382.TakeValueColor());
AddChartBubble(bubble and IsNaN(f618[b]) and !IsNaN(f618[b1]), f618[b1], "61.8%\n" + AsDollars(f618[b1]), f618.TakeValueColor());

#

 

[agent]

Perfect thank you very much. Really appreciate it.

 

[Kashkian]

The fib plots will start after rangeEnd bar.
It will also work on chart's with timeframes ending before rangeEnd time. See image with a 1m example
There are various options at the input screen

Hi SleepyZ, can you do it for MTF?

 

[SleepyZ]

Hi SleepyZ, can you do it for MTF?

Not sure how you would want this done.

I suppose one way would be to change input end = 0935 to

def rangeEnd        = if GetAggregationPeriod() <= AggregationPeriod.five_min
                      then 935         
                      else if  GetAggregationPeriod() <= AggregationPeriod.fifteen_MIN
                      then 1000
                      else 1030 ;