Repaints B4 Balanced BB Breakout For ThinkOrSwim

[Chuck]

Everyone, here is the new beta. We are still working on the new add-on, so I wanted to get this out since it is taking longer than expected. With this beta, I separated out the BullBear options. You can select as many as you see fit to trigger the vertical lines when they agree together. Or, you can use it like how it was before and select "yes" for one of them.

Selecting more than one might delay signals. In some cases it may filter results, but I usually select one and stick with it.

Note: if this not giving the desired outcome, we can revert it back.

# Balanced BB Breakout Indicator
# Free for use. Header credits must be included when any form of the code included in this package is used.
# User assumes all risk. Author not responsible for errors or use of tool.
# v1.2 - Assembled by Chuck Edwards
# v2.0 - Barbaros - cleanup
# v2.1 - Barbaros - added RSI IFT, NumberOfShares, BB crossing options
# v2.2 - Barbaros - fixed PnL issues and removed intraDay filter
# v2.3 - Barbaros - changed input and variable names, RSM is re-done
# v2.4 - Barbaros - removed PnL, added strategy signal arrows and alerts,
#                   added Fibonacci SuperTrend, added unified bar color selection
# v2.5 - Chuck    - added divergence and squeeze label, added squeeze alert
#        Barbaros - cleanup, changed divergance to text, show stoch labels all the time
#        Barbaros - added trend squeeze label for BB, added alerts for Stoch Scalper
#        Barbaros - added options to hide clouds and labels
#        Barbaros - changed trend and divergence colors and text to match
#        Barbaros - removed volume and keltner channel studies, unified squeeze
# BETA - Barbaros - optimizations, added hints and separated out BullBear options for combinations

declare lower;

input ShowMarketForecastLabel = yes;        #hint ShowMarketForecastLabel: Show the intermediate Market Forecast label
input ShowMACDBBLabel = yes;                #hint ShowMACDBBLabel: Show the MACDBB based Trend label
input ShowMACDBBCloud = yes;                #hint ShowMACDBBCloud: Show the MACDBB cloud shaded between BB
input ShowRSMCloud = yes;                   #hint ShowRSMCloud: Show the vertical cloud based on RSM
input ShowHMALabel = yes;                   #hint ShowHMALabel: Show HUll Moving Average based Divergence label
input ShowSTOCHSCALPERSqueezeLabel = yes;   #hint ShowSTOCHSCALPERSqueezeLabel: Show Stochastic Scalper based squeeze label
input ShowSTOCHSCALPERSqueezeCloud = yes;   #hint ShowSTOCHSCALPERSqueezeCloud: Show Stochastic Scalper based squeeze cloud between BB
input ShowBullBearVerticalLines = yes;      #hint ShowBullBearVerticalLines: Show vertical lines for bullish or bearish direction

### Market Forecast

def pIntermediate = MarketForecast().Intermediate;

AddLabel(ShowMarketForecastLabel,
    "Market Forecast " +
    if pIntermediate >= 80 then "Bullish" else
    if pIntermediate <= 20 then "Bearish" else
    if pIntermediate > pIntermediate[1] then "Rising" else
    if pIntermediate < pIntermediate[1] then "Falling" else "Neutral",
    if pIntermediate >= 80 then Color.GREEN else
    if pIntermediate <= 20 then Color.RED else
    if pIntermediate > pIntermediate[1] then Color.LIGHT_GREEN else
    if pIntermediate < pIntermediate[1] then Color.LIGHT_RED else Color.GRAY
);

### MACDBB

input MACDBB_FastLength = 12;
input MACDBB_SlowLength = 26;
input MACDBB_Length = 25;
input MACDBB_BandLength = 15;
input MACDBB_NumDev = 1.0;

def MACDBB_Data = MACD(fastLength = MACDBB_FastLength, slowLength = MACDBB_SlowLength, MACDLength = MACDBB_Length);

plot MACDBB_Upper = reference BollingerBands(price = MACDBB_Data, length = MACDBB_BandLength,
                                             Num_Dev_Dn = -MACDBB_NumDev, Num_Dev_Up = MACDBB_NumDev).UpperBand;
MACDBB_Upper.SetDefaultColor(Color.RED);
MACDBB_Upper.HideTitle();
MACDBB_Upper.HideBubble();

