RSM Indicator for ThinkorSwim

[waltj]

Solid work here guys @cos251, @Joseph Patrick 18, @SuryaKiranC, @RickAns, @TradeUp

I was curious why yall chose to use Wilders on the SlowK, Exponential on the RSI and Weighted on the MACD?

i read his book along with the pdf that was posted here:

https://usethinkscript.com/threads/rsm-indicator-for-thinkorswim.5407/post-50775

and none of those settings are mentioned. Maybe i skimmed thru that part.

regardless great work!!. i just toggle the indicators to my liking

 

[trendr]

Solid work here guys @cos251, @Joseph Patrick 18, @SuryaKiranC, @RickAns, @TradeUp

I was curious why yall chose to use Wilders on the SlowK, Exponential on the RSI and Weighted on the MACD?

i read his book along with the pdf that was posted here:

https://usethinkscript.com/threads/rsm-indicator-for-thinkorswim.5407/post-50775

and none of those settings are mentioned. Maybe i skimmed thru that part.

regardless great work!!. i just toggle the indicators to my liking

I personally use the settings mentioned in the book (except SlowD, I made the changes in one version of the script and compared to slowK and slowK gets me in on average 1 day earlier.) and I have had great success swing trading the strategy. The code base in this thread is awesome, but my opinion is that most of the adapted settings should be set to the original considering that’s how the strategy was tested by Markus. That‘s what I use and it works well, obviously changes can be made as you actually trade the strategy live and based on data you personally collect. This is an awesome project, and I thank all of the contributors for their hard work.

 

[RickAns]

@tron and @trendr , I use the original stop plus an adapted 1.5 ATR daily Trailing Stop that follows the original Entry Signal given by PowerX. Have it set up to use as a daily stop to give as much retracement as the original position. Each day as the price goes up (hopefully) it follows by the original amount. As well as a trailing hourly (or 30 min) Stop to give a warning if the price moves down enough for me to watch it more closely. It might not be perfect but it gives me a nice perspective on what the price movement is doing on my intra day charts.


@BigMiniFridge good to see another fan of the PowerX system. Glad to hear you like it enough to have been using for some time. I still consider myself somewhat new to it but am liking it. I still enjoy watching Markus' videos to get his input on the days events.


@waltj Maybe I overlooked it but do you have reason to think that Markus is using something other than 'Wilders on the SlowK, Exponential on the RSI and Weighted on the MACD?' If so please say. I would be willing to swap over to the different calculations to see how they do.

 

[waltj]

@waltj Maybe I overlooked it but do you have reason to think that Markus is using something other than 'Wilders on the SlowK, Exponential on the RSI and Weighted on the MACD?' If so please say. I would be willing to swap over to the different calculations to see how they do.

My only reason would be based on my TOS settings

My defaults are MACD Exponential

RSI Wilders

and Stoch Slow Simple

I realize Markus is using TradingView and from what i know of TV(which isnt very much) there are no adjustments from wilders to exponential, simple etc. I dont know what the TV defaults are for the indicators used. So im basing everything on TOS

 

[RickAns]

Good call on that, @waltj . I had not noticed that before and just went in to thinkorswim to check. You are right about the ToS defaults for those indicators. I do think that in the early days of this that some settings were adjusted to make the charts seem to line up with what was seen from the pdf article. I am going to test with changes. Thanks for bringing this up. Anything else you notice, please say.

 

[trendr]

Just some current swings I am in so you can see my setup. Ignore colors etc... just cosmetic changes $GM, $UUUU I have several more I am currently in but it boils down to trading the strategy so you can build confidence in it with appropriate risk to your account so you can follow the plan.

 

[trendr]

Just some current swings I am in so you can see my setup. Ignore colors etc... just cosmetic changes $GM, $UUUU I have several more I am currently in but it boils down to trading the strategy so you can build confidence in it with appropriate risk to your account so you can follow the plan.

I mostly swing trade options on equities, but I even trade some OTC with the strategy. $FDMSF today.

 

[tron]

@tron and @trendr , I use the original stop plus an adapted 1.5 ATR daily Trailing Stop that follows the original Entry Signal given by PowerX. Have it set up to use as a daily stop to give as much retracement as the original position. Each day as the price goes up (hopefully) it follows by the original amount. As well as a trailing hourly (or 30 min) Stop to give a warning if the price moves down enough for me to watch it more closely. It might not be perfect but it gives me a nice perspective on what the price movement is doing on my intra day charts.


@BigMiniFridge good to see another fan of the PowerX system. Glad to hear you like it enough to have been using for some time. I still consider myself somewhat new to it but am liking it. I still enjoy watching Markus' videos to get his input on the days events.


@waltj Maybe I overlooked it but do you have reason to think that Markus is using something other than 'Wilders on the SlowK, Exponential on the RSI and Weighted on the MACD?' If so please say. I would be willing to swap over to the different calculations to see how they do.

@RickAns - I actually reached out to Markus during one of his live streams and asked the same question. He likes to lock in the ADR at the time the trade is made. For simplicity, I totally get it, but I have seen some pretty noteworthy changes in ADR from one day to the next. So your method intrigues me......

 

[RickAns]

@tron That is really cool you had a chance to chat with Markus. I like his locked in Stop and I use it but I feel better also having a trailing stop for when the market gets news it does not like and decides to swing against me. If the market trends nicely in my direction I am less concerned on the stops. When the market behaves like it has an upset stomach then I start to think about trailing stops more. Good example being today's 400 point dip in the NASDAQ. Much rather get trailing stopped out early while in a profit then have it drop through the entry point and on down to the stop for a loss.

I took the ATR TRailing Stop of thinkorswim and modifed it to mimic Markus' Stop while adjusting to a new days gains. Wanted something quick and easy to test my idea, only been using this a few weeks. Also, I find this useful if I decide that the stock will continue running up beyond Markus' Profit Target and let a partial position ride to make futher gains. Easier for me to see when it has finished it's run and to step out. Instead of getting out completely as Markus suggests and moving on to another stock.

Basically, I changed the ATRperiod to 7, ATRfactor to 1.5, changed Aggregation to day, commented out their plot signals, added my own plots, label and an alert. Used the unmodified version since the modified smooths the signal. Not sure if averagetype should be Wilders but since this is not meant to be exact I left it. This is Long side only, not made the leap to Shorting side yet so did not code for it. Can add another instance of this and set to 4Hour, hour, thirty min, etc. if wanting an earlier warning.

It can also be set for the bar's low or it's close to fall below the trailing stop to trigger alert. I run this on my intra-day 15 min chart. I may re-write this to be less sloppy later on when I have decided what direction to take it.

Hope this explains things.

#
# TD Ameritrade IP Company, Inc. (c) 2009-2021
#

##  Unmodified = calculations use the ATR on defined period multiplied by the specified factor.
##  Modified = calculations uses long period MA, minimizing gaps between adjacent bars, smoothing out sharp surges in price.

input trailType = {default unmodified, modified};
input ATRPeriod = 7;   # default 5, changed to make more like PowerX
input ATRFactor = 1.5;  #default 3.5, changed to make more like PowerX
input firstTrade = {default long, short};
input averageType = AverageType.WILDERS;

Assert(ATRFactor > 0, "'atr factor' must be positive: " + ATRFactor);

  ##  *modified formula*
def HiLo = Min(high - low, 1.5 * Average(high - low, ATRPeriod));
def HRef = if low <= high[1]
    then high - close[1]
    else (high - close[1]) - 0.5 * (low - high[1]);
def LRef = if high >= low[1]
    then close[1] - low
    else (close[1] - low) - 0.5 * (low[1] - high);
  ##  *end of modified formula*


  # my add for 1 Day  trailing stop
def highHr = high(Period = AggregationPeriod.Day);
def closeHr = close(Period = AggregationPeriod.Day);
def lowHr = low(Period = AggregationPeriod.Day);


def trueRange;
switch (trailType) {
case modified:
    trueRange = Max(HiLo, Max(HRef, LRef));
case unmodified:
    trueRange = TrueRange(highHr, closeHr, lowHr);
}

def loss = ATRFactor * MovingAverage(averageType, trueRange, ATRPeriod);

def state = {default init, long, short};
def trail;
switch (state[1]) {
case init:
    if (!IsNaN(loss)) {
        switch (firstTrade) {
        case long:
            state = state.long;
            trail =  close - loss;
        case short:
            state = state.short;
            trail = close + loss;
        }
    } else {
        state = state.init;
        trail = Double.NaN;
    }
case long:
    if (closeHr > trail[1]) {
        state = state.long;
        trail = Max(trail[1], closeHr - loss);
    } else {
        state = state.short;
        trail = close + loss;
    }
case short:
    if (close < trail[1]) {
        state = state.short;
        trail = Min(trail[1], close + loss);
    } else {
        state = state.long;
        trail =  close - loss;
    }
}

#def BuySignal = Crosses(state == state.long, 0, CrossingDirection.ABOVE);
#def SellSignal = Crosses(state == state.short, 0, CrossingDirection.ABOVE);
#plot TrailingStop = trail;
#TrailingStop.SetPaintingStrategy(PaintingStrategy.POINTS);
#TrailingStop.DefineColor("Buy", GetColor(0));
#TrailingStop.DefineColor("Sell", GetColor(1));
#TrailingStop.AssignValueColor(if state == state.long
#    then TrailingStop.Color("Sell")
#    else TrailingStop.Color("Buy"));


## my add
plot TrailStop = if state == state.long then Trail else Double.NaN;
TrailStop.SetDefaultColor(Color.dark_orange);
TrailStop.SetPaintingStrategy(PaintingStrategy.squares);

AddLabel(yes and state == state.long, "TrailStop-Day: " +round(Trail, 2)+ "", color.dark_orange);
AddLabel(yes and state == state.long and low crosses below Trail, "!!! ALERT : 1Day Trail Stop Hit !!!", color.plum);
alert(state == state.long and low crosses below Trail,"!!! ALERT : 1Day Trail Stop Hit !!!",alert.BAR,sound.RING);

 

[trendr]

Please advice if this is the recommended setting?
RSI 7 Wilders
SlowK 14,3,simple
MACD exponential

That is what I am using. That is closest to Markus excluding that he uses SlowD

 

[tron]

@tron That is really cool you had a chance to chat with Markus. I like his locked in Stop and I use it but I feel better also having a trailing stop for when the market gets news it does not like and decides to swing against me. If the market trends nicely in my direction I am less concerned on the stops. When the market behaves like it has an upset stomach then I start to think about trailing stops more. Good example being today's 400 point dip in the NASDAQ. Much rather get trailing stopped out early while in a profit then have it drop through the entry point and on down to the stop for a loss.

