you need to reevaluate your condition rules and list them out. your words don't match the code.
first thing, your code has a lot of extra nonsense in it, and it doesn't do what you describe.
just because a tool exists, like pattern generator or code wizard, doesn't mean they are capable of creating valid code. you need to study up on logic and variable offsets, so you can interpret the code you are creating.
your words don't mention looking for trending up or down candles, but the formulas include isup and isdown ?
i assume SL is a short term low? , to find a lower low?
the first 3 lines of this formula are useless. they test for every possible scenario, so they don't tell you anything.
def SL =
(IsUp[2] or IsDown[2] or IsDoji[2]) and
(IsDown[1] or IsUp[1] or IsDoji[1]) and
(IsUp[0] or IsDown[0] or IsDoji[0]) and
this checks , previous low < current low, in other words, is the current low higher than the previous low.
low[1] < low[0] and
this checks if the previous low is equal to the previous low or the low before that one.
low[1] is equal to Lowest(low[1], 2);
this formula doesn't tell you if the current low is a short term low.
there are no negative offsets used, so no future variables are checked (the bar after the current bar).
so you aren't checking 'either' side of the current candle.
-----------------
i started from scratch and made this,
this is based on 3 bar patterns,
. peak , current bar has a higher high than bar before and after it
. valley , current bar has a lower low than bar before and after it
green and red dots on every valley and peak
cyan and yellow wedges (or dots) on intermediate peaks and valleys
(the previous and next signals are opposite. not nessesarily the next bars)
Code:
# hihi_lolo_alt_0
#https://usethinkscript.com/threads/finding-an-intermediate-term-high.14255/
# Finding an intermediate term high
#plot AvgExp = ExpAverage(price[-displace], length);
#def IsUp = close > open;
#def IsDown = close < open;
#def IsDoji = IsDoji();
#def avgRange = 0.05 * Average(high - low, 20);
#--------------------------
def na = double.nan;
def bn = barnumber();
# Swing Low
def lo = low[1] > low[0] and low[0] < low[-1];
# Swing High
def hi = high[1] < high[0] and high[0] > high[-1];
# recent hi or lo
def dir = if bn == 1 then 0
else if lo then -1
else if hi then 1
else dir[1];
def y = 0.001;
input show_dot_all_peaks_valleys = yes;
# plot each swing hi and lo
plot zlo = if show_dot_all_peaks_valleys and lo then (low*(1-(y*1))) else na;
zlo.SetPaintingStrategy(PaintingStrategy.points);
zlo.setlineweight(2);
zlo.SetDefaultColor(Color.red);
plot zhi = if show_dot_all_peaks_valleys and hi then (high*(1+(y*1))) else na;
zhi.SetPaintingStrategy(PaintingStrategy.points);
zhi.setlineweight(2);
zhi.SetDefaultColor(Color.green);
#-------------------------
# look after a low for next signal
def lo_after = if lo and dir[1] > 0 then
(fold i = 1 to 40
with p = 1
while (!getvalue(lo, -i) and !getvalue(hi, -i))
# do p + (-getvalue(lo, -(i+1)) + getvalue(hi, -(i+1))))
do p + 1)
else 0;
def lo2 = if !lo or lo_after == 0 then 0
else if getvalue(hi, -lo_after) then 1
else 0;
#-------------------------
# look after a high for next signal
def hi_after = if hi and dir[1] < 0 then
(fold j = 1 to 40
with q = 1
while (!getvalue(lo, -j) and !getvalue(hi, -j))
# do p + (-getvalue(lo, -(i+1)) + getvalue(hi, -(i+1))))
do q + 1)
else 0;
def hi2 = if !hi or hi_after == 0 then 0
else if getvalue(lo, -hi_after) then 1
else 0;
#-------------------------
# place a dot on peaks and valleys that are surrounded by opposite signals
input show_intermediate_dots = no;
plot zlo2 = if show_intermediate_dots and lo2 then (low*(1-(y*2))) else na;
zlo2.SetPaintingStrategy(PaintingStrategy.points);
#zlo2.setlineweight(2);
zlo2.SetDefaultColor(Color.yellow);
plot zhi2 = if show_intermediate_dots and hi2 then (high*(1+(y*2))) else na;
zhi2.SetPaintingStrategy(PaintingStrategy.points);
#zhi2.setlineweight(2);
zhi2.SetDefaultColor(Color.cyan);
# place a wedge on peaks and valleys that are surrounded by opposite signals
input show_intermediate_wedges = yes;
plot zlo2w = if show_intermediate_wedges and lo2 then (low*(1-(y*2))) else na;
zlo2w.SetPaintingStrategy(PaintingStrategy.BOOLEAN_WEDGE_down);
zlo2w.setlineweight(2);
zlo2w.SetDefaultColor(Color.yellow);
plot zhi2w = if show_intermediate_wedges and hi2 then (high*(1+(y*2))) else na;
zhi2w.SetPaintingStrategy(PaintingStrategy.BOOLEAN_WEDGE_UP);
zhi2w.setlineweight(2);
zhi2w.SetDefaultColor(Color.cyan);
#-----------------------
input test_signal = no;
def ref = lowest(low, 500);
plot r = if test_signal then (ref + dir) else na;
addchartbubble(0, ref,
dir + "\n" +
lo + "\n" +
hi + "\n" +
lo_after + "\n" +
lo2
, color.yellow, no);
#
peak , higher high than bar before and after
valley , lower low than bar before and after
green and red dots on every valley and peak
cyan and yellow wedges on intermediate peaks and valleys
(the previous and next signals are opposite, not nessesarily the next bars)