plot MACDBB_Lower = reference BollingerBands(price = MACDBB_Data, length = MACDBB_BandLength,
                                             Num_Dev_Dn = -MACDBB_NumDev, Num_Dev_Up = MACDBB_NumDev).Lowerband;
MACDBB_Lower.SetDefaultColor(Color.GREEN);
MACDBB_Lower.HideTitle();
MACDBB_Lower.HideBubble();

plot MACDBB_Midline = reference BollingerBands(price = MACDBB_Data, length = MACDBB_BandLength,
                                               Num_Dev_Dn = -MACDBB_NumDev, Num_Dev_Up = MACDBB_NumDev).MidLine;
MACDBB_Midline.SetDefaultColor(Color.LIGHT_RED);
MACDBB_Midline.SetStyle(Curve.FIRM);
MACDBB_MidLine.HideTitle();
MACDBB_MidLine.HideBubble();

plot MACDBB_Line = MACDBB_Data;
MACDBB_Line.AssignValueColor(
    if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line >= MACDBB_Upper then Color.GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line >= MACDBB_Upper then Color.DARK_GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line <= MACDBB_Lower then Color.RED else
    if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line <= MACDBB_Lower then Color.DARK_RED
    else Color.GRAY
);
MACDBB_Line.SetLineWeight(1);

plot MACDBB_Dots = MACDBB_Data;
MACDBB_Dots.AssignValueColor(
    if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then Color.GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then Color.DARK_GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then Color.RED
    else if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then Color.DARK_RED
    else Color.GRAY
);
MACDBB_Dots.SetPaintingStrategy(PaintingStrategy.LINE_VS_POINTS);
MACDBB_Dots.SetLineWeight(1);
MACDBB_Dots.HideTitle();
MACDBB_Dots.HideBubble();

input MACDBB_CrossFromAboveAlert = {default "Zero", "Lower", "Middle", "Upper"};
input MACDBB_CrossFromBelowAlert = {default "Zero", "Lower", "Middle", "Upper"};

def MACDBB_CrossFromAboveVal = if MACDBB_CrossFromAboveAlert == MACDBB_CrossFromAboveAlert.Lower then MACDBB_Lower
                               else if MACDBB_CrossFromAboveAlert == MACDBB_CrossFromAboveAlert.Upper then MACDBB_Upper
                              else 0;
def MACDBB_CrossFromBelowVal = if MACDBB_CrossFromBelowAlert == MACDBB_CrossFromBelowAlert.Lower then MACDBB_Lower
                               else if MACDBB_CrossFromBelowAlert == MACDBB_CrossFromBelowAlert.Upper then MACDBB_Upper
                               else 0;

def MACDBB_Buy = MACDBB_Data > MACDBB_Upper;
def MACDBB_Sell = MACDBB_Data <= MACDBB_Lower;

AddLabel(ShowMACDBBLabel,
    "Trend " +
    if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then "Bullish"
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then "Bullish (decreasing)"
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then "Bearish"
    else if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then "Bearish (increasing)"
    else "Neutral",
    if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then Color.GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line > MACDBB_Upper then Color.DARK_GREEN
    else if MACDBB_Line < MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then Color.RED
    else if MACDBB_Line > MACDBB_Line[1] and MACDBB_Line < MACDBB_Lower then Color.DARK_RED
    else Color.GRAY
);

### Bollinger Bands

input BB_Length = 20;
input BB_NumDevDn = -2.0;
input BB_NumDevUp = 2.0;
input BB_AverageType = AverageType.SIMPLE;

def BB_SDev = StDev(data = close, length = BB_Length);
def BB_MidLine = MovingAverage(BB_AverageType, data = close, length = BB_Length);
def BB_LowerBand = BB_MidLine + BB_NumDevDn * BB_SDev;
def BB_UpperBand = BB_MidLine + BB_NumDevUp * BB_SDev;

# BB Cloud

AddCloud(if ShowMACDBBCloud then MACDBB_Upper else MACDBB_Lower, MACDBB_Lower, Color.LIGHT_RED);

### RSI/STOCASTIC/MACD CONFLUENCE COMBO

