Preferred time slots

[congamike]

I've been studying the ICT Mentorship program in youtube. He recommends that there are good times and less preferred times to place entries.
Is it possible to create a Lower Study that draws a line/box/something to start and stop at certain times of the day? (I tried but couldn't figure it out.)

 

[halcyonguy]

I've been studying the ICT Mentorship program in youtube. He recommends that there are good times and less preferred times to place entries.
Is it possible to create a Lower Study that draws a line/box/something to start and stop at certain times of the day? (I tried but couldn't figure it out.)

this will draw 4 purple shaded rectangles, on the desired time periods, on a lower chart.
there are 4 pairs of start/stop times, to define the periods.

if you enter a time that is not a multiple of the chart time, that period won't be shaded.
( 10:04 on a 5 minute chart )

# shade_time_periods_02

# shade time periods, during a day

# https://usethinkscript.com/threads/preferred-time-slots.12736/
# Preferred time slots   congamike  9/19

#------------------------------------
#if you want the shading to be on the upper chart

# .. disable this line ( by adding a  #  in front of it )
declare lower;
# .. and disable this plot
plot z = 0;
z.setdefaultcolor(color.black);

#------------------------------------

def na = Double.NaN;
def pos = Double.POSITIVE_INFINITY;
def neg = Double.NEGATIVE_INFINITY;

# define a color for all the time periods
DefineGlobalColor( "shade1" , color.violet);


# define time periods (EST)
#/////////////////////////////////////
# copy this code segment for as many periods as desired, and change the variable names
input start1 = 1000;
input end1 = 1030;
def period1 = if SecondsFromTime(start1) >= 0 and SecondsTillTime(end1) > 0 then 1 else 0;
addcloud( (if period1 then pos else na), neg,  GlobalColor( "shade1" ));
#/////////////////////////////////////

input start2 = 1130;
input end2 = 1200;
def period2 = if SecondsFromTime(start2) >= 0 and SecondsTillTime(end2) > 0 then 1 else 0;
addcloud( (if period2 then pos else na), neg,  GlobalColor( "shade1" ));

input start3 = 1330;
input end3 = 1400;
def period3 = if SecondsFromTime(start3) >= 0 and SecondsTillTime(end3) > 0 then 1 else 0;
addcloud( (if period3 then pos else na), neg,  GlobalColor( "shade1" ));

input start4 = 1500;
input end4 = 1530;
def period4 = if SecondsFromTime(start4) >= 0 and SecondsTillTime(end4) > 0 then 1 else 0;
addcloud( (if period4 then pos else na), neg,  GlobalColor( "shade1" ));
#
#

-------------------------------------------------------

this code is some notes that may help with,
..drawing vertical lines,
..creating a custom color,
..defining times / time periods

#------------------------

# create a custom color
#  70,70,70 is light gray
#input color_red_num1 = 70;
#input color_green_num1 = 70;
#input color_blue_num1 = 170;
#DefineGlobalColor( "shade1" , CreateColor( color_red_num1, color_green_num1, color_blue_num1));
#AddCloud(hiline, loline,  GlobalColor( "shade1" ),  GlobalColor( "shade1" ));

# ref
# hex color picker
#  https://www.w3schools.com/colors/colors_picker.asp


#input show_start_verticalline = no;
#input show_end_verticalline = no;
#AddVerticalLine(show_start_verticalline and start1, "start", Color.CYAN);
#AddVerticalLine(show_end_verticalline and end1, "end", Color.CYAN);


# is current bar before normal trading hours?
#def before = if SecondsTillTime(start) > 0 then 1 else 0;
# is current bar during normal trading hours?
#def daytime = if SecondsFromTime(start) >= 0 and SecondsTillTime(end) > 0 then 1 else 0;
# is current bar after normal trading hours?
#def after = if SecondsFromTime(end) > 0 then 1 else 0;

#def start1 = if SecondsTillTime(start) == 0 then 1 else 0;
#def end1 = if SecondsFromTime(end) == 0 then 1 else 0;
#