Webby's RS Line For ThinkOrSwim

[Break Trader]

Webby RS Line,
https://www.tradingview.com/script/4qgg7f1C-Webby-s-RS-Line/
can this be converted? Mike Webster RS line above the 21 SMA


It is not this indicator:
https://usethinkscript.com/threads/...le-indicator-webbys-rsi-for-thinkorswim.3638/
They are two different indicators, the RS Line is easier to decipher than the simple indicator.

Has anyone seen the Webby RS Line indicator? it is different from the
webby RSI, this just show where the RS line is in relation (above or below) the 21 MA as seen in this video?

 

[samer800]

Webby RS Line,
https://www.tradingview.com/script/4qgg7f1C-Webby-s-RS-Line/
can this be converted? Mike Webster RS line above the 21 SMA


It is not this indicator:
https://usethinkscript.com/threads/...le-indicator-webbys-rsi-for-thinkorswim.3638/
They are two different indicators, the RS Line is easier to decipher than the simple indicator.

//@version=5
indicator(title = 'Webby\'s RS Line')

// inputs
index       = input.symbol(title='Index to Compare', defval='SPX')
upColor     = input.color(color.blue, 'RS Line Above 21 Color')
downColor   = input.color(color.red, 'RS Line Below 21 Color')
emaWidth    = input.int(title='EMA\'s Line Width', defval=1, minval=1, maxval=5)

//calculations
spx     = request.security(index, timeframe.period, low)
rs      = (low / spx) * 100
ema     = ta.ema(rs,21)
dist    = ((rs - ema) / rs) * 100
ema1    = ta.ema(dist, 3)
ema2    = ta.ema(dist, 13)

//colors
histCol = dist > 0 ? upColor : downColor
ema1Col = ema1 > ema1[1] ? color.lime : color.maroon
ema2Col = ema2 > ema2[1] ? color.green : color.red

//plots
plot(dist, 'Distance', color = histCol, style = plot.style_histogram, linewidth = 2)
plot(ema1, color = ema1Col, linewidth = emaWidth)
plot(ema2, color = ema2Col, linewidth = emaWidth)

Has anyone seen the Webby RS Line indicator? it is different from the
webby RSI, this just show where the RS line is in relation (above or below) the 21 MA as seen in this video?

check the below

#/ This source code is subject to the terms of the Mozilla Public License 2.0 at https://mozilla.org/MPL/2.0/
#// © Amphibiantrading
#indicator(title = 'Webby\'s RS Line')
# request from www.usethinkscript.com members
# Converted by Sam4Cok@Samer800    - 07/2023
declare lower;
#// inputs
input index       = "SPX";    # 'Index to Compare'
input movAvgType = AverageType.EXPONENTIAL;

DefineGlobalColor("up", CreateColor(33,150,243));
DefineGlobalColor("dn", CreateColor(255,82,82));
DefineGlobalColor("lime", CreateColor(0,230,118));
DefineGlobalColor("maroon", CreateColor(136,14,79));
DefineGlobalColor("green", Color.GREEN);
DefineGlobalColor("red", Color.RED);
#//calculations
def spx  = low(Symbol = index);
def rs   = (low / spx) * 100;
def ema  = MovingAverage(movAvgType,rs , 21);
def dist = ((rs - ema) / rs) * 100;
def ema1 = MovingAverage(movAvgType, dist, 3);
def ema2 = MovingAverage(movAvgType, dist, 13);

#//colors
def histCol = dist > 0;
def ema1Col = ema1 > ema1[1];
def ema2Col = ema2 > ema2[1];

#//plots
plot movAvg1 = ema1;
plot movAvg2 = ema2;
plot Distance = dist;

Distance.SetLineWeight(2);
Distance.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Distance.AssignValueColor(if histCol then GlobalColor("up") else GlobalColor("dn"));

movAvg1.AssignValueColor(if ema1Col then GlobalColor("lime") else GlobalColor("maroon"));
movAvg2.AssignValueColor(if ema2Col then GlobalColor("green") else GlobalColor("red"));

 

[Break Trader]

@samer800 looks nice, Thank you, will start playin around with it during my weekend screens