plot RSM_MACD_Diff = reference MACD("fast length" = 12, "slow length" = 26, "macd length" = 9).Diff;
RSM_MACD_Diff.SetDefaultColor(GetColor(5));
RSM_MACD_Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
RSM_MACD_Diff.SetLineWeight(4);
RSM_MACD_Diff.DefineColor("Positive and Up", Color.GREEN);
RSM_MACD_Diff.DefineColor("Positive and Down", Color.DARK_GREEN);
RSM_MACD_Diff.DefineColor("Negative and Down", Color.RED);
RSM_MACD_Diff.DefineColor("Negative and Up", Color.DARK_RED);
RSM_MACD_Diff.AssignValueColor(
    if RSM_MACD_Diff >= 0 then
        if RSM_MACD_Diff > RSM_MACD_Diff[1] then RSM_MACD_Diff.Color("Positive and Up") else RSM_MACD_Diff.Color("Positive and Down")
    else
        if RSM_MACD_Diff < RSM_MACD_Diff[1] then RSM_MACD_Diff.Color("Negative and Down") else RSM_MACD_Diff.Color("Negative and Up")
);

plot RSM_MACD_ZeroLine = 0;
RSM_MACD_ZeroLine.SetDefaultColor(Color.RED);
RSM_MACD_ZeroLine.HideTitle();
RSM_MACD_ZeroLine.HideBubble();

def RSM_RSI = reference RSI(length = 7).RSI;

def RSM_Stoch_Val = 100 * (close - lowest(low, 14)) / (highest(high, 14) - lowest(low, 14));
def RSM_StochSlowK = SimpleMovingAvg(SimpleMovingAvg(RSM_Stoch_Val,3),3);

def RSM_rsiGreen = RSM_RSI >= 50;
def RSM_rsiRed = RSM_RSI < 50;
def RSM_stochGreen = RSM_StochSlowK >= 50;
def RSM_stochRed = RSM_StochSlowK < 50;
def RSM_macdGreen = RSM_MACD_Diff >= 0;
def RSM_macdRed = RSM_MACD_Diff < 0;
def RSM_Buy = RSM_rsiGreen and RSM_stochGreen and RSM_macdGreen;
def RSM_Sell = RSM_rsiRed and RSM_stochRed and RSM_macdRed;

# Shade areas based on criteria; adjust as needed

AddCloud(
    if ShowRSMCloud and RSM_rsiGreen and RSM_stochGreen and RSM_macdGreen then Double.POSITIVE_INFINITY else Double.NaN,
    if ShowRSMCloud and RSM_rsiGreen and RSM_stochGreen and RSM_macdGreen then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN
);
AddCloud(
    if ShowRSMCloud and RSM_rsiRed and RSM_stochRed and RSM_macdRed then Double.POSITIVE_INFINITY else Double.NaN,
    if ShowRSMCloud and RSM_rsiRed and RSM_stochRed and RSM_macdRed then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED
);

### Divergance
input HMA_Length = 55;
input HMA_Lookback = 2;

def HMA = HullMovingAvg(price = HL2, length = HMA_Length);
def HMA_delta = HMA[1] - HMA[HMA_Lookback + 1];
def HMA_delta_per_bar = HMA_delta / HMA_Lookback;
def HMA_next_bar = HMA[1] + HMA_delta_per_bar;
def HMA_concavity = if HMA > HMA_next_bar then 1 else -1;
def HMA_MA_Max = if HMA[-1] < HMA and HMA > HMA[1] then HMA else Double.NaN;
def HMA_MA_Min = if HMA[-1] > HMA and HMA < HMA[1] then HMA else Double.NaN;
def HMA_divergence = HMA - HMA_next_bar;

AddLabel(ShowHMALabel,
        "Divergence " +
        if HMA_concavity < 0 then
            if HMA_divergence[1] > HMA_divergence then "Bearish (increasing)"
            else "Bearish"
        else
            if HMA_divergence[1] < HMA_divergence then "Bullish (decreasing)"
            else "Bullish",
        if HMA_concavity < 0 then
            if HMA_divergence[1] > HMA_divergence then Color.DARK_RED
            else Color.RED
        else
            if HMA_divergence[1] < HMA_divergence then Color.DARK_GREEN
            else Color.GREEN
);

### Stocastic Scalper

input STOCHSCALPER_Period = 21;
input STOCHSCALPER_PeriodEMA = 13;
input STOCHSCALPER_VolumePeriod = 60;

