newbie Q: TOS scan with bounded price above a moving average

[polaris8030]

I am just starting on TOS. Stock scan seems quite powerful but I am stumbling on using the moving average study using the GUI
What I would like:
result = (moving_average)(1+lower_bound) < current_daily_close < (moving_average)(1+upper_bound)

for example: return all stocks that are above a moving average at least 2% but no greater than 20%
where moving average could be defined in mins, days, weeks, or months

thanks
-Patrick

 

[halcyonguy]

I am just starting on TOS. Stock scan seems quite powerful but I am stumbling on using the moving average study using the GUI
What I would like:
result = (moving_average)(1+lower_bound) < current_daily_close < (moving_average)(1+upper_bound)

for example: return all stocks that are above a moving average at least 2% but no greater than 20%
where moving average could be defined in mins, days, weeks, or months

thanks
-Patrick

here are 2 studies for testing, and upper and a lower.
i think the lower can be used as a scan.

the upper one shows red vertical lines when the close is in the range.
the lower one shows a spike when the close is in the range.

test with TSLA, or NVDA , with 2 and 20%. most stocks won't generate triggers over 2%.

upper

# scan_near_avg_rng_upper

#https://usethinkscript.com/threads/newbie-q-tos-scan-with-bounded-price-above-a-moving-average.15747/
# Q: TOS scan with bounded price above a moving average
#I am just starting on TOS. Stock scan seems quite powerful but I am stumbling on using the moving average study using the #GUI
#What I would like:
#result = (moving_average)(1+lower_bound) < current_daily_close < (moving_average)(1+upper_bound)
#for example: return all stocks that are above a moving average at least 2% but no greater than 20%
#where moving average could be defined in mins, days, weeks, or months


def na = double.nan;
def bn = barnumber();

def price = close;
input ma1_len = 21;
input ma1_type =  AverageType.EXPONENTIAL;
def ma1 = MovingAverage(ma1_type, price, ma1_len);

plot z1 = ma1;

input upper_bound = 20.0;
input lower_bound = 2.0;

def upper1 = (ma1 * (1 + upper_bound/100));
def lower1 = (ma1 * (1 + lower_bound/100));

plot z2 = upper1;
plot z3 = lower1;

def x1 = ( close >= lower1 and close <= upper1);
addverticalline(x1, "-");
#

---------------

lower

# scan_near_avg_rng_lower

#https://usethinkscript.com/threads/newbie-q-tos-scan-with-bounded-price-above-a-moving-average.15747/
#newbie Q: TOS scan with bounded price above a moving average

declare lower;

def na = double.nan;
def bn = barnumber();

def price = close;
input ma1_len = 21;
input ma1_type =  AverageType.EXPONENTIAL;
def ma1 = MovingAverage(ma1_type, price, ma1_len);

input upper_bound = 20.0;
input lower_bound = 2.0;

def x = (close >= (ma1 * (1 + lower_bound/100))) and (close <= (ma1 * (1 + upper_bound/100)));

plot z = x;
#

TSLA 15min 6/8+