I took the ATR TRailing Stop of thinkorswim and modifed it to mimic Markus' Stop while adjusting to a new days gains. Wanted something quick and easy to test my idea, only been using this a few weeks. Also, I find this useful if I decide that the stock will continue running up beyond Markus' Profit Target and let a partial position ride to make futher gains. Easier for me to see when it has finished it's run and to step out. Instead of getting out completely as Markus suggests and moving on to another stock.

Basically, I changed the ATRperiod to 7, ATRfactor to 1.5, changed Aggregation to day, commented out their plot signals, added my own plots, label and an alert. Used the unmodified version since the modified smooths the signal. Not sure if averagetype should be Wilders but since this is not meant to be exact I left it. This is Long side only, not made the leap to Shorting side yet so did not code for it. Can add another instance of this and set to 4Hour, hour, thirty min, etc. if wanting an earlier warning.

It can also be set for the bar's low or it's close to fall below the trailing stop to trigger alert. I run this on my intra-day 15 min chart. I may re-write this to be less sloppy later on when I have decided what direction to take it.

Hope this explains things.

#
# TD Ameritrade IP Company, Inc. (c) 2009-2021
#

##  Unmodified = calculations use the ATR on defined period multiplied by the specified factor.
##  Modified = calculations uses long period MA, minimizing gaps between adjacent bars, smoothing out sharp surges in price.

input trailType = {default unmodified, modified};
input ATRPeriod = 7;   # default 5, changed to make more like PowerX
input ATRFactor = 1.5;  #default 3.5, changed to make more like PowerX
input firstTrade = {default long, short};
input averageType = AverageType.WILDERS;

Assert(ATRFactor > 0, "'atr factor' must be positive: " + ATRFactor);

  ##  *modified formula*
def HiLo = Min(high - low, 1.5 * Average(high - low, ATRPeriod));
def HRef = if low <= high[1]
    then high - close[1]
    else (high - close[1]) - 0.5 * (low - high[1]);
def LRef = if high >= low[1]
    then close[1] - low
    else (close[1] - low) - 0.5 * (low[1] - high);
  ##  *end of modified formula*


  # my add for 1 Day  trailing stop
def highHr = high(Period = AggregationPeriod.Day);
def closeHr = close(Period = AggregationPeriod.Day);
def lowHr = low(Period = AggregationPeriod.Day);


def trueRange;
switch (trailType) {
case modified:
    trueRange = Max(HiLo, Max(HRef, LRef));
case unmodified:
    trueRange = TrueRange(highHr, closeHr, lowHr);
}

def loss = ATRFactor * MovingAverage(averageType, trueRange, ATRPeriod);

def state = {default init, long, short};
def trail;
switch (state[1]) {
case init:
    if (!IsNaN(loss)) {
        switch (firstTrade) {
        case long:
            state = state.long;
            trail =  close - loss;
        case short:
            state = state.short;
            trail = close + loss;
        }
    } else {
        state = state.init;
        trail = Double.NaN;
    }
case long:
    if (closeHr > trail[1]) {
        state = state.long;
        trail = Max(trail[1], closeHr - loss);
    } else {
        state = state.short;
        trail = close + loss;
    }
case short:
    if (close < trail[1]) {
        state = state.short;
        trail = Min(trail[1], close + loss);
    } else {
        state = state.long;
        trail =  close - loss;
    }
}

#def BuySignal = Crosses(state == state.long, 0, CrossingDirection.ABOVE);
#def SellSignal = Crosses(state == state.short, 0, CrossingDirection.ABOVE);
#plot TrailingStop = trail;
#TrailingStop.SetPaintingStrategy(PaintingStrategy.POINTS);
#TrailingStop.DefineColor("Buy", GetColor(0));
#TrailingStop.DefineColor("Sell", GetColor(1));
#TrailingStop.AssignValueColor(if state == state.long
#    then TrailingStop.Color("Sell")
#    else TrailingStop.Color("Buy"));


## my add
plot TrailStop = if state == state.long then Trail else Double.NaN;
TrailStop.SetDefaultColor(Color.dark_orange);
TrailStop.SetPaintingStrategy(PaintingStrategy.squares);

AddLabel(yes and state == state.long, "TrailStop-Day: " +round(Trail, 2)+ "", color.dark_orange);
AddLabel(yes and state == state.long and low crosses below Trail, "!!! ALERT : 1Day Trail Stop Hit !!!", color.plum);
alert(state == state.long and low crosses below Trail,"!!! ALERT : 1Day Trail Stop Hit !!!",alert.BAR,sound.RING);

@RickAns - Thanks for the logic, I'll definitely give it a shot in my RSM Chart and Profit/Stop Loss Study. I generally try to catch Markus's live youtube stream on M, W, F at 3:30 - 4:15 ET. He usually answers questions after his topic of the day and I have found that if you get your question in early, you have a great chance that he'll answer it.

 

[Csharp]

can someone check my code for the ADR for 7 days using the $200 limit in his .pdf something seems off. also this is my first Frankenstein script so please feel free to rip it apart

#Hint: Average Daily Range

def len = 2;

def dayHigh = DailyHighLow(AggregationPeriod.DAY, len, 0, no).dailyhigh;
def dayLow = DailyHighLow(AggregationPeriod.DAY, len, 0, no).DailyLow;


def ADR_high = (dayHigh + dayHigh[1] + dayHigh[2] + dayHigh[3] + dayHigh[4] + dayHigh[5] + dayHigh[6]) / 7;
def ADR_low = (dayLow + dayLow[1] + dayLow[2] + dayLow[3] + dayLow[4] + dayLow[5] + dayLow[6]) / 7;

def hiz = (ADR_high - ADR_low);
def amount = round(hiz * 200);

plot hiiz = hiz;
plot amounts = amount;
addlabel(yes, "account: " + 200 + "  shares: " + amounts,color.yellow);

 

[waltj]

Yes

This is what i came up with

#Hint: Average Daily Range

def len = 1;

def dayHigh = DailyHighLow(AggregationPeriod.DAY, len, 0, no).dailyhigh;
def dayLow = DailyHighLow(AggregationPeriod.DAY, len, 0, no).DailyLow;


def ADR_high = (dayHigh + dayHigh[1] + dayHigh[2] + dayHigh[3] + dayHigh[4] + dayHigh[5] + dayHigh[6]) / 7;
def ADR_low = (dayLow + dayLow[1] + dayLow[2] + dayLow[3] + dayLow[4] + dayLow[5] + dayLow[6]) / 7;

def hiz = (ADR_high - ADR_low);
def amount = Round(200 / (hiz * 1.5));

plot hiiz = hiz;
plot amounts = amount;
AddLabel(yes, "account: " + 200 + "  shares: " + amounts, Color.BLUE);

 

[waltj]

Thanks. I was wondering if there was a quick way to figure this out without pulling out a calculator

I went with what you started earlier.....Might be something your after

#Hint: Average Daily Range

input RA = 100;      #Risk Amount
input Entry = high;  #Entry location   (High, Close, etc)
def len = 1;

def dayHigh = DailyHighLow(AggregationPeriod.DAY, len, 0, no).dailyhigh;
def dayLow = DailyHighLow(AggregationPeriod.DAY, len, 0, no).DailyLow;


def ADR_high = (dayHigh + dayHigh[1] + dayHigh[2] + dayHigh[3] + dayHigh[4] + dayHigh[5] + dayHigh[6]) / 7;
def ADR_low = (dayLow + dayLow[1] + dayLow[2] + dayLow[3] + dayLow[4] + dayLow[5] + dayLow[6]) / 7;

def hiz = (ADR_high - ADR_low);

def amount = round(RA / (1.5 * hiz));
plot amounts = amount;

def entries = entry + 0.01;

def stop = round(entries - (1.5*hiz));
plot stops = stop;

def t1 = entries + ((1.5*hiz));

def t2 = t1 + ((1.5*hiz));

def t3 = t2 + ((1.5*hiz));

def t4 = t3 + ((1.5*hiz));

AddLabel(yes, "Risk: " + RA, color.Dark_red);

AddLabel(yes, "  Shares: " + amounts, color.blue);

AddLabel(yes, "  Entry: " + entries, color.dark_green);

AddLabel(yes, "  Stop: " + stops, color.red);

AddLabel(yes, "  Target 1: " + t1, color.light_ORANGE);

AddLabel(yes, "  Target 2: " +t2, color.magenta);

AddLabel(yes, "  Target 3: " + t3, color.light_orange);

 

[trendr]

Noob question here: but is there a way to show RSM on weekly charts?

I haven't been able to figure it out yet. I know the scan works on the weekly chart but I'm not much of coder so I don't know how to color bars on weekly chart.

 

[ApeX Predator]

I haven't been able to figure it out yet. I know the scan works on the weekly chart but I'm not much of coder so I don't know how to color bars on weekly chart.

@trendr @JohnsonM RSM Works on Weekly, we do show the trend on Weekly, what you are must be looking for is ADR/ATR ranges. Unfortunately given the amount of data used in their calculations it's not feasible to project ADR/ATR ranges on weekly, charts. try use RSI Laguerre_MTF for range projections on weekly. Search that work here in this forum, there are plenty of threads on that topic.

-S

 

[bhaskar_madugula]

Can we use this for swing trading? What timeframe you suggest?

 

[ApeX Predator]

Can we use this for swing trading? What timeframe you suggest?

Higher frames, 4H and above sometimes 2H too, specially if I find it towards the last 2 hours of trading day.

-S

 

[FOTM_8888]

Update - Version 1.9
Added Feature (thanks to @SleepZ)

1. Added feature to only plot current ADR Targets and stoploss

Update - Version 1.8
Fixed the following:

1. Plot Up/Down arrows on weekly chart
2. Plot uptrend/downtrend stoploss target and price targets on weekly chart
3. Adjusted shading and trend detection to be greater than 50 or less than 50 (not equal to) per original strategy (thx community)

Update - Version 1.7
A quick update to this indicator for those of you that may be using it. See below for changes in this version.

Added the following:

1. Added additional price targets (7, 8, 9) as an input option (ShowExtraTargets789) - can be turned on and off independent of targets 1-6 but dependent on trend
2. Added ADX triangle plot to stoploss in either direction. Indicates if ADX is greater than previous ADX[1] and denotes if ADR has crossed above ADXR for trend confirmation/strength
   1. ADX Uptrend - White = ADX > ADX[1], RED = ADX crossed above ADXR, CYAN = ADX > 35
   2. ADX DownTrend - Purple = ADX > ADX[1], GREEN = ADX crossed above ADXR, YELLOW = ADX > 35
   3. Added ability to show ADX triangles without plotting ADR Targets and Shading