def STOCHSCALPER_oSS = (open[1] + close[1]) / 2;
def STOCHSCALPER_hSS = Max(high, close[1]);
def STOCHSCALPER_lSS = Min(low, close[1]);
def STOCHSCALPER_cSS = (STOCHSCALPER_oSS + STOCHSCALPER_hSS + STOCHSCALPER_lSS + close) / 4;

def STOCHSCALPER_mean = Average(STOCHSCALPER_cSS, 20);
def STOCHSCALPER_sd = StDev(STOCHSCALPER_cSS, 20);
def STOCHSCALPER_atr = Average(TrueRange(STOCHSCALPER_cSS, STOCHSCALPER_hSS, STOCHSCALPER_lSS), 20);
def STOCHSCALPER_squeeze = if (STOCHSCALPER_mean + (2 * STOCHSCALPER_sd)) < (STOCHSCALPER_mean + (1.5 * STOCHSCALPER_atr)) then yes else no;
def STOCHSCALPER_squeeze_signal = !STOCHSCALPER_squeeze[1] and STOCHSCALPER_squeeze;

AddCloud(if ShowSTOCHSCALPERSqueezeCloud and STOCHSCALPER_squeeze then MACDBB_Upper else Double.NaN,
         if ShowSTOCHSCALPERSqueezeCloud and STOCHSCALPER_squeeze then MACDBB_Lower else Double.NaN, Color.YELLOW);
AddLabel(ShowSTOCHSCALPERSqueezeLabel, "Scalper Squeeze", if STOCHSCALPER_squeeze then Color.WHITE else Color.GRAY);

### Balance of Power

input BOP_EMA_Length = 20;
input BOP_TEMA_Length = 20;

def BOP_THL = If(high != low, high - low, 0.01);
def BOP_BullOpen = (high - open) / BOP_THL;
def BOP_BearOpen = (open - low) / BOP_THL;
def BOP_BullClose = (close - low) / BOP_THL;
def BOP_BearClose = (high - close) / BOP_THL;
def BOP_BullOC = If(close > open, (close - open) / BOP_THL, 0);
def BOP_BearOC = If(open > close, (open - close) / BOP_THL, 0);
def BOP_BullReward = (BOP_BullOpen + BOP_BullClose + BOP_BullOC) / 1;
def BOP_BearReward = (BOP_BearOpen + BOP_BearClose + BOP_BearOC) / 1;

def BOP_BOP = BOP_BullReward - BOP_BearReward;
def BOP_SmoothBOP = ExpAverage(BOP_BOP, BOP_EMA_Length);
def BOP_xPrice = BOP_SmoothBOP;
def BOP_xEMA1 = ExpAverage(BOP_SmoothBOP, BOP_TEMA_Length);
def BOP_xEMA2 = ExpAverage(BOP_xEMA1, BOP_TEMA_Length);
def BOP_xEMA3 = ExpAverage(BOP_xEMA2, BOP_TEMA_Length);
def BOP_nRes = 3 * BOP_xEMA1 - 3 * BOP_xEMA2 + BOP_xEMA3;

def BOP_SmootherBOP = BOP_nRes;
def BOP_s1 = BOP_SmoothBOP;
def BOP_s2 = BOP_SmootherBOP;
def BOP_s3 = BOP_SmootherBOP[2];
def BOP_Direction = if BarNumber() == 1 then 0
                    else if BOP_s2 < BOP_s3 and BOP_s2[1] > BOP_s3[1] then -1
                    else if BOP_s2 > BOP_s3 and BOP_s2[1] < BOP_s3[1] then 1
                    else BOP_Direction[1];

### RSI IFT

def RSI_IFT_R = reference RSI(5, close) - 50;
def RSI_IFT_AvgRSI = MovingAverage(AverageType.Exponential,RSI_IFT_R,9);
def RSI_IFT_InverseRSI = (Power(Double.E, 2 * RSI_IFT_AvgRSI) - 1) / (Power(Double.E, 2 * RSI_IFT_AvgRSI) + 1);
def RSI_IFT_Direction = if BarNumber() == 0 then 0
                        else if (RSI_IFT_InverseRSI[1] > 0) and (RSI_IFT_InverseRSI < 0) then -1
                        else if (RSI_IFT_InverseRSI > 0) and (RSI_IFT_InverseRSI[1] < 0) then 1
                        else RSI_IFT_Direction[1];

