TOS Volume Profile to show # of contracts (blue bar)

[z32]

Been trying to come up w/ a way to modify TOS"s volume profile script to show the # of contracts for each bar (the blue ones on the right) but no luck. Is there anyone here who can help create a script using the existing TOS Volume Profile to show a number on each blue bar representing the # of contracts traded (that determines the thickness / width of the bar)

 

[SleepyZ]

Been trying to come up w/ a way to modify TOS"s volume profile script to show the # of contracts for each bar (the blue ones on the right) but no luck. Is there anyone here who can help create a script using the existing TOS Volume Profile to show a number on each blue bar representing the # of contracts traded (that determines the thickness / width of the bar)

View attachment 21406

1. This is a copy of the TOS Volumeprofile with some adjusttments to the coloring at lines 72-77 in the script , set default to DAY and the opacity to 20.

DefineGlobalColor("Profile", color.white);
DefineGlobalColor("Point Of Control", GetColor(5));
DefineGlobalColor("Value Area", color.magenta);

vol.show(globalColor("Profile"), if showPointOfControl then globalColor("Point Of Control") else color.current, if showValueArea then globalColor("Value Area") else color.current, opacity, "volume color" = Color.white);
POC.SetDefaultColor(globalColor("Point Of Control"));

2. The image (used 1d 1m instead of 1d TODAY) shows the volume in the white numbers on the left side. You need to expand the area to see all of the numbers. In manually adding these, I found that these seem to match the volume for the day.
3. We have very few things that we can do through scripting. Perhaps this might help you.

#
# TD Ameritrade IP Company, Inc. (c) 2010-2024
#

input pricePerRowHeightMode = {default AUTOMATIC, TICKSIZE, CUSTOM};
input customRowHeight = 1.0;
input timePerProfile = {CHART, MINUTE, HOUR, default DAY, WEEK, MONTH, "OPT EXP", BAR};
input multiplier = 1;
input onExpansion = yes;
input profiles = 1000;
input showPointOfControl = yes;
input showValueArea = yes;
input valueAreaPercent = 70;
input opacity = 20;

def period;
def yyyymmdd = getYyyyMmDd();
def seconds = secondsFromTime(0);
def month = getYear() * 12 + getMonth();
def day_number = daysFromDate(first(yyyymmdd)) + getDayOfWeek(first(yyyymmdd));
def dom = getDayOfMonth(yyyymmdd);
def dow = getDayOfWeek(yyyymmdd - dom + 1);
def expthismonth = (if dow > 5 then 27 else 20) - dow;
def exp_opt = month + (dom > expthismonth);
switch (timePerProfile) {
case CHART:
    period = 0;
case MINUTE:
    period = floor(seconds / 60 + day_number * 24 * 60);
case HOUR:
    period = floor(seconds / 3600 + day_number * 24);
case DAY:
    period = countTradingDays(min(first(yyyymmdd), yyyymmdd), yyyymmdd) - 1;
case WEEK:
    period = floor(day_number / 7);
case MONTH:
    period = floor(month - first(month));
case "OPT EXP":
    period = exp_opt - first(exp_opt);
case BAR:
    period = barNumber() - 1;
}

def count = CompoundValue(1, if period != period[1] then (count[1] + period - period[1]) % multiplier else count[1], 0);
def cond = count < count[1] + period - period[1];
def height;
switch (pricePerRowHeightMode) {
case AUTOMATIC:
    height = PricePerRow.AUTOMATIC;
case TICKSIZE:
    height = PricePerRow.TICKSIZE;
case CUSTOM:
    height = customRowHeight;
}

profile vol = volumeProfile("startNewProfile" = cond, "onExpansion" = onExpansion, "numberOfProfiles" = profiles, "pricePerRow" = height, "value area percent" = valueAreaPercent);
def con = compoundValue(1, onExpansion, no);
def pc = if IsNaN(vol.getPointOfControl()) and con then pc[1] else vol.getPointOfControl();
def hVA = if IsNaN(vol.getHighestValueArea()) and con then hVA[1] else vol.getHighestValueArea();
def lVA = if IsNaN(vol.getLowestValueArea()) and con then lVA[1] else vol.getLowestValueArea();

def hProfile = if IsNaN(vol.getHighest()) and con then hProfile[1] else vol.getHighest();
def lProfile = if IsNaN(vol.getLowest()) and con then lProfile[1] else vol.getLowest();
def plotsDomain = IsNaN(close) == onExpansion;

plot POC = if plotsDomain then pc else Double.NaN;
plot ProfileHigh = if plotsDomain then hProfile else Double.NaN;
plot ProfileLow = if plotsDomain then lProfile else Double.NaN;
plot VAHigh = if plotsDomain then hVA else Double.NaN;
plot VALow = if plotsDomain then lVA else Double.NaN;

DefineGlobalColor("Profile", color.white);
DefineGlobalColor("Point Of Control", GetColor(5));
DefineGlobalColor("Value Area", color.magenta);

vol.show(globalColor("Profile"), if showPointOfControl then globalColor("Point Of Control") else color.current, if showValueArea then globalColor("Value Area") else color.current, opacity, "volume color" = Color.white);
POC.SetDefaultColor(globalColor("Point Of Control"));
POC.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VAHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VALow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
VAHigh.SetDefaultColor(globalColor("Value Area"));
VALow.SetDefaultColor(globalColor("Value Area"));
ProfileHigh.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
ProfileLow.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
ProfileHigh.SetDefaultColor(GetColor(3));
ProfileLow.SetDefaultColor(GetColor(3));
ProfileHigh.hide();
ProfileLow.hide();


#

 

[Rascanpincas]

1. This is a copy of the TOS Volumeprofile with some adjusttments to the coloring at lines 72-77 in the script , set default to DAY and the opacity to 20.

2. The image (used 1d 1m instead of 1d TODAY) shows the volume in the white numbers on the left side. You need to expand the area to see all of the numbers. In manually adding these, I found that these seem to match the volume for the day.
3. We have very few things that we can do through scripting. Perhaps this might help you.

Great tool thanks!