After quite a bit of collaboration from several members - we wanted to provide a central reference point for this indicator. The original request for this write up came from @Joseph Patrick 18 to replicate a well known strategy known as Power X. For the purposes of this indicator, it is being referred to as RSM (RSI, Stochastic,MACD) Indicator.

I'd like to thank the following members for their contributions: @Joseph Patrick 18 , @SuryaKiranC, @RickAns, @TradeUp (and many others, sorry if I forgot you)

Basic requirements for this indicator:

1. Use RSI, Stochastic and MACD standard indicators (with minor settings tweak) to identify trends
2. RSI - Set to 7, EXPONENTIAL MOVING AVERAGE
3. Stochastic Slow- Set to 14 and 3, WILDERS AVERAGE
4. MACD - Set to 12,26,9 - WEIGHTED AVERAGE
5. Paint Candles accordintly - (GREEN/UP, RED/DOWN)

Trend Identification


Reference material for strategy: https://rockwell-files.s3.amazonaws.com/PXCompanionGuide2ndEd_cover.pdf

Indicators Available (See below for code). The following scripts are provided for this indicator:

1. RSM Upper - works on any TF and TICK Charts
   1. Color candles, Plots Arrows and displays informational labels
   2. Most settings can be turned off if desired
2. RSM Lower
   1. 3 Indicators in 1 - can be added to chart seperatly and choose indicator desired
   2. Can plot RSI, Stochastic, RSI & Stochastic, or MACD Only as lower study with shading and candle painting
3. RSM MTF
   1. Adds Labels for ALL TF's to show current status of RSM Signal
4. RSM SCAN - Use to scan for the following:
   1. Stocks currently in UpTrend
   2. Stocks just starting UpTrend
   3. Stocks currently in DownTrend
   4. Stocks just starting DownTrend

* - Quick personal note - thanks so much for letting me work on this project and for you patience. I had a chance to learn quite a bit and hopefully improve my trading in the process. Great community here!!!!!!!!!!!

Disclaimer
This indicator may or may not be suitable for you. Constructive criticism welcomed in order to improve. Please report any bugs so we can continue to improve it.

RSM Upper

Features

1. Paint Bars (Green, Red, Gray)
2. Shade chart area per trend
3. Select between trade type (Long,Short,Both)
4. Dynamic calculation of ADR/ATR at moment of trend start
5. Select between ADR/ATR for target and stop loss calculations
6. Plot ADR/ATR target lines while trend is active (on/off)
   1. Plot 3 targets up/down by default
7. Plot additional targets (4-6) if desired (on/off)
8. Shade the ADR/ATR zones (on/off)
9. Stop loss multiplier selection
10. Show Labels for first 3 targets
11. Show Labels for Trend info

#START OF RSI/Stochastic/MACD Confluence Strategy for ThinkOrSwim
#RSM_STANDARD_UPPER
#
#CHANGELOG
#
# 2021.05.11 V1.9 @cos251 - Added feature to plot only current ADR Targets and Stoploss
#                            - Feature credit goes to @SleepyZ (thx)
#
# 2021.05.04 V1.8 @cos251 - Fixed >= error to match original strategy as noted by community
#                            - Fixed UpTrend and DownTrend Arrows to display on weekly chart
#                            - Fixed StopLoss and UpTrend/DownTrend targets to display on weekly chart
#
# 2021.04.13 V1.7 @cos251 - Added additional price targets (7, 8, 9) as an input option (ShowExtraTargets789) -
#                            - can be turned on and off independent of targets 1-6 but dependent on trend
#                         - Added ADX triangle plot to stoploss in either direction.  Indicates if ADX #                            - is greater than previous ADX[1] and denotes if ADR has crossed
#                            - above ADXR for trend confirmation/strength
#                            - ADX Uptrend - White = ADX > ADX[1], RED = ADX crossed above ADXR, CYAN = ADX > 35
#                            - ADX DownTrend - Purple = ADX > ADX[1], GREEN = ADX crossed above ADXR, YELLOW = ADX > 35
#
# 2021.01.15 V1.6 @SuryaKirnaC
#                         - Modifed ADR Zones shading colors
#                         - Adjusted Indicator and target labels for space
#                         - Made audible alerts user configurable via settings
#
# 2021.01.04 V1.5 @cos251 - Fixed long, short ADR Zone plots to match TradeType selection (Long, Short, BOTH)
#                         - will only plot as selected
#
# 2020.12.21 V1.4 @cos251 - Added input "plotADR"
#                            - plots dynamic ATR/ADR targets- default plots 3 targets - can be turned off by setting #                              "plotADR" to no
#                         - Added input "showExtraTargets"
#                            -  - plots dynamic ATR/ADR targets- for targets 4, 5, and 6
#                         - Added input "showADRZones"
#                            - Dynamic shading of ATR/ADR targets - can be turned off in settings using "showADRZones"
#                         - Added dynamic calculation of both ATR and ADR. User can select between ATR and ADR in #                              settings
#                         - Added input "showADRLabels"
#                            - Added Dynamic Target labels for UpTrend or DownTrend; they will be green or red #                              depending on Up or Down trend
#                         - Added input "showTodayOnly"
#                            - Added option to display shaded ADR/ATR zones for today only "showTodayOnly"
#                            - if set to no - ADR/ATR plots will be plotted for all available data on chart
#                         - Added ability to plot ATR or ADR on DAY chart - MUST TURN OFF "showTodayOnly"
#                         - Added Labels that can be used for "debug" - MUST change "debug" setting to yes
#                         - Added Trend information labels that can be turned on/off
#                      
#
# 2020.11.30 V1.3 @cos251 - Stripped down TICK Version; No ADR since time based aggregation period do not work on TICK #                           Charts
#
# 2020.11.30 V1.2 @cos251 - Add ADR plots and shading per request; will tweak these settings to improve overall
#                           options
# 2020.11.12 V1.1 @cos251 - Changed from strategy to standard study. Added Green Arrow UP
#                           and Red Arrow down when trend starts.  Added option to change to high
#                           timeframe but this WILL repaint; if used, should be used with other
#                           indicators to confirm an entry/exit.
#
# 2020.10.27 V1.0 @cos251 - Added RSI, StochasticSlow and MACD to same indicator
#                         - also calculates MACD;
#                         - Will shade the lower plot area of the following conditions are met
#                           Shade GREEN = RSI > 50 and SlowK > 50 and (macd)Value > (macd)Avg
#                           Shade RED = RSI < 50 and SlowK < 50 and (macd)Value < (macd)Avg
#
#              
#REQUIREMENTS - RSI Set to 7, EXPONENTIAL
#               Stoch Slow 14 and 3 WILDERS
#               MACD 12,26,9 WEIGHTED


declare upper;
################################################################
##########                 Variables                   #########
################################################################

input paintBars = yes;
input showRSMShade = no;
input tradetype = { "long", "short", default "both" };
input rangeType = { default "ADR", "ATR" };
input stopLossMultiplier = 1.0;
input plotADR = yes;
input showADRZones = yes;
input showCurrentTargetsOnly = yes;
input showTodayOnly = yes;
input showTrendLabels = no;
input showADRLabels = no;
input showExtraTargets = no;
input showExtraTargets789 = no;
input showADXTriangle = yes;
input lengthADX = 21;
input showIndicatorLabels = no;
input audibleAlerts = yes;
input debug = no; # change to "NO" after testing



################################################################
##########              ATR/ADR Calc                   #########
################################################################
input ATRlength = 14;
input ATRaverageType = AverageType.WILDERS;
def Range;
if rangeType == rangeType.ATR {
    Range = MovingAverage(ATRaverageType, TrueRange(high, close, low), ATRlength);
} else {
    Range = Average(high - low, 7);
}

################################################################
##########         Booleans Set for Plot Use           #########
################################################################
def afterStart;
def beforeEnd;
def today;
def openPrice;
if GetAggregationPeriod() <= AggregationPeriod.DAY {
    afterStart = GetTime() > RegularTradingStart(GetYYYYMMDD());
    beforeEnd = GetTime() < RegularTradingEnd(GetYYYYMMDD());
    today = if GetLastDay() == GetDay() then 1 else Double.NaN;
    openPrice = DailyOpen();
} else {
    afterstart = Double.NaN;
    beforeEnd = Double.NaN;
    today = Double.NaN;
    openPrice = Double.NaN;
}

plot DailyO = if openPrice then openPrice else Double.NaN;
AddLabel(if debug then yes else no, "Day = :" + today);
AddLabel(if debug then yes else no, "Day = :" + GetDay());


################################################################
##########           ADX Indicator Reference           #########
################################################################
def ADX = reference ADX();
def ADXR = (ADX + ADX[lengthADX - 1]) / 2;

################################################################
##########                 RSI                         #########
################################################################
input lengthRSI = 7;
input price = close;
input averageTypeRSI = AverageType.EXPONENTIAL;
def NetChgAvg = MovingAverage(averageTypeRSI, close - close[1], lengthRSI);
def TotChgAvg = MovingAverage(averageTypeRSI, AbsValue(close - close[1]), lengthRSI);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
def RSI = 50 * (ChgRatio + 1);


################################################################
##########                 Stochastic Slow             #########
################################################################
input over_boughtSt = 80;
input over_soldSt = 20;
input KPeriod = 14;
input DPeriod = 3;
input averageTypeStoch = AverageType.WILDERS;
def SlowK = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, high, low, close, 3, averageTypeStoch).FullK;
def SlowD = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, high, low, close, 3, averageTypeStoch).FullD;



################################################################
##########                  MACD                       #########
################################################################
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageTypeMACD = AverageType.WEIGHTED;
def Value = MovingAverage(averageTypeMACD, close, fastLength) - MovingAverage(averageTypeMACD, close, slowLength);
def Avg = MovingAverage(averageTypeMACD, Value, MACDLength);
def Diff = Value - Avg;



################################################################
##########         Assign Price Color                  #########
################################################################
AssignPriceColor(if paintBars and RSI > 50 and SlowK > 50 and Value > Avg then Color.GREEN else if paintBars and RSI < 50 and SlowK < 50 and Value < Avg then Color.RED else if paintBars then Color.DARK_GRAY else Color.CURRENT);