### Fibonacci SuperTrend

input FST_Length = 11;
input FST_Retrace = 23.6;
input FST_UseHighLow = yes;

def FST_h = if FST_UseHighLow then high else close;
def FST_l = if FST_UseHighLow then low else close;
def FST_minL = Lowest(FST_l, FST_Length);
def FST_maxH = Highest(FST_h, FST_Length);

def FST_hh = if FST_h > FST_maxH[1] then FST_h else FST_hh[1];
def FST_ll = if FST_l < FST_minL[1] then FST_l else FST_ll[1];
def FST_trend = if FST_h > FST_maxH[1] then 1 else if FST_l < FST_minL[1] then -1 else FST_trend[1];
def FST_Direction = if BarNumber() == 0 then 0
                    else if FST_trend != 1 then -1
                    else if FST_trend == 1 then 1
                    else FST_Direction[1];

### Bar Color

input BarColor = { "None", default "RSM", "FibonacciSuperTrend" };

AssignPriceColor(
    if BarColor == BarColor.FibonacciSuperTrend then
        if FST_trend == 1 then Color.GREEN else Color.RED
    else if BarColor == BarColor.RSM then
        if RSM_Buy then Color.GREEN
        else if RSM_Sell then Color.RED
        else Color.DARK_GRAY
    else Color.CURRENT
);

### Strategy

input BullBear_Include_BOP = no;
input BullBear_Include_FST = no;
input BullBear_Include_RSI_IFT = yes;

def BullBear_Buy = (!BullBear_Include_BOP or BOP_Direction == 1) and
                   (!BullBear_Include_FST or FST_Direction == 1) and
                   (!BullBear_Include_RSI_IFT or RSI_IFT_Direction == 1);
def BullBear_Sell = (!BullBear_Include_BOP or BOP_Direction == -1) and
                    (!BullBear_Include_FST or FST_Direction == -1) and
                    (!BullBear_Include_RSI_IFT or RSI_IFT_Direction == -1);

AddVerticalLine(ShowBullBearVerticalLines and BullBear_Buy and !BullBear_Buy[1],
                AsDollars(close),
                Color.GREEN, Curve.SHORT_DASH);
AddVerticalLine(ShowBullBearVerticalLines and BullBear_Sell and !BullBear_Sell[1],
                AsDollars(close),
                Color.RED, Curve.SHORT_DASH);

def Strategy_Buy = BullBear_Buy and MACDBB_Buy and RSM_Buy;
def Strategy_Sell = BullBear_Sell and MACDBB_Sell and RSM_Sell;
def Strategy_BuySignal = Strategy_Buy and !Strategy_Buy[1];
def Strategy_SellSignal = Strategy_Sell and !Strategy_Sell[1];

plot BuyArrow = if Strategy_BuySignal then 0 else Double.NaN;
BuyArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
BuyArrow.SetDefaultColor(Color.WHITE);
BuyArrow.HideTitle();
BuyArrow.HideBubble();

plot SellArrow = if Strategy_SellSignal then 0 else Double.NaN;
SellArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
SellArrow.SetDefaultColor(Color.WHITE);
SellArrow.HideTitle();
SellArrow.HideBubble();

### Alerts

Alert(Strategy_BuySignal, "Long Entry", Alert.BAR, Sound.DING);
Alert(Strategy_SellSignal, "Short Entry", Alert.BAR, Sound.DING);
Alert(MACDBB_Line crosses above MACDBB_CrossFromAboveVal, "MACDBB Crossed Up", Alert.BAR, Sound.DING);
Alert(MACDBB_Line crosses below MACDBB_CrossFromBelowVal, "MACDBB Crossed Down", Alert.BAR, Sound.DING);
Alert(STOCHSCALPER_squeeze_signal, "Scalper Squeeze", Alert.BAR, Sound.DING);

Love the way it is all optional, makes it completely versital. You can make it as simple or as complex as you need it for one chart or any combination. It gives you so many ways to use on any combination of charts. Good call!!!!!

 

[Homemadeitmyself]

Multiple time frame super trend lower study, Balance of power setting for vertical lines, and macd switching from green to red or red to green all on the 5min chart. If all these 3 lineup it has not failed me yet, insane.

https://imgur.com/a/5N5Uh4q

https://imgur.com/a/f5uUnxY

