Repaints Noro's OverCloud MTF For ThinkOrSwim

[petergluis]

Noro's OverCloud provides nice supports and resistances in different timeframes.

I would like to know how to convert this Pinescript indicator into one by using Thinkscript.
Here is the link of Noro's OverCloud v1.2 MTF:
https://tradingview.com/script/A83HIJSO-noro-s-overcloud-v1-2-mtf/

 

[samer800]

Noro's OverCloud provides nice supports and resistances in different timeframes. I would like to know how to convert this Pinescript indicator into one by using Thinkscript.

Here is the link of Noro's OverCloud v1.2 MTF:

https://ru.tradingview.com/script/A83HIJSO-noro-s-overcloud-v1-2-mtf/

Here is the content of the indicator. Thank you very much for your help.



//Noro
//2017

//@version=2

study(title = "Noro's OverCloud v1.2 MTF", shorttitle = "OverCloud 1.2", overlay = true)

//Settings
cloud = input(25, defval = 25, minval = 5, maxval = 50, title = "cloud, % of ATR")
needcenter = input(false, defval = false, title = "50%-line")
needcenterbig = input(false, defval = false, title = "50%-line big timeframe")
bigtf = input('D', defval = 'D', title = "big timeframe")
border = input(true, defval = true, title = "need borders?")
trendcolor = input(true, defval = true, title = "need trendcolor?")

//Fast ATR
up = hl2 - (3 * atr(7))
dn = hl2 + (3 * atr(7))
tup = close[1] > tup[1] ? max(up, tup[1]) : up
tdown = close[1] < tdown[1]? min(dn, tdown[1]) : dn
center = (tup + tdown) / 2
limit = (tup - tdown) / 100 * cloud
upcloud = tup - limit
dncloud = tdown + limit
trend = close > tdown[1] ? 1 : close < tup[1]? -1 : nz(trend[1], 1)

centercolor = needcenter == false ? na : blue
bordercolor = border == true ? black : na
cloudcolor = trend == 1 ? lime : red
p11 = plot(tup, color = bordercolor, linewidth = 1, transp = 0, title = "100% ATR")
p12 = plot(tdown, color = bordercolor, linewidth = 1, transp = 0, title = "Upper cloud")
p13 = plot(center, color = centercolor, linewidth = 3, transp = 0, title = "50% ATR")
p14 = plot(upcloud, color = bordercolor, linewidth = 1, transp = 0, title = "Lower cloud")
p15 = plot(dncloud, color = bordercolor, linewidth = 1, transp = 0, title = "0% ATR")
fill(p11, p14, color = trendcolor == false ? lime : cloudcolor, transp = 50)
fill(p12, p15, color = trendcolor == false ? red : cloudcolor, transp = 50)

//Slow ATR
up2 = security(tickerid, bigtf, hl2 - (3 * atr(7)))
dn2 = security(tickerid, bigtf, hl2 + (3 * atr(7)))
tup2 = close[1] > tup2[1] ? max(up2, tup2[1]) : up2
tdown2 = close[1] < tdown2[1]? min(dn2, tdown2[1]) : dn2
center2 = (tup2 + tdown2) / 2
limit2 = (tup2 - tdown2) / 100 * cloud
upcloud2 = tup2 - limit2
dncloud2 = tdown2 + limit2
trend2 = close > tdown2[1] ? 1 : close < tup2[1]? -1 : nz(trend2[1], 1)

centercolor2 = needcenterbig == false ? na : black
bordercolor2 = border == true ? black : na
cloudcolor2 = trend2 == 1 ? lime : red
p21 = plot(tup2, color = bordercolor2, linewidth = 1, transp = 0, title = "100% ATR big TF")
p22 = plot(tdown2, color = bordercolor2, linewidth = 1, transp = 0, title = "Upper cloud big TF")
p23 = plot(center2, color = centercolor2, linewidth = 3, transp = 0, title = "50% ATR big TF")
p24 = plot(upcloud2, color = bordercolor2, linewidth = 1, transp = 0, title = "Lower cloud big TF")
p25 = plot(dncloud2, color = bordercolor2, linewidth = 1, transp = 0, title = "0% ATR big TF")
fill(p21, p24, color = trendcolor == false ? lime : cloudcolor2, transp = 50)
fill(p22, p25, color = trendcolor == false ? red : cloudcolor2, transp = 50)

https://imgur.com/9Jd5gJ9

check the below:

#//Noro
#study(title = "Noro's OverCloud v1.2 MTF", shorttitle = "OverCloud 1.2", overlay = true)
# Converted by Sam4Cok@Samer800    - 03/2024