#################################################################
#####   Up/Down Trend Check/SCAN Variables              #########
#################################################################
plot UpTrend = if RSI > 50 and SlowK > 50 and Value > Avg then 1 else 0;
plot DownTrend = if RSI < 50 and SlowK < 50 and Value < Avg then 1 else 0;
UpTrend.Hide();
DownTrend.Hide();
plot upArrow = if UpTrend == 1 and UpTrend[1] == 0 and (tradetype == tradetype.long or tradetype == tradetype.both) then low else Double.NaN;
upArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
upArrow.SetDefaultColor(Color.GREEN);
upArrow.SetLineWeight(4);
plot downArrow = if DownTrend == 1 and DownTrend[1] == 0 and (tradetype == tradetype.short or tradetype == tradetype.both) then high else Double.NaN;
downArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
downArrow.SetDefaultColor(Color.RED);
downArrow.SetLineWeight(4);

def bnumUp;
def bnumDown;
def closeUpTrendStart;
def closeDownTrendStart;
def UpTrendBarCount;
def DownTrendBarCount;
if UpTrend and (!UpTrend[1] or DownTrend[1]) {
    bnumUp = BarNumber();
    bnumDown = 0;
    closeUpTrendStart = close;
    closeDownTrendStart = 0;
    UpTrendBarCount = 1;
    DownTrendBarCount = 0;
} else if UpTrend {
    bnumUp = bnumUp[1];
    bnumDown = 0;
    closeUpTrendStart = closeUpTrendStart[1];
    closeDownTrendStart = 0;
    UpTrendBarCount = UpTrendBarCount[1] + 1;
    DownTrendBarCount = 0;
} else if DownTrend and (!DownTrend[1] or UpTrend[1]) {
    bnumUp = 0;
    bnumDown = BarNumber();
    closeDownTrendStart = close;
    closeUpTrendStart = 0;
    UpTrendBarCount = 0;
    DownTrendBarCount = 1;
} else if DownTrend {
    bnumDown = bnumDown[1];
    closeDownTrendStart = closeDownTrendStart[1];
    DownTrendBarCount = DownTrendBarCount[1] + 1;
    bnumUp = 0;
    closeUpTrendStart = 0;
    UpTrendBarCount = 0;
} else {
    bnumUp = 0;
    bnumDown = 0;
    closeUpTrendStart = 0;
    closeDownTrendStart = 0;
    UpTrendBarCount = 0;
    DownTrendBarCount = 0;
}
def c;
if BarNumber() == bnumUp or BarNumber() == bnumDown {
    c = Range;
} else if UpTrend or DownTrend {
    c = c[1];
} else {
    c = 0;
}
AddLabel(if debug then yes else no, "Current Bar:" + BarNumber());
AddLabel(if debug then yes else no, "C:" + c);
AddLabel( if debug then yes else no, "PlotADR: " + plotADR);
AddLabel( if debug then yes else no, "TodayOnly: " + showTodayOnly);


#################################################################
############        ADR/ATR Targets Shading              #########
#################################################################
def up = if UpTrend   then bnumUp   else Double.NaN;
def dn = if DownTrend then bnumDown else Double.NaN;
# - UpTrend Targets and StopLoss
plot UpTrendStopLoss = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly then closeUpTrendStart - (c * stopLossMultiplier) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeUpTrendStart - c else Double.NaN;
plot oneADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly then closeUpTrendStart + (c * 1) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeUpTrendStart + c else Double.NaN;
plot twoADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly then closeUpTrendStart + (c * 2) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeUpTrendStart + (c * 2) else Double.NaN;
plot threeADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly then closeUpTrendStart + (c * 3) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeUpTrendStart + (c * 3) else Double.NaN;
plot fourADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets then closeUpTrendStart + (c * 4) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets then closeUpTrendStart + (c * 4) else Double.NaN;
plot fiveADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets then closeUpTrendStart + (c * 5) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets then closeUpTrendStart + (c * 5) else Double.NaN;
plot sixADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets then closeUpTrendStart + (c * 6) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets then closeUpTrendStart + (c * 6) else Double.NaN;
plot sevenADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 7) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 7) else Double.NaN;
plot eightADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 8) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 8) else Double.NaN;
plot nineADRPlus = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 9) else if (tradetype == tradetype.both or tradetype == tradetype.long) and UpTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd and showExtraTargets and showExtraTargets789 then closeUpTrendStart + (c * 9) else Double.NaN;

# - DownTrend Targets and StopLoss
plot DownTrendStopLoss = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly then closeDownTrendStart + (c * stopLossMultiplier) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeDownTrendStart + c else Double.NaN;
plot oneADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly then closeDownTrendStart - c else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeDownTrendStart - c else Double.NaN;
plot twoADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly then closeDownTrendStart - (c * 2) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeDownTrendStart - (c * 2) else Double.NaN;
plot threeADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly then closeDownTrendStart - (c * 3) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd then closeDownTrendStart - (c * 3) else Double.NaN;
plot fourADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets then closeDownTrendStart - (c * 4) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets then closeDownTrendStart - (c * 4) else Double.NaN;
plot fiveADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets then closeDownTrendStart - (c * 5) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets then closeDownTrendStart - (c * 5) else Double.NaN;
plot sixADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets then closeDownTrendStart - (c * 6) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets then closeDownTrendStart - (c * 6) else Double.NaN;
plot sevenADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 7) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 7) else Double.NaN;
plot eightADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 8) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 8) else Double.NaN;
plot nineADRMinus = if showCurrentTargetsOnly == yes and (bnumDown < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and !showTodayOnly and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 9) else if (tradetype == tradetype.both or tradetype == tradetype.short) and DownTrend and plotADR and showTodayOnly  and today and afterStart and beforeEnd  and showExtraTargets and showExtraTargets789 then closeDownTrendStart - (c * 9) else Double.NaN;

UpTrendStopLoss.SetDefaultColor(Color.LIGHT_RED);
oneADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
twoADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
threeADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
fourADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
fiveADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
sixADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
sevenADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
eightADRPlus.SetDefaultColor(Color.LIGHT_GREEN);
nineADRPlus.SetDefaultColor(Color.LIGHT_GREEN);

DownTrendStopLoss.SetDefaultColor(Color.LIGHT_GREEN);
oneADRMinus.SetDefaultColor(Color.LIGHT_RED);
twoADRMinus.SetDefaultColor(Color.LIGHT_RED);
threeADRMinus.SetDefaultColor(Color.LIGHT_RED);
fourADRMinus.SetDefaultColor(Color.LIGHT_RED);
fiveADRMinus.SetDefaultColor(Color.LIGHT_RED);
sixADRMinus.SetDefaultColor(Color.LIGHT_RED);
sevenADRMinus.SetDefaultColor(Color.LIGHT_RED);
eightADRMinus.SetDefaultColor(Color.LIGHT_RED);
nineADRMinus.SetDefaultColor(Color.LIGHT_RED);


########### ADX Triangle Plot ###################################
plot ADXTriangleUp = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if showADXTriangle and UpTrend and ADX > ADX[1] and !showTodayOnly then closeUpTrendStart - (c * stopLossMultiplier) else if showADXTriangle and UpTrend and ADX > ADX[1] and showTodayOnly and today then closeUpTrendStart - (c * stopLossMultiplier)  else Double.NaN;
ADXTriangleUp.SetPaintingStrategy(PaintingStrategy.TRIANGLES);
ADXTriangleUp.SetDefaultColor(Color.WHITE);
ADXTriangleUp.AssignValueColor(if ADX > ADXR and ADX[1] < ADXR[1] then Color.RED else if ADX > 35 then Color.CYAN else Color.CURRENT);
ADXTriangleUp.SetLineWeight(1);
plot ADXBubbleDown = if showCurrentTargetsOnly == yes and (bnumUp < Max(HighestAll(dn), HighestAll(up)))
                         then Double.NaN
                         else if showADXTriangle and DownTrend and ADX > ADX[1] and !showTodayOnly then closeDownTrendStart + (c * stopLossMultiplier) else if showADXTriangle and DownTrend and ADX > ADX[1] and showTodayOnly and today then closeDownTrendStart + (c * stopLossMultiplier) else Double.NaN;
ADXBubbleDown.SetPaintingStrategy(PaintingStrategy.TRIANGLES);
ADXBubbleDown.SetDefaultColor(Color.MAGENTA);
ADXBubbleDown.AssignValueColor(if ADX > ADXR and ADX[1] < ADXR[1] then Color.GREEN else if ADX > 35 then Color.YELLOW else Color.CURRENT);
ADXBubbleDown.SetLineWeight(1);


#################################################################
############          ADR/ATR Zone Shading              #########
#################################################################
def u = if UpTrend then closeUpTrendStart else Double.NaN;
def d = if DownTrend then closeDownTrendStart else Double.NaN;
def bnumUpCheck = if bnumUp != 0 then 1 else Double.NaN;
def bnumDownCheck = if bnumDown != 0 then 1 else Double.NaN;

AddCloud(if showADRZones and UpTrend and bnumUpCheck and showExtraTargets and showExtraTargets789 then nineADRPlus else if showADRZones and UpTrend and bnumUpCheck and showExtraTargets then sixADRPlus else if showADRZones and UpTrend and bnumUpCheck then threeADRPlus else Double.NaN, if showADRZones and UpTrend and bnumUpCheck then u else Double.NaN , CreateColor(213, 252, 213));
AddCloud(if showADRZones and UpTrend then u else Double.NaN, if showADRZones and UpTrend then UpTrendStopLoss else Double.NaN , CreateColor(255, 174, 174));

# - Shade Downtrend ADR/ATR zones
AddCloud( if showADRZones and DownTrend and bnumDownCheck then d else Double.NaN ,if showADRZones and DownTrend and bnumDownCheck and showExtraTargets and showExtraTargets789 then nineADRminus else if showADRZones and DownTrend and bnumDownCheck and showExtraTargets then sixADRMinus else if showADRZones and DownTrend and bnumDownCheck then threeADRMinus else Double.NaN, CreateColor(213, 252, 213));

AddCloud(if showADRZones and DownTrend then DownTrendStopLoss else Double.NaN, if showADRZones and DownTrend then d else Double.NaN, CreateColor(255, 174, 174));


#################################################################
####    RSM shade areas based on criteria; adjust as needed  ####
#################################################################
AddCloud(if showRSMShade and RSI > 50 and SlowK >= 50 and Value > Avg then Double.POSITIVE_INFINITY else Double.NaN, if RSI > 50 and SlowK > 50 and Value > Avg then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN);
AddCloud(if showRSMShade and RSI < 50 and SlowK < 50 and Value < Avg then Double.POSITIVE_INFINITY else Double.NaN, if RSI < 50 and SlowK < 50 and Value < Avg then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);


