Trying to define variable properly

[Trikortreat12]

I'm trying to write this script where I define 2 aggregation periods. 1 of them is daily, and other is hour/4 hour. My problem comes in when i want to define my 2nd aggregation period. I want to only have the aggregation period change if I have an ATR value greater than 3. I think it's a problem with the way integers/conditionals work in thinkscript, but am not sure.

input averagetype = AverageType.WILDERS;

input ATRlength = 10;
input Agg_1 = AggregationPeriod.Day;
def Agg_2;

def ATR = MovingAverage (averagetype, TrueRange(high(period = Agg_1)[1], close(period =  Agg_1)[1], low(period = Agg_1)[1]), ATRlength);

if (ATR > 3) {
Agg_2 = AggregationPeriod.FOUR_HOURS;
}
else {
Agg_2 = AggregationPeriod.HOUR;
}

 

[SleepyZ]

I'm trying to write this script where I define 2 aggregation periods. 1 of them is daily, and other is hour/4 hour. My problem comes in when i want to define my 2nd aggregation period. I want to only have the aggregation period change if I have an ATR value greater than 3. I think it's a problem with the way integers/conditionals work in thinkscript, but am not sure.

input averagetype = AverageType.WILDERS;

input ATRlength = 10;
input Agg_1 = AggregationPeriod.Day;
def Agg_2;

def ATR = MovingAverage (averagetype, TrueRange(high(period = Agg_1)[1], close(period =  Agg_1)[1], low(period = Agg_1)[1]), ATRlength);

if (ATR > 3) {
Agg_2 = AggregationPeriod.FOUR_HOURS;
}
else {
Agg_2 = AggregationPeriod.HOUR;
}

This syntax seems to work with a Plot statement with 2 different aggs vs a Def Statement with 2 different aggs

input averagetype = AverageType.WILDERS;

input ATRlength = 10;
input Agg_1 = AggregationPeriod.DAY;
plot Agg_2;

def ATR = Round(MovingAverage (averagetype, TrueRange(high(period = Agg_1)[1], close(period =  Agg_1)[1], low(period = Agg_1)[1]), ATRlength), 2);

if (ATR > 3) {
    Agg_2 = close(period = AggregationPeriod.FOUR_HOURS);
}
else {
    Agg_2 = close(period = AggregationPeriod.HOUR);
}

plot x1 = close(period = Agg_1);
plot x2 = Agg_2;

 

[halcyonguy]

I'm trying to write this script where I define 2 aggregation periods. 1 of them is daily, and other is hour/4 hour. My problem comes in when i want to define my 2nd aggregation period. I want to only have the aggregation period change if I have an ATR value greater than 3. I think it's a problem with the way integers/conditionals work in thinkscript, but am not sure.

input averagetype = AverageType.WILDERS;

input ATRlength = 10;
input Agg_1 = AggregationPeriod.Day;
def Agg_2;

def ATR = MovingAverage (averagetype, TrueRange(high(period = Agg_1)[1], close(period =  Agg_1)[1], low(period = Agg_1)[1]), ATRlength);

if (ATR > 3) {
Agg_2 = AggregationPeriod.FOUR_HOURS;
}
else {
Agg_2 = AggregationPeriod.HOUR;
}

i got distracted in the middle of my research on this and didn't realize sleepyz answered it, until i refreshed the page.
anyway, the more the merrier
merry christmas everyone

to expand on what @SleepyZ said

the problem you were running into, is that you can't define 2+ aggregation times in 1 formula.
. error: 2 different secondary periods can not be used in a variable

you can,
. define 2 different aggregation variables.
. create 2 formulas, each using one of the aggregation variables.
. then use an if-then to choose the desired value from the 2 formulas.

i don't know what you want to use the agg2 for, so i used close in my version.

i made a bubble to display several variables. it turns yellow when the if-then condition is true ( ATR > 3 )
i added a variable to represent the choosen aggregation minutes. it is the bottom value in the bubble.

# aggchoose_3rd

input averagetype = AverageType.WILDERS;
input ATRlength = 10;
input Agg_1 = AggregationPeriod.DAY;

def agg1_min = (Agg_1/60000);

def ATR = MovingAverage (averagetype, TrueRange(high(period = Agg_1)[1], close(period =  Agg_1)[1], low(period = Agg_1)[1]), ATRlength);

# -------------------------
# this section has an error
# error 2 different secondary periods can not be used in a variable

#def agg_2;
#if (ATR > 3) {
#  Agg_2 = AggregationPeriod.FOUR_HOURS;
#}
#else {
#  Agg_2 = AggregationPeriod.HOUR;
#}

#def cls2 = close(period = agg_2);
# ------------------------

input agg_3a = AggregationPeriod.FOUR_HOURS;
input agg_3b = AggregationPeriod.HOUR;
def agg3a_min = (Agg_3a/60000);
def agg3b_min = (Agg_3b/60000);

def cls_3a = close(period = agg_3a);
def cls_3b = close(period = agg_3b);

def cls3;
def aggmin;
if (ATR > 3) then {
  cls3 = cls_3a;
#  aggmin = (4 * 60);
  aggmin = agg3a_min;
} else {
  cls3 = cls_3b;
#  aggmin = (1 * 60);
  aggmin = agg3b_min;
}

# -------------------------
#def cls4 = if (ATR > 3) then cls_2a else cls_2b;

AddChartBubble(1, low * 0.99,
"len " + ATRlength
+ "\nA1 " + Agg1_min
+ "\natr " + ATR
#+ "\n------"
#+ "\nA2 " + (agg_2/60000)
#+ "\nc2" + cls2
+ "\n------"
+ "\n2a " + agg3a_min
+ "\n2b " + agg3b_min
+ "\nc3" + cls3
+ "\nAmin " + aggmin
, ( if (ATR > 3) then Color.YELLOW else Color.GRAY), no);
#

i tested with WMT 5day 15min
the bottom number shows the selected agg minutes