Please help to get horizontal lines to plot.

[METAL]

I keep getting bands above all of the bars. I only want the previous days bar to be where the plot begins and goes across the chart to the end of following day.

# Half ATR Bands

input length = 14;
def atrValue = ATR(length);
def halfAtr = atrValue / 2;

def prevClose = close(period = AggregationPeriod.DAY)[1];

def ATR_High = if !IsNaN(prevClose) then prevClose + halfAtr else Double.NaN;
def ATR_Low = if !IsNaN(prevClose) then prevClose - halfAtr else Double.NaN;

plot UpperLine = CompoundValue(1, ATR_High, ATR_High);
UpperLine.SetLineWeight(2);
UpperLine.SetDefaultColor(Color.green);

plot LowerLine = CompoundValue(1, ATR_Low, ATR_Low);
LowerLine.SetLineWeight(2);
LowerLine.SetDefaultColor(Color.red);

 

[SleepyZ]

I keep getting bands above all of the bars. I only want the previous days bar to be where the plot begins and goes across the chart to the end of following day.

# Half ATR Bands

input length = 14;
def atrValue = ATR(length);
def halfAtr = atrValue / 2;

def prevClose = close(period = AggregationPeriod.DAY)[1];

def ATR_High = if !IsNaN(prevClose) then prevClose + halfAtr else Double.NaN;
def ATR_Low = if !IsNaN(prevClose) then prevClose - halfAtr else Double.NaN;

plot UpperLine = CompoundValue(1, ATR_High, ATR_High);
UpperLine.SetLineWeight(2);
UpperLine.SetDefaultColor(Color.green);

plot LowerLine = CompoundValue(1, ATR_Low, ATR_Low);
LowerLine.SetLineWeight(2);
LowerLine.SetDefaultColor(Color.red);

See if this is what you want. The ATR was adjusted to be at the same Aggregation you used for the close.

# Half ATR Bands

input showlastdayonly = yes;
input length = 14;
input averageType = AverageType.WILDERS;
input agg = AggregationPeriod.DAY;

def ATR = MovingAverage(averageType, TrueRange(high(period = agg), close(period = agg), low(period = agg)), length);
def halfAtr = ATR / 2;

def prevClose = close(period = agg)[1];

def ATR_High = if !IsNaN(prevClose) then prevClose + halfAtr else Double.NaN;
def ATR_Low = if !IsNaN(prevClose) then prevClose - halfAtr else Double.NaN;

plot UpperLine = if GetDay() != GetLastDay() and showlastdayonly then Double.NaN else CompoundValue(1, ATR_High, ATR_High);
UpperLine.SetLineWeight(2);
UpperLine.SetDefaultColor(Color.GREEN);

plot LowerLine = if GetDay() != GetLastDay() and showlastdayonly then Double.NaN else CompoundValue(1, ATR_Low, ATR_Low);
LowerLine.SetLineWeight(2);
LowerLine.SetDefaultColor(Color.RED);