Need assistance with finishing strategy code

[nowhmar]

I am creating a strategy that uses two Variable moving averages the 10, and the 50 vma I need some help finishing the code...

#
# TD Ameritrade IP Company, Inc. (c) 2008-2021
#

input price = close;
input fastlegnth  = 10;
input slowlength = 50;


def tmp1 = if price > price[1] then price - price[1] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);
plot VMA = asd;
VMA.SetDefaultColor(GetColor(0));

def buy = fastlegnth > slowlegnth ;
def sell = slowlegnth < fastlegnth;


AddOrder(OrderType.BUY_AUTO, fastlegnth  crosses above Slowlegnth, tickcolor = GetColor(1), arrowcolor = GetColor(1), name = "long");
AddOrder(OrderType.SELL_AUTO, fastlegnth crosses below fastlegnth, tickcolor = GetColor(2), arrowcolor = GetColor(2), name = "take profit");

 

[halcyonguy]

what do you want to add/change ?

 

[nowhmar]

what do you want to add/change ?

it is not functional I need assistance to get it to work. I am a new thinkscripter.

 

[rad14733]

it is not functional I need assistance to get it to work. I am a new thinkscripter.

Your buy and sell variables should be using crosses above and crosses below, and you AddOrder()'s should be using buy and sell as the conditions... I haven't checked beyond that but those items jumped right out... See if that gets you further...

 

[nowhmar]

Your buy and sell variables should be using crosses above and crosses below, and you AddOrder()'s should be using buy and sell as the conditions... I haven't checked beyond that but those items jumped right out... See if that gets you further...

that seemed to decrease some of the red highlighting. still isn't working though I just don't know what else I am missing. here is the latest of what I changed. I would appreciate any further guidance.

#
# TD Ameritrade IP Company, Inc. (c) 2008-2021
#

input price = close;
input fastlegnth  = 10;
input slowlength = 50;


def tmp1 = if price > price[1] then price - price[1] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);
plot VMA = asd;
VMA.SetDefaultColor(GetColor(0));

def buy = fastlegnth crosses above slowlegnth;
def sell = fastlegnth crosses below slowlegnth;


AddOrder(OrderType.BUY_AUTO, buy, tickcolor = GetColor(1), arrowcolor = GetColor(1), name = "long");
AddOrder(OrderType.SELL_AUTO, sell, tickcolor = GetColor(2), arrowcolor = GetColor(2), name = "take profit");

 

[halcyonguy]

your compoundvalue() has 2 parameters , instead of 3. you are missing the 1st parameter.

if the barnumber is <= the 1st number, then use the 3rd parameter/formula.

if the barnumber is > the 1st number, then use the 2nd parameter/formula

i've never seen the parameter names used before in compoundvalue, but probably ok.

https://tlc.thinkorswim.com/center/reference/thinkScript/Functions/Others/CompoundValue

 

[nowhmar]

your compoundvalue() has 2 parameters , instead of 3. you are missing the 1st parameter.

if the barnumber is <= the 1st number, then use the 3rd parameter/formula.

if the barnumber is > the 1st number, then use the 2nd parameter/formula

i've never seen the parameter names used before in compoundvalue, but probably ok.

https://tlc.thinkorswim.com/center/reference/thinkScript/Functions/Others/CompoundValue

do you mean a second group of def statements for the other moving average? I switched the 1 for the two. It didnt help...

def tmp1 = if price > price[2] then price - price[2] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);

 

[generic]

@nowhmar Your d2, d4, coeff length's are undefined. Compoundvalue is fine since you specified visible and historical data. Your buy and sell conditions have some spelling problem. I made an assumption of what you want. Remember to save it as a strategy.

#
# TD Ameritrade IP Company, Inc. (c) 2008-2021
#

input price = close;
input fastlength  = 10;
input slowlength = 50;

script VMA {
input price = close;
input length = 10;
def tmp1 = if price > price[1] then price - price[1] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);
plot VMA = asd;
}

def vma_fast = VMA(price, fastlength);
def vma_slow = VMA(price, slowlength);

def buy = vma_fast crosses above vma_slow;
def sell = vma_fast crosses below vma_slow;


AddOrder(OrderType.BUY_AUTO, buy, tickcolor = GetColor(1), arrowcolor = GetColor(1), name = "long");
AddOrder(OrderType.SELL_AUTO, sell, tickcolor = GetColor(2), arrowcolor = GetColor(2), name = "take profit");

 

[halcyonguy]

do you mean a second group of def statements for the other moving average? I switched the 1 for the two. It didnt help...

def tmp1 = if price > price[2] then price - price[2] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);

no, i mean what i wrote. the compoundvalue() funtion is not configured correctly.

 

[nowhmar]

@nowhmar Your d2, d4, coeff length's are undefined. Compoundvalue is fine since you specified visible and historical data. Your buy and sell conditions have some spelling problem. I made an assumption of what you want. Remember to save it as a strategy.

#
# TD Ameritrade IP Company, Inc. (c) 2008-2021
#

input price = close;
input fastlength  = 10;
input slowlength = 50;

script VMA {
input price = close;
input length = 10;
def tmp1 = if price > price[1] then price - price[1] else 0;
def tmp2 = if price[1] > price then price[1] - price else 0;
def d2 = Sum(tmp1, length);
def d4 = Sum(tmp2, length);
def cond = d2 + d4 == 0;
def ad3 = if cond then 0 else (d2 - d4) / (d2 + d4) * 100;
def coeff = 2 / (length + 1) * AbsValue(ad3) / 100;
def asd = CompoundValue("visible data" = coeff * price + (if IsNaN(asd[1]) then 0 else asd[1]) * (1 - coeff), "historical data" = price
);
plot VMA = asd;
}

def vma_fast = VMA(price, fastlength);
def vma_slow = VMA(price, slowlength);

def buy = vma_fast crosses above vma_slow;
def sell = vma_fast crosses below vma_slow;


AddOrder(OrderType.BUY_AUTO, buy, tickcolor = GetColor(1), arrowcolor = GetColor(1), name = "long");
AddOrder(OrderType.SELL_AUTO, sell, tickcolor = GetColor(2), arrowcolor = GetColor(2), name = "take profit");

thats exactly what I wanted thanks for that.