Signals based on RSI, BB, and Moving Average

[Babisco]

Greeting to everyone is my please to joined this amazing community I'm very grateful
please I needed your help I have been working on this script but note able to make it work on ThinkOrSwim

# Trend Following with Mean Reversion Strategy
# Inputs
input lengthMA = 50;
input lengthBB = 20;
input lengthRSI = 14;
input overbought = 70;
input oversold = 30;
# Define indicators
def MA = Average(close, lengthMA);
def UpperBB = BollingerBandTop(close, lengthBB);
def LowerBB = BollingerBandBottom(close, lengthBB);
def RSI = RSI(close, lengthRSI);
# Entry rules
def longCondition = close > MA and RSI < oversold and close crosses above LowerBB;
def shortCondition = close < MA and RSI > overbought and close crosses below UpperBB;
# Exit rules
def longExit = close crosses below UpperBB or RSI > overbought;
def shortExit = close crosses above LowerBB or RSI < oversold;
# Plot signals
plot longEntry = if longCondition then Low else Double.NaN;
plot shortEntry = if shortCondition then High else Double.NaN;
plot longExitSignal = if longExit then Low else Double.NaN;
plot shortExitSignal = if shortExit then High else Double.NaN;
longEntry.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longEntry.SetDefaultColor(Color.GREEN);
shortEntry.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortEntry.SetDefaultColor(Color.RED);
longExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longExitSignal.SetDefaultColor(Color.GREEN);
shortExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortExitSignal.SetDefaultColor(Color.RED);
# Alerts
Alert(longCondition, "Long Entry", "Long Entry Signal", Alert.BAR, Sound.RING);
2
Alert(shortCondition, "Short Entry", "Short Entry Signal", Alert.BAR, Sound.RING);
Alert(longExit, "Long Exit", "Long Exit Signal", Alert.BAR, Sound.RING);
Alert(shortExit, "Short Exit", "Short Exit Signal", Alert.BAR, Sound.RING);

 

[halcyonguy]

Greeting to everyone is my please to joined this amazing community I'm very grateful
please I needed your help I have been working on this script but note able to make it work on ThinkOrSwim

# Trend Following with Mean Reversion Strategy
# Inputs
input lengthMA = 50;
input lengthBB = 20;
input lengthRSI = 14;
input overbought = 70;
input oversold = 30;
# Define indicators
def MA = Average(close, lengthMA);
def UpperBB = BollingerBandTop(close, lengthBB);
def LowerBB = BollingerBandBottom(close, lengthBB);
def RSI = RSI(close, lengthRSI);
# Entry rules
def longCondition = close > MA and RSI < oversold and close crosses above LowerBB;
def shortCondition = close < MA and RSI > overbought and close crosses below UpperBB;
# Exit rules
def longExit = close crosses below UpperBB or RSI > overbought;
def shortExit = close crosses above LowerBB or RSI < oversold;
# Plot signals
plot longEntry = if longCondition then Low else Double.NaN;
plot shortEntry = if shortCondition then High else Double.NaN;
plot longExitSignal = if longExit then Low else Double.NaN;
plot shortExitSignal = if shortExit then High else Double.NaN;
longEntry.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longEntry.SetDefaultColor(Color.GREEN);
shortEntry.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortEntry.SetDefaultColor(Color.RED);
longExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longExitSignal.SetDefaultColor(Color.GREEN);
shortExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortExitSignal.SetDefaultColor(Color.RED);
# Alerts
Alert(longCondition, "Long Entry", "Long Entry Signal", Alert.BAR, Sound.RING);
2
Alert(shortCondition, "Short Entry", "Short Entry Signal", Alert.BAR, Sound.RING);
Alert(longExit, "Long Exit", "Long Exit Signal", Alert.BAR, Sound.RING);
Alert(shortExit, "Short Exit", "Short Exit Signal", Alert.BAR, Sound.RING);

if you look up the functions, you would realize the spelling errors and wrong input parameters
https://toslc.thinkorswim.com/center/reference/Tech-Indicators/studies-library/A-B/BollingerBands
notes in comments

#signals_rsi_bb_ma

#https://usethinkscript.com/threads/signals-based-on-rsi-bb-and-moving-average.19517/
#Signals based on RSI, BB, and Moving Average
#Babisco  9/9

#1
#Greeting to everyone is my please to joined this amazing community I'm very grateful
#please I needed your help I have been working on this script but note able to make it work on ThinkOrSwim

# Trend Following with Mean Reversion Strategy
# Inputs
input lengthMA = 50;
input lengthBB = 20;
input lengthRSI = 14;
input overbought = 70;
input oversold = 30;

# Define indicators
def MA = Average(close, lengthMA);

#  wrong study name. didn't use correct plot name
def UpperBB = BollingerBands(close, lengthBB).upperband;
def LowerBB = BollingerBands(close, lengthBB).LowerBand;

# BollingerBands
#plot MidLine = MovingAverage(averageType, data = price[-displace], length = length);
#plot LowerBand = MidLine + num_Dev_Dn * sDev;
#plot UpperBand = MidLine + num_Dev_Up * sDev;



# inputs in wrong order
def RSI = RSI(length = lengthRSI, price = close);

# rsi inputs
#input length = 14;
#input over_Bought = 70;
#input over_Sold = 30;
#input price = close;
#input averageType = AverageType.WILDERS;
#input showBreakoutSignals = no;





# Entry rules
def longCondition = close > MA and RSI < oversold and close crosses above LowerBB;
def shortCondition = close < MA and RSI > overbought and close crosses below UpperBB;
# Exit rules
def longExit = close crosses below UpperBB or RSI > overbought;
def shortExit = close crosses above LowerBB or RSI < oversold;
# Plot signals
plot longEntry = if longCondition then low else Double.NaN;
plot shortEntry = if shortCondition then high else Double.NaN;
plot longExitSignal = if longExit then low else Double.NaN;
plot shortExitSignal = if shortExit then high else Double.NaN;
longEntry.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longEntry.SetDefaultColor(Color.GREEN);
shortEntry.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortEntry.SetDefaultColor(Color.RED);
longExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
longExitSignal.SetDefaultColor(Color.GREEN);
shortExitSignal.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
shortExitSignal.SetDefaultColor(Color.RED);


# had extra text value
# Alerts
Alert(longCondition, "Long Entry Signal", Alert.BAR, Sound.Ring);
Alert(shortCondition, "Short Entry Signal", Alert.BAR, Sound.Ring);
Alert(longExit,  "Long Exit Signal", Alert.BAR, Sound.Ring);
Alert(shortExit,  "Short Exit Signal", Alert.BAR, Sound.Ring);