Caught 100 Points to the upside then another 100 to the downside, goodnight.

Any chance you could share the Super_MTF Study? This is exactly what I was looking for. It's much harder to gauge the state of things with MTF labels

 

[Homemadeitmyself]

@Trend Trader @BeEazy10

http://tos.mx/3wHG5jZ

Link to the indicator, let me know if it doesn't work.

Also in terms of the Multiple time frame super trend, whenever the stars have aligned with the BB Breakout, whatever color the 60min red or green I've noticed it shows a greater move in favor of the color itself. So for example in many cases expect larger shorts than longs when 60min is red and expect larger longs than shorts when the 60min is green.


Obviously this is not always the case but it might be a cool way to decide to get out early or hold on to a position you're in.

NM! Found this post!

 

[ALV]

@Homemadeitmyself ; welcome to usethinkscript. This is a great community with excellent coders and experienced traders. The indicator you highlighted above include the names of the persons that helped to develop it, see the CREDITS section of the code. It is a good indicator.

 

[Homemadeitmyself]

I appreciate your response and have nothing against @Ghostwar19's strategy. Personally, I want more timeframes than the MTF SuperTrend displays. While testing this BB Balance Breakout indicator, I've been trading micros to minimize risk. Below is a screenshot of the top of my grid. See how the RSM labels show me in a glance that the ES and YM are my safest bets to trade longs in alignment with the higher timeframe? If a short signal pops on either one, it could be a trend reversal but is more likely to be a pullback that risks my getting stopped out. The RSM labels let me see very quickly which instrument is my best bet for the day, whether to look for longs or shorts, and warns me if I should be looking at fast scalps instead of longer plays.

But that's just me. Others do it differently. That's what makes the MACD_BB so awesome. It pairs well with so many things!

https://imgur.com/a/AvweND3

Hi there! I found the link to RSM labels. What are the labels that show Trend, Choppy or Bullish etc? Could you share those? Thanks so much in advance!

 

[Homemadeitmyself]

@Homemadeitmyself ; welcome to usethinkscript. This is a great community with excellent coders and experienced traders. The indicator you highlighted above include the names of the persons that helped to develop it, see the CREDITS section of the code. It is a good indicator.

yeah I saw it after I posted. Glad I didn't post without giving credit!

 

[Homemadeitmyself]

I typically just scan on a daily if I am going to be alerted with emails or texts as it upfates,
only to not be bugged with notifications every time the watchlist updates.

I use a top down approach to evaluate market conditions. Meaning I like timeframe continuity in my favor.

I want it to be trending in the same direction on the monthly, weekly, daily, 4h, 1h. If on all those timeframes are in agreement I like to look for my trading edge on the lower timeframe I am going to be trading on. Let’s say I use a 3 min chart to enter a position. Now if Idon’t have an alert on, I use higher timeframes to set my watchlist too. It’s nice to have it show up in the watchlist and have the option to trade.
Daytraders, interday traders and scalpers tend to look at different timeframes.

Chuck, do you usually set the scan on the daily to run within "one bar"? It works perfectly for me and I wonder if should set it within a the last couple of days since it will probably be running for a few days anyway?

Again, thank you for all of this. This is amazing!!!!

 

[svencool]

ADX ADD-ON
Hey Chuck, I put the ADX script in with the code and I can see it plotted on the Indicator. You had yours set to 35, How are you using this? For an exit strategy? Just trying to learn thanks again for all your guys hard work....

ADX ADD-ON PICTURE

 

[Chuck]

ADX ADD-ON
Hey Chuck, I put the ADX script in with the code and I can see it plotted on the Indicator. You had yours set to 35, How are you using this? For an exit strategy? Just trying to learn thanks again for all your guys hard work....

ADX ADD-ON PICTURE

My main reason for building It was to help identify good exit points.

 

[VictusJogi]

@VictusJogi @nitrous
Nitrous Posted This -
Can you explain more, by "wrong" side of the zero line.
Trying to understand that and see if we can weed it out false signals.

If you find some time I would like to see an example as well. Thx..

@barbaros @Chuck @nitrous @svencool... This is what i was talking about... Look at "A,B,C,D" I wont call this a "FALSE SIGNAL" (price did move up 5 points) rather "OUT OF STEAM" signal..

 

[Chuck]

