Scanning For Filter Between 30 and 300 bars ago

[TosRox]

Hi ThinkScripters. Have a thinkscript question that maybe simple for somebody to respond to. In Stock Hacker I am looking for an event that occured "between a RANGE of bars" ago. In this case I don't want a moving average cross-over to have occured between 300 and 30 bars ago.
The thinkScript in stock hacker that I used which it will not accept is:

MovingAvgCrossover("length1" = 50, "length2" = 200) is false within between 300 and 30 bars.

So the question is what is the correct thinkscript for a within "RANGE of bars" ago.

Appreciate the assistance!

 

[halcyonguy]

Hi ThinkScripters. Have a thinkscript question that maybe simple for somebody to respond to. In Stock Hacker I am looking for an event that occured "between a RANGE of bars" ago. In this case I don't want a moving average cross-over to have occured between 300 and 30 bars ago.
The thinkScript in stock hacker that I used which it will not accept is:

MovingAvgCrossover("length1" = 50, "length2" = 200) is false within between 300 and 30 bars.

So the question is what is the correct thinkscript for a within "RANGE of bars" ago.

Appreciate the assistance!

here is a lower study to experiment with
i disabled MovingAvgCrossover() as my signal didn't seem right.
i added MovingAverage()'s and looked for 'crosses' and that worked.

this can take 10 seconds to draw the chart, so not sure if it will work in a scan.
not tested in a scan.

#crossover_in_past

#https://usethinkscript.com/threads/scanning-for-filter-between-30-and-300-bars-ago.16094/
#Scanning For Filter Between 30 and 300 bars ago
#TosRox  7/16

#Hi ThinkScripters. Have a thinkscript question that maybe simple for somebody to respond to. In Stock Hacker I am looking for an event that occured "between a RANGE of bars" ago. In this case I don't want a moving average cross-over to have occured between 300 and 30 bars ago.

#The thinkScript in stock hacker that I used which it will not accept is:

#MovingAvgCrossover("length1" = 50, "length2" = 200) is false within between 300 and 30 bars.

#So the question is what is the correct thinkscript for a within "RANGE of bars" ago.

declare lower;

def na = Double.NaN;
def bn = BarNumber();

def price = close;
input avg1_len = 50;
input avg1_type = AverageType.EXPONENTIAL;
def ma1 = MovingAverage(avg1_type, price, avg1_len);

input avg2_len = 200;
input avg2_type = AverageType.EXPONENTIAL;
def ma2 = MovingAverage(avg2_type, price, avg2_len);

#def x = MovingAvgCrossover(price = close, length1 = avg1_len, length2 = avg2_len);
def x2 = ma1 crosses ma2;

input bars_back_start = 30;
input bars_back_stop = 300;

def rng = bars_back_stop - bars_back_start;

#def xcnt = sum(x[bars_back_start], rng);
def xcnt = sum(x2[bars_back_start], rng);

plot z = if xcnt == 0 then 1 else 0;


#----------------------
#input show_lines = yes;
#plot z1 = if show_lines then ma1 else na;
#z1.SetDefaultColor(GetColor(1));
#z1.HideBubble();

#plot z2 = if show_lines then ma2 else na;
#z2.SetDefaultColor(GetColor(2));
#z2.HideBubble();

#

settings of 10 and 20 for bars back

--------------------


upper for testing

# ma12_cross

def na = double.nan;
def bn = barnumber();

def price = close;

input ma1_len = 50;
def len1 = if ma1_len == 0 then 1 else ma1_len;
input ma1_type =  AverageType.EXPONENTIAL;
def ma1 = MovingAverage(ma1_type, price, len1);

input ma2_len = 200;
def len2 = if ma2_len == 0 then 1 else ma2_len;
input ma2_type =  AverageType.EXPONENTIAL;
def ma2 = Movingaverage(ma2_type, price, len2);

input show_lines = yes;
plot z1 = if show_lines and len1 > 1 then ma1 else na;
z1.setdefaultcolor(getcolor(1));
#z1.setlineweight(1);
z1.hidebubble();

plot z2 = if show_lines and len2 > 1 then ma2 else na;
z2.setdefaultcolor(getcolor(2));
#z2.setlineweight(1);
z2.hidebubble();
#