SELL_TO_CLOSE after a number of bars

[krose]

I want to backtest a strategy that does a SELL_TO_CLOSE within a given number of bars if a target price hasn't been reached. Is there a function that tells the number of bars a trade has been opened? Or a method one can follow to keep a count that can be used in the SELL_TO_CLOSE test?

The following snippet describes what I've tried (that isn't working):

def longOpenRule = aboveBars > minLongBarsSinceMACross
  and rsiCrossBelow
  and price > trendDef;
def longTargetReached = price >= (EntryPrice() * (1 + (longExitPct  / 100)));

def barCount = if !EntryPrice() then 0 else barCount[1] + 1;

AddOrder(OrderType.BUY_TO_OPEN, longOpenRule, price, tradeSize);
AddOrder(OrderType.SELL_TO_CLOSE,longTargetReached or barCount > maxLongBars, price, tradeSize);

 

[halcyonguy]

I want to backtest a strategy that does a SELL_TO_CLOSE within a given number of bars if a target price hasn't been reached. Is there a function that tells the number of bars a trade has been opened? Or a method one can follow to keep a count that can be used in the SELL_TO_CLOSE test?

The following snippet describes what I've tried (that isn't working):

def longOpenRule = aboveBars > minLongBarsSinceMACross
  and rsiCrossBelow
  and price > trendDef;
def longTargetReached = price >= (EntryPrice() * (1 + (longExitPct  / 100)));

def barCount = if !EntryPrice() then 0 else barCount[1] + 1;

AddOrder(OrderType.BUY_TO_OPEN, longOpenRule, price, tradeSize);
AddOrder(OrderType.SELL_TO_CLOSE,longTargetReached or barCount > maxLongBars, price, tradeSize);

maybe try using the same variable as in your addorder, to drive the counter?

def barCount = if barnumber() == 1 then 0 
 else if longTargetReached then 0
 else if longOpenRule then 0
 else barCount[1] + 1;

a variation to try, reset to a negative number when trade closed, so the count will be negative.
then you can check if count > 0 to see if it is valid

# if barcount > 0 then a trade is open
def barCount = if barnumber() == 1 then 0 
 else if longTargetReached then -99999
 else if longOpenRule then 0
 else barCount[1] + 1;

 

[krose]

Posting back because I finally found a good way to do this simply. The days in the current position is simple if you leverage the EntryPrice() function:

def posCount = if isNaN(EntryPrice()) then 0 else posCount[1] + 1;

This value can be used to close a position after it has been open for a specified period of time. Here's a simple strategy to illustrate:

# ====================================
# MA Crosover Strategy
# ====================================

input price = open;

input fastMAbars = 3;
input slowMAbars = 20;
input maAverageType = AverageType.WILDERS;

input holdBars = 20;

# ------------------------------------
# Situation
# ------------------------------------
plot fastMA = MovingAverage(maAverageType, price, fastMAbars);
plot slowMA = MovingAverage(maAverageType, price, slowMAbars);

def bullCross = fastMA > slowMA and fastMA[1] <= slowMA[1];
def bearCross = fastMA < slowMA and fastMA[1] >= slowMA[1];

# ------------------------------------
# Rules
# ------------------------------------
def posCount = if isNaN(EntryPrice()) then 0 else posCount[1] + 1;

def bullOpen  = bullCross;
def bullClose = bearCross or posCount >= holdBars;

def bearOpen  = bearCross;
def bearClose = bullCross or posCount >= holdBars;

# ------------------------------------
# Orders
# ------------------------------------
AddOrder(OrderType.BUY_TO_OPEN,   bullOpen, price, name = "BullOpen");
AddOrder(OrderType.SELL_TO_CLOSE, bullClose, price, name = "BullClose");

AddOrder(OrderType.SELL_TO_OPEN,  bearOpen, price, name = "BearOpen");
AddOrder(OrderType.BUY_TO_CLOSE,  bearClose, price, name = "BearClose");