@barbaros @Chuck @nitrous @svencool... This is what i was talking about... Look at "A,B,C,D" I wont call this a "FALSE SIGNAL" (price did move up 5 points) rather "OUT OF STEAM" signal..

Please outline your observations of what you understand at each point A, B, C and D . Once you do that , I think I can help you.

 

[optionsRS]

I typically just scan on a daily if I am going to be alerted with emails or texts as it upfates,
only to not be bugged with notifications every time the watchlist updates.

I use a top down approach to evaluate market conditions. Meaning I like timeframe continuity in my favor.

I want it to be trending in the same direction on the monthly, weekly, daily, 4h, 1h. If on all those timeframes are in agreement I like to look for my trading edge on the lower timeframe I am going to be trading on. Let’s say I use a 3 min chart to enter a position. Now if Idon’t have an alert on, I use higher timeframes to set my watchlist too. It’s nice to have it show up in the watchlist and have the option to trade.
Daytraders, interday traders and scalpers tend to look at different timeframes.

Hi Chuck, do you mind to post screenshots? I did the other way (5 min to monthly), but your approach is good and makes more sense.

Currently, with my scanner settings, I see LOW is one the ticker with daily uptrend. I checked weekly and monthly and they're in uptrend.

When I check the 4h,1hr i don't see any arrow all i see is the green zone. is that what you're seeing?

 

[VictusJogi]

Please outline your observations of what you understand at each point A, B, C and D . Once you do that , I think I can help you.

Point "A" a buy signal was given, however if you look at MACD BB, there is a Gap between Zero line and BB line and its sloping down which I guess is negative divergence, Plus I have TMO 5 and 30 mins on the lower chart, at point A (Buy signal) and point C (TMO 5 Mins turned Red and Wave Osc gave a sell signal). Point B..a lot of candles grey and green before buy arrow (point A) appeared..

 

[Joseph Patrick 18]

I will share one example once I get home

Hi @VictusJogi I never got a chance to poperly thank you for you helping me out on the other forum. Thanks it was kind of you to take the time out to help me understand.

 

[svencool]

@barbaros @Chuck @nitrous @svencool... This is what i was talking about... Look at "A,B,C,D" I wont call this a "FALSE SIGNAL" (price did move up 5 points) rather "OUT OF STEAM" signal..

Thanks I believe I see what your saying now!

 

[graci117]

Multiple time frame super trend lower study, Balance of power setting for vertical lines, and macd switching from green to red or red to green all on the 5min chart. If all these 3 lineup it has not failed me yet, insane.

https://imgur.com/a/5N5Uh4q

https://imgur.com/a/f5uUnxY

Caught 100 Points to the upside then another 100 to the downside, goodnight.

Thanks to everyone for continuous updates to the indicator. I loaded the indicator and it looks awesome.

@Ghostwar19 - Do you mind sharing your study set - upper and lower?

 

[weip2k]

@Chuck @barbaros hey guys, as we all know, MACD defaults are 12/26/9 - the defaults here are 12/26/25 is there a reason behind this? also, noticed that even if i changed "25" to any other lower or higher number, it seemingly has no effect, can you guys look into that?

Sorry, just wanted to bump this before it gets lost - anyone else, feel free to chime in if you use different values from default, thankyou.

 

[barbaros]

Sorry, just wanted to bump this before it gets lost - anyone else, feel free to chime in if you use different values from default, thankyou.

This variable relates to MACD's Bollinger Bands. It is passed to to MACD but inside of MACD, it is used for calculating the average of the “value”. However, we are only using the value coming out of MACD for Bollinger Bands, so it doesn't matter what you set this to. I will remove it from the next beta.

 

[weip2k]

This variable relates to MACD's Bollinger Bands. It is passed to to MACD but inside of MACD, it is used for calculating the average of the “value”. However, we are only using the value coming out of MACD for Bollinger Bands, so it doesn't matter what you set this to. I will remove it from the next beta.

ah..gotcha. but the first 2 macd values work as intended to incase anyone was wondering as I mostly daytrade/scalp - i tend to use lower value for better reaction. thank you.

 

[Joseph Patrick 18]

My main reason for building It was to help identify good exit points.

Just wanted to say congrats chuck and barbaros for building an excellent indicator! 32 pages and 600+ posts!!! I'd say thats pretty successful Congrats and thanks!