Yeah, there seems to be some weirdness with some symbols.
I put the original study on a 5D 15m chart and modified
v the same way. If I load any symbol with generally good premarket volume everything looks fine. GLD, QQQ, SPY, all look good. KO, PEP, TWTR have good premarket data a lot less often but generally have some and those look okay. PSA, PFPT sometimes have no premarket volume and this is where the problem is.
v still has the value from the last day that did have premarket volume because there is no candle that meets the condition of
GlobeX and !GlobeX[1] to reset it.
GetDay() != GetDay()[1] would get the volume of the first candle even if it's after the open, so that won't work. We need a time that is guaranteed to actually have a candle on the chart. I updated the code to use 4pm as the reset time and that looks okay on the chart.
NOTE: The field will not work correctly while volume for the symbol is N/A. Once any shares get traded and volume has a numeric value then it should work.
The change is just to the definition of GxVol, as follows:
Ruby:
def GxVol = if secondsTillTime(1600) == 0
then 0
else if GlobeX and !GlobeX[1]
then volume
else if GlobeX
then CompoundValue(1, GxVol[1] + volume, volume)
else GxVol[1];
For different results on different timeframes, there's nothing I can do about that one. I think the issue with an Hour chart that caused infinity is because there's not an even number of whole hours in regular trading hours. There's 6.5. And the code is looking for 9:30am which is in the middle of an hour candle so never true. 15m works because 6.5 hours divides evenly by 15m. I think if you use timeframes that don't create partial candles in 6.5 hours it should be mostly okay.
We've seen, many times, values from TOS for one timeframe, such as for volume, don't match another timeframe. We expect we can add together volume for all the bars of the day and come up with the same total as the day chart but it's often not exact and it isn't something we have control over. It's the data they send us. It shouldn't be too far off, though.
I updated the code to display a % of the average instead of just above/below. If the volume is very close to the average, above/below doesn't mean much. If volume is 500% of average, that's meaningful. Here's the whole script. You may want to adjust the color thresholds near the bottom to fit your criteria.
Ruby:
def daysOnChart = if secondsTillTime(0930) == 0
then daysOnChart[1] + 1
else daysOnChart[1];
def GlobeX = getTime() < regularTradingStart(getYYYYMMDD());
def GxVol = if secondsTillTime(1600) == 0 then 0
else if GlobeX and !GlobeX[1]
then volume
else if GlobeX
then CompoundValue(1, GxVol[1] + volume, volume)
else GxVol[1];
def sumVol = if !GlobeX and GlobeX[1]
then sumVol[1] + GxVol[1]
else sumVol[1];
def v = GxVol;
def AvgGbX = HighestALL(if isNaN(close[-1])
then sumVol / daysOnChart
else double.nan);
plot pct = if IsNaN(GxVol) or GxVol == 0 then Double.NaN else Round(GxVol / AvgGbX * 100, 1);
pct.AssignValueColor(
if pct < 50 then Color.RED
else if pct < 80 then Color.DARK_ORANGE
else if pct < 120 then Color.YELLOW
else if pct < 200 then Color.UPTICK
else Color.GREEN
);
