Whats wrong with my code (Open High Low indicator)

[Trigun1127]

So I have my code set to display yesterdays High And Low while also displaying just the days open price for that current day. However the open price has been inaccurate for the past two days either by a tick or a whole point. I'm also using this on the 5 minute chart.

declare hide_on_daily;
declare once_per_bar;

input timeFrame = {default DAY, WEEK, MONTH};

plot high = If(GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN, high(period = timeFrame)[1], Double.NaN);
plot Low = If(GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN, low(period = timeFrame)[1], Double.NaN);
plot Open = If(GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN, open(period = timeFrame)[0], Double.NaN);

high.SetDefaultColor (Color.GREEN);
high.SetPaintingStrategy(PaintingStrategy.DASHES);
Low.SetDefaultColor(Color.RED);
Low.SetPaintingStrategy(PaintingStrategy.DASHES);
Open.SetDefaultColor (Color.Yellow);
Open.SetPaintingStrategy(PaintingStrategy.DASHES);

https://imgur.com/a/DUg4lOW

 

[SleepyZ]

So I had a chance to test today, yesterday oddly I had no problem on old code but then today the High wasnt printing. So input new code and this is what what's happening
Before Candle Close
After Candle Close

https://imgur.com/a/N19DxkD

I am assuming you are referencing that the new code sometimes does not extend the lines. If so, this should hopefully fix that.

The code fix I did friday used !isnan(close) to ensure that it picked up periods with data. The code fix I just did with isnan(close) on hi, lo, op extended those lines if there is no data.

Thanks for letting me know!

declare hide_on_daily;
declare once_per_bar;

input timeFrame = {default DAY, WEEK, MONTH};
def x      = if timeFrame == timeFrame.WEEK
             then GetWeek()
             else if timeFrame == timeFrame.MONTH   
             then GetMonth()
             else GetDay();
def hi     = if isnan(close)
             then hi[1]
             else If(!isnan(close) and GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN and
             x != x[1],
             high(period = timeFrame)[1],
             hi[1]);
plot high  = hi;
def lo     = if isnan(close)
             then lo[1]
             else If(!isnan(close) and GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN and
             x != x[1] ,
             low(period = timeFrame)[1],
             lo[1]);
plot Low   = lo;
def op     = if isnan(close)
             then op[1]
             else If(!isnan(close) and GetAggregationPeriod() <= AggregationPeriod.FIFTEEN_MIN and
             x != x[1] ,
             open,
             op[1]);
plot Open  = op;

high.SetDefaultColor (Color.GREEN);
high.SetPaintingStrategy(PaintingStrategy.DASHES);
Low.SetDefaultColor(Color.RED);
Low.SetPaintingStrategy(PaintingStrategy.DASHES);
Open.SetDefaultColor (Color.YELLOW);
Open.SetPaintingStrategy(PaintingStrategy.DASHES);

 

[Trigun1127]

I am assuming you are referencing that the new code sometimes does not extend the lines. If so, this should hopefully fix that.

The code fix I did friday used !isnan(close) to ensure that it picked up periods with data. The code fix I just did with isnan(close) on hi, lo, op extended those lines if there is no data.

Thanks for letting me know!

Looking good no more issues that I'm seeing currently!