input cloud = 25; #, defval = 25, minval = 5, maxval = 50, title = "cloud, % of ATR")
input showCenterLine = no; #(false, defval = false, title = "50%-line")
input showBigTimeCenterLine = no; #(false, defval = false, title = "50%-line big timeframe")
input bigtf = AggregationPeriod.DAY; #('D', defval = 'D', title = "big timeframe")
input needBorders = yes; #(true, defval = true, title = "need borders?")
input needTrendColor = yes; #(true, defval = true, title = "need trendcolor?")

def na = Double.NaN;
#//Fast ATR
def up = hl2 - (3 * atr(Length = 7));
def dn = hl2 + (3 * atr(Length = 7));
def tup = if close[1] > tup[1] then max(up, tup[1]) else up;
def tdown = if close[1] < tdown[1] then min(dn, if(!tdown[1], dn, tdown[1])) else dn;
def center = (tup + tdown) / 2;
def limit = (tup - tdown) / 100 * cloud;
def upcloud = tup - limit;
def dncloud = tdown + limit;
def trend = if close > tdown[1] then 1 else
            if close < tup[1]then -1 else if(trend[1], trend[1], 1);

def cloudColUp = if !needTrendColor then  1 else if  trend == 1 then 1 else -1;
def cloudColDn = if !needTrendColor then -1 else if  trend == 1 then 1 else -1;
def p11 = tup; #, color = bordercolor, linewidth = 1, transp = 0, title = "100% ATR")
def p12 = tdown; #, color = bordercolor, linewidth = 1, transp = 0, title = "Upper cloud")
plot p13 = if showCenterLine then center else na; #, color = centercolor, linewidth = 3, transp = 0, title = "50% ATR")
def p14 = upcloud; #, color = bordercolor, linewidth = 1, transp = 0, title = "Lower cloud")
def p15 = dncloud; #, color = bordercolor, linewidth = 1, transp = 0, title = "0% ATR")
p13.SetDefaultColor(Color.CYAN);

AddCloud(if cloudColUp > 0 then p11 else na, p14, Color.DARK_GREEN, Color.DARK_GREEN, needBorders);
AddCloud(if cloudColUp < 0 then p11 else na, p14, Color.DARK_RED, Color.DARK_RED, needBorders);
AddCloud(if cloudColDn > 0 then p12 else na, p15, Color.DARK_GREEN, Color.DARK_GREEN, needBorders);
AddCloud(if cloudColDn < 0 then p12 else na, p15, Color.DARK_RED, Color.DARK_RED, needBorders);

#//Slow ATR
def tr = TrueRange(high(Period = bigtf), close(Period = bigtf), low(Period = bigtf));
def atr7 = WildersAverage(tr, 7);
def hl = hl2(Period = bigtf);
def up2 = hl - (3 * atr7);
def dn2 = hl + (3 * atr7);
def tup2 = if close[1] > tup2[1] then max(up2, tup2[1]) else up2;
def tdown2 = if close[1] < tdown2[1] then min(dn2, if(!tdown2[1], dn2, tdown2[1])) else dn2;
def center2 = (tup2 + tdown2) / 2;
def limit2 = (tup2 - tdown2) / 100 * cloud;
def upcloud2 = tup2 - limit2;
def dncloud2 = tdown2 + limit2;
def trend2 = if close > tdown2[1] then 1 else
             if close < tup2[1] then -1 else if(trend2[1], trend2[1], 1);

def cloudColUp2 = if !needTrendColor then  1 else if  trend2 == 1 then 1 else -1;
def cloudColDn2 = if !needTrendColor then -1 else if  trend2 == 1 then 1 else -1;

def p21 = tup2; #, color = bordercolor2, linewidth = 1, transp = 0, title = "100% ATR big TF")
def p22 = tdown2; #, color = bordercolor2, linewidth = 1, transp = 0, title = "Upper cloud big TF")
plot p23 = if showBigTimeCenterLine then center2 else na; # title = "50% ATR big TF")
def p24 = upcloud2; #, color = bordercolor2, linewidth = 1, transp = 0, title = "Lower cloud big TF")
def p25 = dncloud2; #, color = bordercolor2, linewidth = 1, transp = 0, title = "0% ATR big TF")
p23.SetDefaultColor(Color.MAGENTA);

AddCloud(if cloudColUp2 > 0 then p21 else na, p24, Color.DARK_GREEN, Color.DARK_GREEN);
AddCloud(if cloudColUp2 < 0 then p21 else na, p24, Color.DARK_RED, Color.DARK_RED);
AddCloud(if cloudColDn2 > 0 then p22 else na, p25, Color.DARK_GREEN, Color.DARK_GREEN);
AddCloud(if cloudColDn2 < 0 then p22 else na, p25, Color.DARK_RED, Color.DARK_RED);



#== END of CODE