#################################################################
############   Labels disable/blockout as needed        #########
#################################################################
# - Trend Labels
AddLabel(showTrendLabels and (bnumDown != 0 or bnumUp != 0), "Trend BAR#: " + (if bnumUp > 0 then bnumUp else + bnumDown), if bnumUp > 0 then Color.GREEN else Color.RED);
AddLabel(showTrendLabels and (bnumDown != 0 or bnumUp != 0), "Trend @ $:" + (if bnumUp > 0 then closeUpTrendStart else  + closeDownTrendStart), if bnumUp > 0 then Color.GREEN else Color.RED);
AddLabel(showTrendLabels, "Tot Bars:" + (if bnumUp > 0 then UpTrendBarCount else DownTrendBarCount), if bnumUp > 0 then Color.GREEN else Color.RED);
AddLabel(showTrendLabels, "RSM:" + (if UpTrend == 1 then "L" else if DownTrend == 1 then "S" else "I"), if UpTrend == 1 then Color.GREEN else if DownTrend == 1 then Color.RED else Color.GRAY);

# - ADR/ATR Labels Targets
AddLabel(openPrice and showADRLabels, "Open:" + dailyO, Color.ORANGE);

AddLabel(showADRLabels and (UpTrend or DownTrend), "Target #1: " + (if UpTrend then Round(oneADRPlus, 2) else if DownTrend then Round(oneADRMinus, 2) else Double.NaN) + " ", if UpTrend then Color.GREEN else if DownTrend then Color.RED else Color.GRAY);
AddLabel(showADRLabels and (UpTrend or DownTrend), "Target #2: " + (if UpTrend then Round(twoADRPlus, 2) else if DownTrend then Round(twoADRMinus, 2) else Double.NaN) + " ", if UpTrend then Color.GREEN else if DownTrend then Color.RED else Color.GRAY);
AddLabel(showADRLabels and (UpTrend or DownTrend), "Target #3: " + (if UpTrend then Round(threeADRPlus, 2) else if DownTrend then Round(threeADRMinus, 2) else Double.NaN) + " ", if UpTrend then Color.GREEN else if DownTrend then Color.RED else Color.GRAY);

# - Indicator Label
AddLabel(if showIndicatorLabels then yes else no, "RSI:" + Round (RSI, 2) + " | sK:" + Round(SlowK, 2) + " | Macd:" + Round(Value, 4) + "  ", Color.ORANGE);




#### ALERTS Sound
Alert(audibleAlerts and upArrow, "RSM UpTrend Started", Alert.BAR, Sound.Ding);
Alert(audibleAlerts and downArrow, "RSM DownTrend Started", Alert.BAR, Sound.Ding);

RSM Lower

Update - Version 1.5 (Lower)

1. Added Stochastic Divergence Indicator (in addition to RSI)
2. Added labels for selected plot
3. Added RSI Drivergence indicator
   1. Credit to @BenTen - https://usethinkscript.com/threads/rsi-divergence-indicator-with-scanner-for-thinkorswim.136/
   2. Identifies Divergence for RSI only
   3. Plotted by ORANGE Dots and Orange Dashed Line
   4. Requested by - @bigshow3

Features

1. 3 Indicators in 1
   1. RSI - Only
   2. Stochastic - Only
   3. RSI & Stochastic
   4. MACD - Only
2. Will shade lower area when trend is confirmed for each indicator individually
3. All settings for each indicator made avaiable in settings for user configuration
4. Paint Bars if not used with upper study - user configurable

#RSM_Lower_v1.5
#
#CHANGELOG
#
# 2021.07.06 V1.5 @SuryaKiranC - Updated code to use existing variables; added Stochastic Slow Divergence (in addition
#                           to RSI Divergence - added Labeles to show which plot is enabled; can be turned off
#
# 2021.07.06 V1.4 @cos251 - Added RSI Divergence indicator from "RSI Dirvergence Indicator" from BenTen code
#                           Please note that the overbought and oversold used for divergence is 70/30 and can be adjusted in
#                           settings
#
# 2021.01.11 V1.3 @cos251 - Addjusted lower shading to shade trends when individual indicator crosses respective midline
#                           Shading will match if stochPlots is set to "Both" (RSI & Stochastci)
#
# 2020.11.30 V1.2 @cos251 - Added quick option to select plot(s) (RSI, Stochastic, Both or MACDOnly), set SlowD to enabled,
#                           user can uncheck SlowD plot if desired; adjusted coloring and shading to work with
#                           any plot selected; Combined plots for ease of use.
#
# 2020.10.30 V1.1 @cos251 - Added UpTrend and DownTrend variables that can be used for a SCAN (HAS BEEN REMOVED)
# 2020.10.27 V1.0 @cos251 - Added RSI, StochasticSlow and MACD to same indicator; this
#                           will plot only RSI and Stochastic but also
#                         - calculates MACD; Will shade the lower plot area of the following conditions are met
#                           Shade GREEN = RSI > 50 and SlowK > 50 and (macd)Value > (macd)Avg
#                           Shade RED = RSI < 50 and SlowK < 50 and (macd)Value < (macd)Avg
#                 
#REQUIREMENTS - RSI Set to 7, EXPONENTIAL
#               Stoch Slow 14 and 3 WILDERS
#               MACD 12,26,9 WEIGHTED
#
#
#CREDITS
# requesed by "@Joseph Patrick 18"
#
#LINK
# https://rockwell-files.s3.amazonaws.com/PXCompanionGuide2ndEd_cover.pdf
# Markus Heikoetter who is the author of the Power X Strategy
# https://usethinkscript.com/threads/mimicking-power-x-strategy-by-markus-heitkoetter.4283/
#
#USAGE
#



declare lower;

input paintBars = yes;
input selectPlots = { default "RSI", "Stochastic", "Both", "MACDOnly" };

################################################################
##########                 RSI                         #########
################################################################

input lengthRSI = 7;
input over_BoughtRSI = 80;
input over_SoldRSI = 20;
input price = close;
input averageTypeRSI = AverageType.EXPONENTIAL;
input showBreakoutSignalsRSI = no;
input showRSI_obos = no;


def NetChgAvg = MovingAverage(averageTypeRSI, price - price[1], lengthRSI);
def TotChgAvg = MovingAverage(averageTypeRSI, AbsValue(price - price[1]), lengthRSI);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
def calcRSI = 50 * (ChgRatio + 1);

plot RSI = if selectPlots == selectPlots.RSI or selectPlots == selectPlots.Both then calcRSI else Double.NaN;
plot OverSold_RSI = if (selectPlots == selectPlots.RSI or selectPlots == selectPlots.Both) and showRSI_obos then over_SoldRSI else Double.NaN;
plot OverBought_RSI = if (selectPlots == selectPlots.RSI or selectPlots == selectPlots.Both) and showRSI_obos then over_BoughtRSI else Double.NaN;
plot UpSignalRSI = if RSI crosses above OverSold_RSI then OverSold_RSI else Double.NaN;
plot DownSignalRSI = if RSI crosses below OverBought_RSI then OverBought_RSI else Double.NaN;
UpSignalRSI.SetHiding(!showBreakoutSignalsRSI);
DownSignalRSI.SetHiding(!showBreakoutSignalsRSI);
RSI.DefineColor("OverBought", GetColor(5));
RSI.DefineColor("Normal", Color.YELLOW);
RSI.DefineColor("OverSold", GetColor(1));
#RSI.AssignValueColor(if RSI > rsiover_Bought then RSI.Color("OverBought") else if RSI < rsiover_Sold then RSI.Color("OverSold") else RSI.Color("Normal"));
OverSold_RSI.SetDefaultColor(GetColor(8));
OverBought_RSI.SetDefaultColor(GetColor(8));
UpSignalRSI.SetDefaultColor(Color.UPTICK);
UpSignalRSI.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignalRSI.SetDefaultColor(Color.DOWNTICK);
DownSignalRSI.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

def BN = barNumber();
def RSI_H = if RSI > over_BoughtRSI then fold Ri = 1 to Floor(lengthRSI / 2) with Rp = 1 while Rp do RSI > GetValue(RSI, -Ri) else 0;
def RSI_PivotH = if (BN > lengthRSI and RSI == Highest(RSI, Floor(lengthRSI / 2)) and RSI_H) then RSI else Double.NaN;
def RSI_L = if RSI < over_SoldRSI then fold Rj = 1 to Floor(lengthRSI / 2) with Rq = 1 while Rq do RSI < GetValue(RSI, -Rj) else 0;
def RSI_PivotL = if (BN > lengthRSI and RSI == Lowest(RSI, Floor(lengthRSI / 2)) and RSI_L) then RSI else Double.NaN;
def RSI_PHBar = if !IsNaN(RSI_PivotH) then BN else RSI_PHBar[1];
def RSI_PLBar = if !IsNaN(RSI_PivotL) then BN else RSI_PLBar[1];
def RSI_PHPoint = if !IsNaN(RSI_PivotH) then RSI_PivotH else RSI_PHPoint[1];
def RSI_LastPHBar = if RSI_PHPoint != RSI_PHPoint[1] then RSI_PHBar[1] else RSI_LastPHBar[1];
def RSI_PLPoint = if !IsNaN(RSI_PivotL) then RSI_PivotL else RSI_PLPoint[1];
def RSI_LastPLBar = if RSI_PLPoint != RSI_PLPoint[1] then RSI_PLBar[1] else RSI_LastPLBar[1];

def RSI_HighPivots = BN >= HighestAll(RSI_LastPHBar);
def RSI_LowPivots = BN >= HighestAll(RSI_LastPLBar);
def RSI_pivotHigh = if RSI_HighPivots then RSI_PivotH else Double.NaN;

plot RSI_plotHline = if selectPlots == selectPlots.RSI then RSI_pivotHigh else Double.NaN;
RSI_plotHline.EnableApproximation();
RSI_plotHline.SetDefaultColor(Color.LIME);
RSI_plotHline.SetStyle(Curve.SHORT_DASH);

plot RSI_pivotLow = if selectPlots == selectPlots.RSI and RSI_LowPivots then RSI_PivotL else Double.NaN;
RSI_pivotLow.EnableApproximation();
RSI_pivotLow.SetDefaultColor(Color.LIME);
RSI_pivotLow.SetStyle(Curve.SHORT_DASH);

