MTF StochasticMACD

[TOS007]

Hi everyone, I am trying to code Multi-timeframe StochasticMACD. I simply copy the formula from TOS, but the value is not correct at all. Can anyone correct my mistake, please? Thanks in advance and much appreciated.

declare lower;

input tf = {"MIN", "TWO_MIN", default "FIVE_MIN", "FIFTEEN_MIN", "HOUR", "TWO_HOURS", "FOUR_HOURS", "DAY", "WEEK", "MONTH"};

def timeframe;

switch (tf){
case "MIN":
timeframe = AggregationPeriod.MIN;
case "TWO_MIN":
timeframe = AggregationPeriod.TWO_MIN;
case "FIVE_MIN":
timeframe = AggregationPeriod.FIVE_MIN;
case "FIFTEEN_MIN":
timeframe = AggregationPeriod.FIFTEEN_MIN;
case "HOUR":
timeframe = AggregationPeriod.HOUR;
case "TWO_HOURS":
timeframe = AggregationPeriod.TWO_HOURS;
case "FOUR_HOURS":
timeframe = AggregationPeriod.FOUR_HOURS;
case "DAY":
timeframe = AggregationPeriod.DAY;
case "WEEK":
timeframe = AggregationPeriod.WEEK;
case "MONTH":
timeframe = AggregationPeriod.MONTH;
}


input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close, fastLength);
def slowMA = MovingAverage(averageType, close, slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);

plot overbought = over_bought;
overbought.SetDefaultColor(GetColor(5));
overbought.SetStyle(Curve.SHORT_DASH);

plot oversold = over_sold;
oversold.SetDefaultColor(GetColor(5));
oversold.SetStyle(Curve.SHORT_DASH);

 

[TOS007]

here is the image.

https://imgur.com/a/uk11wbo

 

[TOS007]

I can see the mistake for plotting the stochasticMACD without the timeframe, and I will try to figure it out how to code that line.

 

[TOS007]

yeah, I am that dumb. I don't know how to code these two statements for MTF.

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);

 

[TOS007]

Can anyone correct my statement for this line, please?

plot StochasticMACD = ((stochFastMA - stochSlowMA) * 100, close(period = Period));

This is what I have for the rest:

#
# TD Ameritrade IP Company, Inc. (c) 2019-2021
#

declare lower;

input Period = AggregationPeriod.HOUR;
input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close, fastLength);
def slowMA = MovingAverage(averageType, close, slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = ((stochFastMA - stochSlowMA) * 100, close(period = Period);
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));

 

[TOS007]

I think I almost got it. The StochaMACD is more jacketed than its non MTF version.
The values for stochasticMACD and Signal line are not matching but the crossover at almost identical.

https://imgur.com/G7QCasN

declare lower;
input Period = aggregationPeriod.HOUR;
input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close(period = Period), fastLength);
def slowMA = MovingAverage(averageType, close(period = Period), slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));

 

[halcyonguy]

I think I almost got it. The StochaMACD is more jacketed than its non MTF version.
The values for stochasticMACD and Signal line are not matching but the crossover at almost identical.

https://imgur.com/G7QCasN

declare lower;
input Period = aggregationPeriod.HOUR;
input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close(period = Period), fastLength);
def slowMA = MovingAverage(averageType, close(period = Period), slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));

try adding period = ...
to the hh and ll formulas

 

[TOS007]

try adding period = ...
to the hh and ll formula

halcyonguy,

Thank you for taking your time to look over my struggle to get this to work. I have tried your tip, but I just could not get it to work.

https://imgur.com/jcrKQaz

 

[TOS007]

I noticed the missing commas, and I tried it again, and I got denied.


stochFastMA = (fastMA - ll) / (hh - ll), close(period = Period);
stochSlowMA = (slowMA - ll) / (hh - ll), close(period = Period);

 

[MerryDay]

@TOS007 impressed w/ your stick-to-it-fulness

def agg_high = high (period = period);
def agg_low = low (period = period);
def hh = Highest(agg_high, stochLength);
def ll = Lowest(agg_low, stochLength);

 

[TOS007]

@TOS007 impressed w/ your stick-to-it-fulness

def agg_high = high (period = period);
def agg_low = low (period = period);
def hh = Highest(agg_high, stochLength);
def ll = Lowest(agg_low, stochLength);

It is alive! It is alive!!! Thank you so much MerryDay!

Here is the code for anyone who is interested!

https://imgur.com/wYjmMga

declare lower;
input Period = aggregationPeriod.HOUR;
input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def agg_high = high (period = period);
def agg_low = low (period = period);
def hh = Highest(agg_high, stochLength);
def ll = Lowest(agg_low, stochLength);

def fastMA = MovingAverage(averageType, close(period = Period), fastLength);
def slowMA = MovingAverage(averageType, close(period = Period), slowLength);


def stochFastMA;
def stochSlowMA;

if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));

 

[halcyonguy]

@TOS007 impressed w/ your stick-to-it-fulness

def agg_high = high (period = period);
def agg_low = low (period = period);
def hh = Highest(agg_high, stochLength);
def ll = Lowest(agg_low, stochLength);

thanks merryday. this is what i meant

 

[jaricarr]

@MerryDay @BenTen
Good afternoon, Can someone please look to see if this code can be changed so that it doesn't project to the right ? (StochMACD error)
Looks like is trying to make a false future projection by standing over the zero line. This makes it difficult to read the correct signal.
Thanks.
This is the TOS original Coding:

#
# TD Ameritrade IP Company, Inc. (c) 2019-2021
#

declare lower;

input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close, fastLength);
def slowMA = MovingAverage(averageType, close, slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
stochFastMA = (fastMA - ll) / (hh - ll);
stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
stochFastMA = 0;
stochSlowMA = 0;
}

plot StochasticMACD = (stochFastMA - stochSlowMA) * 100;
plot Signal = MovingAverage(averageType, StochasticMACD, signalLength);
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));

 

[Pensar]

@jaricarr this should remove the plots in the expansion area as you requested

declare lower;

input stochLength = 45;
input fastLength = 12;
input slowLength = 26;
input signalLength = 9;
input over_bought = 10;
input over_sold = -10;
input averageType = AverageType.EXPONENTIAL;

def hh = Highest(high, stochLength);
def ll = Lowest(low, stochLength);

def fastMA = MovingAverage(averageType, close, fastLength);
def slowMA = MovingAverage(averageType, close, slowLength);

def stochFastMA;
def stochSlowMA;
if (hh - ll) != 0 {
    stochFastMA = (fastMA - ll) / (hh - ll);
    stochSlowMA = (slowMA - ll) / (hh - ll);
} else {
    stochFastMA = 0;
    stochSlowMA = 0;
}

def n = double.nan;
def x = !isnan(close);

plot StochasticMACD = if x then (stochFastMA - stochSlowMA) * 100 else n;
plot Signal = if x then MovingAverage(averageType, StochasticMACD, signalLength) else n;
plot OverBought = over_bought;
plot ZeroLine = 0;
plot OverSold = over_sold;

StochasticMACD.SetDefaultColor(GetColor(1));
Signal.SetDefaultColor(GetColor(8));
OverBought.SetDefaultColor(GetColor(7));
ZeroLine.SetDefaultColor(GetColor(0));
OverSold.SetDefaultColor(GetColor(7));