Plot High Low 1st Day to form range

[Sai]

Plot High Low 1st Day of the month to form range

HI, I am trying to plot 1st Day of the month's High and LOW . i want to use this as a range for my Swings for that month.

 

[SleepyZ]

HI, I am trying to plot 1st Day of the month's High and LOW . i want to use this as a range for my Swings for that month.

This plots those lines and has an optional cloud.

#HL_Month
def hi = if GetMonth() != GetMonth()[1] then high else hi[1];
plot h = hi;
h.SetPaintingStrategy(PaintingStrategy.DASHES);
h.setdefaultColor(color.green);

def lo = if GetMonth() != GetMonth()[1] then low else lo[1];
plot l = lo;
l.SetPaintingStrategy(PaintingStrategy.DASHES);
l.setdefaultColor(color.red);

input cloud = no;
defineGlobalColor("Cloud", color.light_gray);
addcloud(if !cloud then double.nan else h, l, globalColor("Cloud"), globalColor("Cloud"));
#

 

[Sai]

Thank you SleepyZ.

 

[Sai]

This plots those lines and has an optional cloud.

Hi Sally, if i am trying to plot only for current month using GetMonth() != GetMonth()[1] . its acting weired. can you pls help to plot for current month pls.

 

[SleepyZ]

Hi Sally, if i am trying to plot only for current month using GetMonth() != GetMonth()[1] . its acting weired. can you pls help to plot for current month pls.

This should plot just the current month's h/l. This version should also work on intraday charts with enough days displayed on the chart for the month.

#HL_Month
input showcurrentonly = yes;

def hi = if GetMonth() != GetMonth()[1] then high(period = AggregationPeriod.DAY) else hi[1];
plot h = if showcurrentonly and GetMonth() != GetLastMonth() then Double.NaN else hi;
h.SetPaintingStrategy(PaintingStrategy.DASHES);
h.SetDefaultColor(Color.GREEN);

def lo = if GetMonth() != GetMonth()[1] then low(period = AggregationPeriod.DAY) else lo[1];
plot l = if showcurrentonly and GetMonth() != GetLastMonth() then Double.NaN else lo;
l.SetPaintingStrategy(PaintingStrategy.DASHES);
l.SetDefaultColor(Color.RED);

input cloud = no;
DefineGlobalColor("Cloud", Color.LIGHT_GRAY);
AddCloud(if !cloud then Double.NaN else h, l, GlobalColor("Cloud"), GlobalColor("Cloud"));
#

 

[Sai]

This should plot just the current month's h/l. This version should also work on intraday charts with enough days displayed on the chart for the month.

Hi Sleepyz, Thank you . Trying to see how can we draw the range for Highs and lows of 1st 10 business days of the month(January for example ) . I see above has different approaches which cant be used to find out for 10 days. can you help me
Thank you

 

[SleepyZ]

Hi Sleepyz, Thank you . Trying to see how can we draw the range for Highs and lows of 1st 10 business days of the month(January for example ) . I see above has different approaches which cant be used to find out for 10 days. can you help me
Thank you

This should plot the developing high/low for the 1st x days input of the last month on the chart.

#Plot H/L 1st 10 trading days of Last Month Extended
input days = 10;
def ymd = GetYYYYMMDD();
def ct  = if GetMonth() != GetMonth()[1] and ymd then 1
          else if ymd != ymd[1]
          then ct[1] + 1
          else ct[1];

def h   = if isnan(close)
          then h[1]
          else if ct[1] != 1 and ct == 1
          then high
          else if ct <= days
          then Max(high, h[1])
          else h[1];
plot hh_x_days = if GetMonth() != GetLastMonth() then Double.NaN else h;

def l   = CompoundValue(1,
          if isnan(close)
          then l[1]
          else if ct[1] != 1 and ct == 1
          then low
          else if ct <= days
          then Min(low, l[1])
          else l[1], low);
plot ll_xdays = if GetMonth() != GetLastMonth() then Double.NaN else l;

input verticals = yes;
addverticalLine(verticals and getmonth()!=getmonth()[1], " ", color.white);
addverticalLine(verticals and ct==11 and ct[1] == 10, " ", color.white);

#

 

[Sai]

THANK YOU SkeepyZ. Each version has diff logic . Any idea how can we have this as a scan column for the stocks which close is above high / Low of this range

 

[SleepyZ]

THANK YOU SkeepyZ. Each version has diff logic . Any idea how can we have this as a scan column for the stocks which close is above high / Low of this range

There was different logic because in the 1st request you displayed a monthly chart upon which only regular trading hours are included. Looking at the 10 day request, I assumed you might use intraday charts with expanded hours and therefore you would want those included in the high/low.

Here if the 10 day code with scan logic that you can adjust to your preferences.

To test it today, the code is set to input days = 2, only 1 plot can be used so the other is commented out, and scan was set to 5m, extended hours included and used plot scanhigh. The custom 2 column in the results is the h / l values at days = 2

#Plot H/L 1st 10 trading days of Last Month Extended
input days = 2;
def ymd = GetYYYYMMDD();
def ct  = if GetMonth() != GetMonth()[1] and ymd then 1
          else if ymd != ymd[1]
          then ct[1] + 1
          else ct[1];

def h   = if isnan(close)
          then h[1]
          else if ct[1] != 1 and ct == 1
          then high
          else if ct <= days
          then Max(high, h[1])
          else h[1];
plot scan_high = close > h;

def l   = CompoundValue(1,
          if isnan(close)
          then l[1]
          else if ct[1] != 1 and ct == 1
          then low
          else if ct <= days
          then Min(low, l[1])
          else l[1], low);

#plot scanlow = close < l;
#

 

[Sai]

Thank you SleepyZ. Appreciate your help .you are awesome!!!