plot RSI_pivotDot = if !IsNaN(selectPlots == selectPlots.RSI and RSI_pivotHigh) then RSI_pivotHigh else if !IsNaN(RSI_pivotLow) then RSI_pivotLow else Double.NaN;
RSI_pivotDot.SetDefaultColor(Color.LIME);
RSI_pivotDot.SetPaintingStrategy(PaintingStrategy.POINTS);
RSI_pivotDot.SetLineWeight(3);


################################################################
##########                 Stochastic Slow             #########
################################################################
input over_boughtSt = 80;
input over_soldSt = 20;
input KPeriod = 14;
input DPeriod = 3;
input priceH = high;
input priceL = low;
input priceC = close;
input averageTypeStoch = AverageType.WILDERS;
input showBreakoutSignalsStoch = {default "No", "On SlowK", "On SlowD", "On SlowK & SlowD"};
input showStochastic_ob_os = no;

def calcSlowK = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullK;
def calcSlowD = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullD;
plot SlowK = if selectPlots == selectPlots.Stochastic or selectPlots == selectPlots.Both then calcSlowK else Double.NaN;
plot SlowD = if selectPlots == selectPlots.Stochastic or selectPlots == selectPlots.Both then calcSlowD else Double.NaN;
plot OverBoughtSt = if (selectPlots == selectPlots.Stochastic or selectPlots == selectPlots.Both) and showStochastic_ob_os then over_boughtSt else Double.NaN;
plot OverSoldSt = if (selectPlots == selectPlots.Stochastic or selectPlots == selectPlots.Both) and showStochastic_ob_os then over_soldSt else Double.NaN;

def upK = SlowK crosses above OverSoldSt;
def upD = SlowD crosses above OverSoldSt;
def downK = SlowK crosses below OverBoughtSt;
def downD = SlowD crosses below OverBoughtSt;

plot UpSignalSt;
plot DownSignalSt;
switch (showBreakoutSignalsStoch) {
case "No":
    UpSignalSt = Double.NaN;
    DownSignalSt = Double.NaN;
case "On SlowK":
    UpSignalSt = if upK then OverSoldSt else Double.NaN;
    DownSignalSt = if downK then OverBoughtSt else Double.NaN;
case "On SlowD":
    UpSignalSt = if upD then OverSoldSt else Double.NaN;
    DownSignalSt = if downD then OverBoughtSt else Double.NaN;
case "On SlowK & SlowD":
    UpSignalSt = if upK or upD then OverSoldSt else Double.NaN;
    DownSignalSt = if downK or downD then OverBoughtSt else Double.NaN;
}
UpSignalSt.SetHiding(showBreakoutSignalsStoch == showBreakoutSignalsStoch."No");
DownSignalSt.SetHiding(showBreakoutSignalsStoch == showBreakoutSignalsStoch."No");
SlowK.SetDefaultColor(Color.WHITE);
SlowD.SetDefaultColor(Color.DARK_ORANGE);
OverBoughtSt.SetDefaultColor(GetColor(1));
OverSoldSt.SetDefaultColor(GetColor(1));
UpSignalSt.SetDefaultColor(Color.UPTICK);
UpSignalSt.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignalSt.SetDefaultColor(Color.DOWNTICK);
DownSignalSt.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);

def SlowK_H = if SlowK > over_boughtSt then fold Si = 1 to Floor(KPeriod / 2) with Sp = 1 while Sp do SlowK > getValue(SlowK, -Si) else 0;
def SlowK_PivotH = if (BN > KPeriod and SlowK == highest(SlowK, Floor(KPeriod/2)) and SlowK_H) then SlowK else double.NaN;
def SlowK_L = if SlowK < over_soldSt then fold Sj = 1 to Floor(KPeriod / 2) with Sq = 1 while Sq do SlowK < getValue(SlowK, -Sj) else 0;
def SlowK_PivotL = if (BN > KPeriod and SlowK == lowest(SlowK, Floor(KPeriod/2)) and SlowK_L) then SlowK else double.NaN;
def SlowK_PHBar = if !isNaN(SlowK_PivotH) then BN else SlowK_PHBar[1];
def SlowK_PLBar = if !isNaN(SlowK_PivotL) then BN else SlowK_PLBar[1];
def SlowK_PHPoint = if !isNaN(SlowK_PivotH) then SlowK_PivotH else SlowK_PHPoint[1];
def SlowK_LastPHBar = if SlowK_PHPoint != SlowK_PHPoint[1] then SlowK_PHBar[1] else SlowK_LastPHBar[1];
def SlowK_PLPoint = if !isNaN(SlowK_PivotL) then SlowK_PivotL else SlowK_PLPoint[1];
def SlowK_LastPLBar = if SlowK_PLPoint != SlowK_PLPoint[1] then SlowK_PLBar[1] else SlowK_LastPLBar[1];

def SlowK_HighPivots = BN >= highestAll(SlowK_LastPHBar);
def SlowK_LowPivots = BN >= highestAll(SlowK_LastPLBar);
def SlowK_PivotHigh = if SlowK_HighPivots then SlowK_PivotH else double.NaN;

plot SlowK_plotHline = SlowK_PivotHigh;
     SlowK_plotHline.enableApproximation();
     SlowK_plotHline.SetDefaultColor(Color.LIME);
     SlowK_plotHline.SetStyle(Curve.Short_DASH);

plot SlowK_pivotLow = if SlowK_LowPivots then SlowK_PivotL else double.NaN;
     SlowK_pivotLow.enableApproximation();
     SlowK_pivotLow.SetDefaultColor(Color.LIME);
     SlowK_pivotLow.SetStyle(Curve.Short_DASH);

plot SlowK_pivotDot = if !isNaN(SlowK_pivotHigh) then SlowK_pivotHigh else if !isNaN(SlowK_pivotLow) then SlowK_pivotLow else double.NaN;
     SlowK_pivotDot.SetDefaultColor(Color.LIME);
     SlowK_pivotDot.SetPaintingStrategy(PaintingStrategy.POINTS);
     SlowK_pivotDot.SetLineWeight(3);


################################################################
##########                 MACD                        #########
################################################################
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageTypeMACD = AverageType.WEIGHTED;
input showBreakoutSignalsMACD = no;
def calcValue = MovingAverage(averageTypeMACD, close, fastLength) - MovingAverage(averageTypeMACD, close, slowLength);
def calcAvg = MovingAverage(averageTypeMACD, calcValue, MACDLength);
def calcDiff = calcValue - calcAvg;
plot ZeroLine = if selectPlots == selectPlots.MACDOnly then 0 else Double.NaN;
plot Value = if selectPlots == selectPlots.MACDOnly then calcValue else Double.NaN;
plot Avg = if selectPlots == selectPlots.MACDOnly then calcAvg else Double.NaN;
plot Diff = if selectPlots == selectPlots.MACDOnly then calcDiff else Double.NaN;
plot UpSignalMACD = if calcDiff crosses above 0 then 0 else Double.NaN;
plot DownSignalMACD = if calcDiff crosses below 0 then 0 else Double.NaN;

UpSignalMACD.SetHiding(!showBreakoutSignalsMACD);
DownSignalMACD.SetHiding(!showBreakoutSignalsMACD);

Value.SetDefaultColor(Color.GREEN);
Avg.SetDefaultColor(Color.RED);
Diff.SetDefaultColor(GetColor(5));
Diff.SetPaintingStrategy(PaintingStrategy.HISTOGRAM);
Diff.SetLineWeight(4);
Diff.DefineColor("Positive and Up", Color.CYAN);
Diff.DefineColor("Positive and Down", Color.BLUE);
Diff.DefineColor("Negative and Down", Color.RED);
Diff.DefineColor("Negative and Up", Color.YELLOW);
Diff.AssignValueColor(if Diff >= 0 then if Diff > Diff[1] then Diff.Color("Positive and Up") else Diff.Color("Positive and Down") else if Diff < Diff[1] then Diff.Color("Negative and Down") else Diff.Color("Negative and Up"));
ZeroLine.SetDefaultColor(GetColor(0));
UpSignalMACD.SetDefaultColor(Color.UPTICK);
UpSignalMACD.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
DownSignalMACD.SetDefaultColor(Color.DOWNTICK);
DownSignalMACD.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);


# Check Each Signal for over 50 and MACD for Value > Avg
def rsiGreen = if calcRSI > 50 then 1 else Double.NaN;
def rsiRed = if calcRSI < 50 then 1 else Double.NaN;
def stochGreen = if calcSlowK >= 50 then 1 else Double.NaN;
def stochRed = if calcSlowK < 50 then 1 else Double.NaN;
def macdGreen = if calcValue > calcAvg then 1 else Double.NaN;
def macdRed = if calcValue < calcAvg then 1 else Double.NaN;
def green = if rsiGreen and stochGreen and macdGreen then 1 else Double.NaN;
def red = if rsiRed and stochRed and macdRed then 1 else Double.NaN;


#RSI Color Assignment per requeset
RSI.AssignValueColor(if calcRSI > 50 and calcSlowK > 50 and calcValue > calcAvg then Color.GREEN else if calcRSI < 50 and calcSlowK < 50 and calcValue < calcAvg then Color.RED else Color.DARK_GRAY);

#AssignPriceColor
AssignPriceColor(if paintBars and calcRSI > 50 and calcSlowK > 50 and calcValue > calcAvg then Color.GREEN else if paintBars and calcRSI < 50 and calcSlowK < 50 and calcValue < calcAvg then Color.RED else if paintBars then Color.DARK_GRAY else Color.CURRENT);

#################################################################
############  Shade areas based on criteria; adjust as needed  ##
#################################################################
AddCloud(if rsiGreen and stochGreen and selectPlots == selectPlots.Both then Double.POSITIVE_INFINITY else Double.NaN, if rsiGreen and stochGreen and selectPlots == selectPlots.Both then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN);


AddCloud(if rsiRed and stochRed and selectPlots == selectPlots.Both then Double.POSITIVE_INFINITY else Double.NaN, if rsiRed and stochRed and selectPlots == selectPlots.Both then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);

AddCloud(if rsiGreen and selectPlots == selectPlots.RSI then Double.POSITIVE_INFINITY else Double.NaN, if rsiGreen and selectPlots == selectPlots.RSI then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN);
AddCloud(if rsiRed and selectPlots == selectPlots.RSI then Double.POSITIVE_INFINITY else Double.NaN, if rsiRed and selectPlots == selectPlots.RSI then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);

AddCloud(if stochGreen and selectPlots == selectPlots.Stochastic then Double.POSITIVE_INFINITY else Double.NaN, if stochGreen and selectPlots == selectPlots.Stochastic then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN);
AddCloud(if stochRed and selectPlots == selectPlots.Stochastic then Double.POSITIVE_INFINITY else Double.NaN, if stochRed and selectPlots == selectPlots.Stochastic then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);

AddCloud(if macdGreen and selectPlots == selectPlots.MACDOnly then Double.POSITIVE_INFINITY else Double.NaN, if macdGreen and selectPlots == selectPlots.MACDOnly then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_GREEN);
AddCloud(if macdRed and selectPlots == selectPlots.MACDOnly then Double.POSITIVE_INFINITY else Double.NaN, if macdRed and selectPlots == selectPlots.MACDOnly then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);


plot fifty = if selectPlots == selectPlots.RSI or selectPlots == selectPlots.Stochastic or selectPlots == selectPlots.Both then 50 else Double.NaN;
fifty.SetDefaultColor(Color.RED);



input showLabels = yes;
AddLabel(if showLabels then yes else no,if selectPlots == selectPlots.RSI then "RSM: RSI PLOT" else if selectPlots == selectPlots.Stochastic then "RSM: Stochastic Plot" else if selectPlots == selectPlots.Both then "RSM: RSI & Stochastic Plot" else "RSM: MACD PLOT", Color.ORANGE);

RSM MTF (Labels)

Features

1. Provides chart labels (upper left corner of price chart) with current status of MTF RSM Trend for the following TF's
   1. 1m, 2m, 3m, 4m, 5m, 10m, 15m, 20m, 30m, 1h, 2h, 4h, 1d, 2d, 3d, 4d, 1wk, 1mnth
   2. Add indicator for each time frame you would like shown

#START OF RSI/Stochastic/MACD Confluence Strategy for ThinkOrSwim
# RSM_MTF_Labels
#
#CHANGELOG
# 2020.12.30 V2.1 @SuryaKiranC - Fork from @cos251 Version, to reduce the number of lines in code and optimize for performance.
#
# 2020.12.11 V1.1 @cos251 - Added 2D, 3D, 4D, 1WK, 1MNTH Agg Period Labels
#
# 2020.12.02 V1.0 @cos251 - Added RSM signal calculation for following timeframes:
#                         - 1m, 2m, 5m, 15m, 30m, 1h, 2h, 4h, D
#                         - Label will be added to top of chart for every allowed TF
#                         - Label will read "TF:L(Long):S(Short):I(Idle)"
#                         - Label Color will be green, red or gray accordingly
#
#
#REQUIREMENTS - RSI Set to 7, EXPONENTIAL
#               Stoch Slow 14 and 3 WILDERS
#               MACD 12,26,9 WEIGHTED
#
#ORIGINAL REQUEST - @Joseph Patrick 18
#                 - Link: https://usethinkscript.com/threads/mimicking-power-x-strategy-by-markus-heitkoetter.4283/
#
#

input period = AggregationPeriod.DAY;

DefineGlobalColor("UpTrend", Color.Green);
DefineGlobalColor("DownTrend", Color.RED);
DefineGlobalColor("NoTrend", Color.GRAY);

script RSM_ {

    input aP = AggregationPeriod.DAY;
    # RSI
    def lengthRSI = 7;
    def averageTypeRSI = AverageType.EXPONENTIAL;
    # Stochastic
    def over_boughtSt = 80;
    def over_soldSt = 20;
    def KPeriod = 14;
    def DPeriod = 3;
    input averageTypeStoch = AverageType.WILDERS;
    # MACD
    def fastLength = 12;
    def slowLength = 26;
    def MACDLength = 9;
    def averageTypeMACD = AverageType.WEIGHTED;

    ###############################################################
    ##########                 RSI                         #########
    ################################################################

    def NetChgAvg = MovingAverage(averageTypeRSI, close(period = aP) - close(period = aP)[1], lengthRSI);
    def TotChgAvg = MovingAverage(averageTypeRSI, AbsValue(close(period = aP) - close(period = aP)[1]), lengthRSI);
    def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
    def RSI_ = 50 * (ChgRatio + 1);

    ################################################################
    ##########                 Stochastic Slow             #########
    ################################################################

    def SlowK_ = reference StochasticFull(over_boughtSt,  over_soldSt,  KPeriod,  DPeriod,  high(period = aP),  low(period = aP),  close(period = aP),  3, if (averageTypeStoch == 1) then AverageType.SIMPLE else AverageType.EXPONENTIAL).FullK;
    def SlowD_ = reference StochasticFull(over_boughtSt,  over_soldSt,  KPeriod,  DPeriod,  high(period = aP),  low(period = aP),  close(period = aP),  3, if (averageTypeStoch == 1) then AverageType.SIMPLE else AverageType.EXPONENTIAL).FullD;

    ################################################################
    ##########                 MACD                      ###########
    ################################################################

    def Value_ = MovingAverage(averageTypeMACD, close(period = aP), fastLength) - MovingAverage(averageTypeMACD, close(period = aP), slowLength);
    def Avg_ = MovingAverage(averageTypeMACD, Value_, MACDLength);
    def Diff_ = Value_ - Avg_;

    #################################################################
    ##########          Trend  & Labels                   #########
    #################################################################
    def UpTrend_ = if RSI_ >= 50 and SlowK_ >= 50 and Value_ > Avg_ then 1 else 0;
    def DownTrend_ = if RSI_ < 50 and SlowK_ < 50 and Value_ < Avg_ then 1 else 0;
    plot Trend_ = if UpTrend_ then 1 else if DownTrend_ then 0 else -1;

}

def currentPeriod = GetAggregationPeriod();
def RSM;

if period >= currentPeriod {
    RSM = RSM_(aP = period);

} else {
    RSM = Double.NaN;

}

AddLabel(!IsNaN(RSM), if period == AggregationPeriod.MONTH then "M"
else if period == AggregationPeriod.WEEK then "W"
else if period == AggregationPeriod.FOUR_DAYS then "4D"
else if period == AggregationPeriod.THREE_DAYS then "3D"
else if period == AggregationPeriod.TWO_DAYS then "2D"
else if period == AggregationPeriod.DAY then "D"
else if period == AggregationPeriod.FOUR_HOURS then "4H"
else if period == AggregationPeriod.TWO_HOURS then "2H"
else if period == AggregationPeriod.HOUR then "60m"
else if period == AggregationPeriod.THIRTY_MIN then "30m"
else if period == AggregationPeriod.TWENTY_MIN then "20m"
else if period == AggregationPeriod.FIFTEEN_MIN then "15m"
else if period == AggregationPeriod.TEN_MIN then "10m"
else if period == AggregationPeriod.FIVE_MIN then "5m"
else if period == AggregationPeriod.FOUR_MIN then "4m"
else if period == AggregationPeriod.THREE_MIN then "3m"
else if period == AggregationPeriod.TWO_MIN then "2m"
else if period == AggregationPeriod.MIN then "1m"
else "", if RSM == 1 then GlobalColor("UpTrend") else if RSM == 0 then GlobalColor("DownTrend") else GlobalColor("NoTrend"));

RSM SCAN

• Scanner Setup Instructions:
  1. Click Create (Create New Study)
  2. Remove the default plot statement and past the code block from RSM_SCAN.
  3. Save the study with name "RSM_SCAN", make sure it is not loaded in your studies on the right, if it is loaded by default when you saved it, please remove we don't need this on chart study.
  4. Go to Scan, Remove all the filters and add a new filter, select "Study" as a filter, Default study selected will be "ADXCrossOver", Click on Pencil Icon next to Default TimeFrame "D" and click "ThinkScript Editor".
  5. Here you can past one of the scan query RSM_SCAN().UpTrendJustStarted or RSM_SCAN().DownTrendJustStarted.
  6. You can even limit the scan results, select a default narrowed down list as "S&P 500" under "Scan In, on the scan tab itself.
  7. Finally you can save the scan query with a name.
  8. Repeat Step 4 to 7, for other scan queries.
• The following scan queries are available
  1. RSM_Scan().UpTrend (UpTrend in Progress, in the selected timeframe for Scan)
  2. RSM_Scan().UpTrendJustStarted (Uptrend Just started, in the selected timeframe for Scan)
  3. RSM_Scan().DownTrend (DownTrend in Progress, in the selected timeframe for Scan)
  4. RSM_Scan().DownTrendJustStarted (DownTrend Just started, in the selected timeframe for Scan)
  5. RSM_Scan().UpTrendJustEnded (UpTrend finished, in the selected timeframe for Scan)
  6. RSM_Scan().DownTrendJustEnded (DownTrend finished, in the selected timeframe for Scan)
• As always, please match the chart timeframe to your Scanner Settings for review.

#START OF RSI/Stochastic/MACD Confluence combo for ThinkOrSwim
#
# RSM_SCAN
#
#CHANGELOG
# 2020.12.05 - V1.0 @cos251 - RSM SCANS study - to be used to scan for following conditions:
#            - Stocks currently in UpTrend
#            - Stocks currently in DownTrend
#            - Stocks where UpTrendJustSarted - first bar of UpTrend for scanend TF
#            - Stocks where DownTrendJustStarted - first bar of DownTrend for scanned TF
#            - Stocks where UpTredJustEnded - first NO Trend bar after UpTrend
#            - Stocks where DownTrendJustEnded - first NO Trend bar after DownTrend
#            - Recommend using default studies for SCANS of RSI, Stochastics or MACD for efficiency
# 
#REQUIREMENTS - RSI Set to 7, EXPONENTIAL
#               Stoch Slow 14 and 3 WILDERS
#               MACD 12,26,9 WEIGHTED
#
#
#CREDITS
# requesed by "@Joseph Patrick 18"
#
#LINK
# https://rockwell-files.s3.amazonaws.com/PXCompanionGuide2ndEd_cover.pdf
# Markus Heikoetter who is the author of the Power X Strategy
# https://usethinkscript.com/threads/mimicking-power-x-strategy-by-markus-heitkoetter.4283/
#
#USAGE
#
declare lower;

plot fiftyLine = 50;
################################################################
##########                 RSI                         #########
################################################################

input lengthRSI = 7;
input over_BoughtRSI = 80;
input over_SoldRSI = 20;
input price = close;
input averageTypeRSI = AverageType.EXPONENTIAL;
def NetChgAvg = MovingAverage(averageTypeRSI, price - price[1], lengthRSI);
def TotChgAvg = MovingAverage(averageTypeRSI, AbsValue(price - price[1]), lengthRSI);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
def RSI = 50 * (ChgRatio + 1);


################################################################
##########                 Stochastic Slow             #########
################################################################
input over_boughtSt = 80;
input over_soldSt = 20;
input KPeriod = 14;
input DPeriod = 3;
input priceH = high;
input priceL = low;
input priceC = close;
input averageTypeStoch = AverageType.WILDERS;
def SlowK = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullK;
def SlowD = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullD;


#################################################################
############           MACD Calculation                 #########
#################################################################
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageTypeMACD = AverageType.WEIGHTED;
def Value = MovingAverage(averageTypeMACD, close, fastLength) - MovingAverage(averageTypeMACD, close, slowLength);
def Avg = MovingAverage(averageTypeMACD, Value, MACDLength);
def Diff = Value - Avg;


#################################################################
############          SCAN Variables                    #########
#################################################################

# If you want to scan for stocks that are not in either trend you can add two filters and scan for false for both conditions

# The UpTrend and DownTrend plots can be used to scan for stocks that are currently in that trend
plot UpTrend = if RSI > 50 and SlowK > 50 and Value > Avg then 1 else Double.NaN;
plot DownTrend = if RSI < 50 and SlowK < 50 and Value < Avg then 1 else Double.NaN;
UpTrend.Hide();
DownTrend.Hide();

# The UpTrendJustStarted and DownTrendJustStarted plots can be used to find stocks that have just started
# a trend in either direction
def UpTrendJustStartedBool = if RSI > 50 and SlowK > 50 and Value > Avg then 1 else 0;
def DownTrendJustStartedBool = if RSI < 50 and SlowK < 50 and Value < Avg then 1 else 0;
plot UpTrendJustStarted = if UpTrendJustStartedBool == 1 and UpTrendJustStartedBool[1] == 0 then 1 else Double.NaN;
plot DownTrendJustStarted = if DownTrendJustStartedBool == 1 and DownTrendJustStartedBool[1] == 0 then 1 else Double.NaN;
UpTrendJustStarted.Hide();
DownTrendJustStarted.Hide();
plot UpTrendJustEnded= if UpTrendJustStartedBool[1] == 1 and UpTrendJustStartedBool == 0 then 1 else Double.NaN;
plot DownTrendJustEnded= if DownTrendJustStartedBool[1] == 1 and DownTrendJustStartedBool == 0 then 1 else Double.NaN;
UpTrendJustEnded.Hide();
DownTrendJustEnded.Hide();

STRATEGY

Below is code for a basic start to a strategy. Please use as you wish.
The orders are set to only open and close during RTH. Please adjust for what you may be looking for. Thanks.

#START OF RSI/Stochastic/MACD Confluence Strategy for ThinkOrSwim
# RSM Strategy - BASIC
#CHANGELOG
# 2020.10.27 V1.0 @cos251 - Added RSI, StochasticSlow and MACD to same indicator
#             - also calculates MACD;
#               Will shade the lower plot area of the following conditions are met
#                    Shade GREEN = RSI > 50 and SlowK > 50 and (macd)Value > (macd)Avg
#                    Shade RED = RSI < 50 and SlowK < 50 and (macd)Value < (macd)Avg
#       
#REQUIREMENTS - RSI Set to 7, EXPONENTIAL
#               Stoch Slow 14 and 3 WILDERS
#               MACD 12,26,9 WEIGHTED

declare upper;


################################################################
##########            AddOrder Prep                    #########
################################################################
def bar = BarNumber();
def CloseAllCondition = SecondstillTime(1558) == 0;
def EOD = if SecondsTillTime(1558) == 0 and SecondsFromTime(1558) == 0 then 1 else 0;
def NotActive = if SecondsFromTime(1550) > 0 then 1 else 0;
def Active1 = if SecondsFromTime(0930) > 0 then 1 else 0;
def notrades = if SecondstillTime(1500) > 0 then 1 else 0;


################################################################
##########                 RSI                         #########
################################################################
input paintBars = yes;
input showShade = no;
input tradetype = { default "long", "short", "both" };
input lengthRSI = 7;
input price = close;
input averageTypeRSI = AverageType.EXPONENTIAL;
def NetChgAvg = MovingAverage(averageTypeRSI, price - price[1], lengthRSI);
def TotChgAvg = MovingAverage(averageTypeRSI, AbsValue(price - price[1]), lengthRSI);
def ChgRatio = if TotChgAvg != 0 then NetChgAvg / TotChgAvg else 0;
def RSI = 50 * (ChgRatio + 1);


################################################################
##########                 Stochastic Slow             #########
################################################################
input over_boughtSt = 80;
input over_soldSt = 20;
input KPeriod = 14;
input DPeriod = 3;
input priceH = high;
input priceL = low;
input priceC = close;
input averageTypeStoch = AverageType.WILDERS;
def SlowK = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullK;
def SlowD = reference StochasticFull(over_boughtSt, over_soldSt, KPeriod, DPeriod, priceH, priceL, priceC, 3, averageTypeStoch).FullD;



#################################################################
#MACD Calculation
input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageTypeMACD = AverageType.WEIGHTED;
def Value = MovingAverage(averageTypeMACD, close, fastLength) - MovingAverage(averageTypeMACD, close, slowLength);
def Avg = MovingAverage(averageTypeMACD, Value, MACDLength);
def Diff = Value - Avg;


#AssignPriceColor
AssignPriceColor(if paintBars and RSI >= 50 and SlowK >= 50 and Value > Avg then Color.GREEN else if paintBars and RSI < 50 and SlowK < 50 and Value < Avg then Color.RED else if paintBars then Color.DARK_GRAY else Color.CURRENT);

#################################################################
############  Shade areas based on criteria; adjust as needed  ##
#################################################################
AddCloud(if showShade and RSI >= 50 and SlowK >= 50 and Value > Avg then Double.POSITIVE_INFINITY else Double.NaN, if RSI >= 50 and SlowK >= 50 and Value > Avg then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_Green);
AddCloud(if showShade and RSI < 50 and SlowK < 50 and Value < Avg then Double.POSITIVE_INFINITY else Double.NaN, if RSI < 50 and SlowK < 50 and Value < Avg then Double.NEGATIVE_INFINITY else Double.NaN, Color.LIGHT_RED);



#################################################################
############          SCAN Variables                    #########
#################################################################
plot UpTrend = if RSI >= 50 and SlowK >= 50 and Value > Avg then 1 else 0;
plot DownTrend = if RSI < 50 and SlowK < 50 and Value < Avg then 1 else 0;
def LongBuy = if UpTrend == 1 and UpTrend[1] == 0 then 1 else 0;
def LongExit = if UpTrend[1] == 1 and UpTrend == 0 then 1 else 0;
def ShortSell = if DownTrend == 1 and DownTrend[1] == 0 then 1 else 0;
def ShortExit = if DownTrend == 0 and DownTrend[1] == 1 then 1 else 0;
UpTrend.Hide();
DownTrend.Hide();
AddLabel(yes, if UpTrend == 1 then "::RSM-Signal:LONG" else if DownTrend == 1 then "::RSM-Signal:SHORT" else "::RSM-Signal:IDLE", if UpTrend == 1 then Color.GREEN else if DownTrend == 1 then Color.RED else Color.GRAY);

plot upArrow = if UpTrend == 1 and UpTrend[1] == 0 then low else Double.NaN;
upArrow.SetPaintingStrategy(PaintingStrategy.ARROW_UP);
upArrow.SetDefaultColor(Color.GREEN);

plot downArrow = if DownTrend == 1 and DownTrend[1] == 0 then high else Double.NaN;
downArrow.SetPaintingStrategy(PaintingStrategy.ARROW_DOWN);
downArrow.SetDefaultColor(Color.RED);


### BUY
#AddOrder(OrderType.BUY_TO_OPEN, LongBuy == 1 and (tradetype == tradetype.long or tradetype == tradetype.both), open, tickcolor = GetColor(9), #arrowcolor = GetColor(9), name = "LONG");

#AddOrder(OrderType.SELL_TO_CLOSE, LongExit == 1 and (tradetype == tradetype.long or tradetype == tradetype.both), open, tickcolor = #GetColor(9), arrowcolor = GetColor(9), name = "LONG_EXIT");

AddOrder(OrderType.BUY_AUTO, LongBuy == 1 and (tradetype == tradetype.long or tradetype == tradetype.both) and Active1 and notrades, price = close, tickcolor = Color.ORANGE, arrowcolor = Color.ORANGE, name = "BUY");

AddOrder(OrderType.Sell_To_Close, LongExit == 1 and (tradetype == tradetype.long or tradetype == tradetype.both), price = open[-1], tickcolor = Color.ORANGE, arrowcolor = Color.ORANGE, name = "Sell To Close");


AddOrder(OrderType.Sell_TO_CLOSE, EOD or closeAllCondition, price = close, tickcolor = Color.ORANGE, arrowcolor = Color.ORANGE, name = "SELL EOD");

### SELL
#AddOrder(OrderType.SELL_TO_OPEN, ShortSell == 1 and (tradetype == tradetype.short or tradetype == tradetype.both), open, tickcolor = #GetColor(9), arrowcolor = GetColor(8), name = "SHORT");
#AddOrder(OrderType.BUY_TO_CLOSE, ShortExit == 1 and (tradetype == tradetype.short or tradetype == tradetype.both), open, tickcolor = #GetColor(9), arrowcolor = GetColor(8), name = "Short_EXIT");

AddOrder(OrderType.SELL_AUTO, ShortSell == 1 and (tradetype == tradetype.short or tradetype == tradetype.both)  and Active1 and notrades , price = close, tickcolor = Color.YELLOW, arrowcolor = Color.YELLOW, name = "SELL");

AddOrder(OrderType.Buy_To_Close, ShortExit == 1 and (tradetype == tradetype.short or tradetype == tradetype.both), price = open[-1], tickcolor = Color.ORANGE, arrowcolor = Color.ORANGE, name = "Buy To Close");

AddOrder(OrderType.BUY_TO_CLOSE, EOD or closeAllCondition, price = close, tickcolor = Color.ORANGE, arrowcolor = Color.ORANGE, name = "BUY EOD");

hello to everyone, this is a great job, a quick question... i've traying this strategy it is very great!! but is only for day trading.. can someone changes to a swing trading, i will like to try it for more then a day!! also i see the original strategy have the two targets and the stop loss. if somenone can help me really appreciate. thanks in advance

 

[Nicholas]

Greeting guys,
Does the indicator work on the app on mobile. It appear to be super zoom out. Like a “vwap” on a very large time frame/look back duration was in it.

Appear as 1 line on the chart. Tks