Join useThinkScript to post your question to a community of 21,000+ developers and traders.
find below.
#// This source code is subject to these terms:
#// Attribution-NonCommercial 4.0 International (CC BY-NC 4.0)
#// https://creativecommons.org/licenses/by-nc/4.0/
#// You are free to:
#// Share, copy and redistribute this script
#// Adapt, transform and build on this script
#// Under the following terms:
#// Non-commercial: You cannot sell my indicator. You can't sell my work.
#// Attribution: If you post part of my code, you must give me proper credit
#// © gu5tavo71 (Gustavo Cardelle)
#// Indicator to combines:
#// Trend Channel[Gu5] (by @gu5tavo71) +
#// EMA's cross (26, 50 ) +
#// Golden Cross (50, 200)
#// Actual Study Version: @gu5tavo71
#// v2.4.19, 2022.09.18
#// Project #101
#// This script was written using open source code from another authors:
#// @PineCoders, Built-in Library, and Community Scripts
#// And using the recommendations from the Pine Script™ User Manual's Style Guide
#// Disclaimer: I am not a financial advisor.
#// For purpose educate only. Use at your own risk.
#indicator(title = 'Mix1 : Ema Cross + Trend Channel [Gu5]', shorttitle = 'Mix1', overlay = true)
# Converted and mod by Sam4Cok@Samer800 - 06/2023
#// ——————————— <inputs> {
input maSrc = close; # 'MA Source'
input MovAvgFast1 = 26; # 'EMA Fast'
input MovAvgFast2 = 50; # 'EMA Medium'
input trendLength = 200; # 'MA Trend'
input atrLength = 200;
input atrMultiplier = 0.618; # 'Channel Range Length'
input MovAvgType = AverageType.SIMPLE; # 'MA Type'
input useChartTimeframe = {default "Yes", "No"}; # 'Select Higher Timeframe'
input manualTimeframe = AggregationPeriod.FIFTEEN_MIN;
input ShowStopLoss = no; # 'Stop Loss On/Off'
input StopLossPercent = 2.618; # 'SL %'
input PositionType = {"Only Long", "Only Short", default "Both"}; # 'Position Type'
input StrategyType = {"Strategy 1", default "Strategy 2"}; # 'Strategy Type'
input barColor = yes; # 'Bar Color On/Off'
input SignalsOn = yes; # 'Alert On/Off'
input ChannelRangeOn = no; # 'Channel Range On/Off'
input GoldenCrossOn = no; # 'Golden Cross On/Off'
def na = Double.NaN;
def strat1 = StrategyType == StrategyType."Strategy 1";
def long = PositionType == PositionType."Only Long";
def short = PositionType == PositionType."Only Short";
def c;
switch (useChartTimeframe) {
case "Yes" :
c = close;
case "No" :
c = close(Period = manualTimeframe);
}
#// ——————————— <calculations> {
def condition;
def condition1 = if isNaN(condition[1]) then 0 else condition[1];
def maFast1 = ExpAverage(maSrc, MovAvgFast1);
def maFast2 = ExpAverage(maSrc, MovAvgFast2);
def MovAvgMTF = MovingAverage(MovAvgType, c, trendLength)[1];
def maDir = if maFast1 > maFast2 then 1 else -1;
def maTrend = MovAvgMTF;#//No repaint
def maTrendDir = if maSrc >= maTrend then 1 else -1;
def rangeAtr = ATR(Length = atrLength) * atrMultiplier;
def rangeTop = maTrend + rangeAtr;
def rangeBot = maTrend - rangeAtr;
def rangeCh = (open <= rangeTop or close <= rangeTop) and
(open >= rangeBot or close >= rangeBot);
def trendDir = if strat1 then
if rangeCh then 0 else
if maTrendDir == 1 and maDir == 1 and maTrend > maFast2 then 0 else
if maTrendDir == -1 and maDir == -1 and maTrend < maFast2 then 0 else
if maTrendDir == 1 and maDir == 1 then 1 else
if maTrendDir == -1 and maDir == -1 then -1 else 0 else
if rangeCh then 0 else
if maTrendDir == 1 and maDir == 1 then 1 else
if maTrendDir == -1 and maDir == -1 then -1 else 0;
def GCross = if GoldenCrossOn then Crosses(maFast2, maTrend, CrossingDirection.ABOVE) else na;
def DCross = if GoldenCrossOn then Crosses(maFast2, maTrend, CrossingDirection.BELOW) else na;
#//<rules>
def entryLong = !short and trendDir == 1;
def entryShort = !long and trendDir == -1;
def exitLong = !short and (trendDir != 1 or maDir == -1) and condition1 == 1;
def exitShort = !long and (trendDir != -1 or maDir == 1) and condition1 == -1;
#//<stop loss>
def slEntry = if ShowStopLoss then close * StopLossPercent / 100 else na;
def slTop = if isNaN(slEntry) then 0 else close + slEntry;
def slBot = if isNaN(slEntry) then 0 else close - slEntry;
def slTopBuff = if (condition1 != 1 and entryLong) then slBot else slTopBuff[1];
def slBotBuff = if (condition1 != -1 and entryShort) then slTop else slBotBuff[1];
def slLine = if condition1 == -1 and entryLong then slTopBuff else
if condition1 == 1 and entryShort then slBotBuff else
if condition1 == 1 or entryLong then slTopBuff else
if condition1 == -1 or entryShort then slBotBuff else 0;
def longCross = if isNaN(slLine) then 0 else (close < slLine) and (close[1] >= slLine[1]);
def shortCross = if isNaN(slLine) then 0 else (close > slLine) and (close[1] <= slLine[1]);
def slLong = condition1 == 1 and longCross or high > slLine and low < slLine;
def slShort = condition1 == -1 and shortCross or high > slLine and low < slLine;
#//<conditions>
condition = if condition1 != 1 and entryLong then 1 else
if condition1 != -1 and entryShort then -1 else
if condition1 == 1 and slLong then 0 else
if condition1 == -1 and slShort then 0 else
if condition1 != 0 and exitLong then 0 else
if condition1 != 0 and exitShort then 0 else condition1;
def longE = condition[1] != 1 and condition == 1;
def shortE = condition[1] != -1 and condition == -1;
def longX = condition[1] == 1 and exitLong and !slLong;
def shortX = condition[1] == -1 and exitShort and !slShort;
def longSL = condition[1] == 1 and slLong;
def shortSL = condition[1] == -1 and slShort;
#//<color>
def c_maFill = if longX then 0 else if shortX then 0 else
if trendDir == 1 and maDir == 1 then 1 else
if trendDir == -1 and maDir == -1 then -1 else 0;
def c_maTrend = if trendDir == 0 then 0 else
if trendDir == 1 and maTrend[1] < maTrend then 2 else
if trendDir == 1 and maTrend[1] >= maTrend then 1 else
if trendDir == -1 and maTrend[1] < maTrend then -1 else
if trendDir == -1 and maTrend[1] >= maTrend then -2 else na;
def c_ch = if trendDir == 1 then 1 else
if trendDir == -1 then -1 else 0;
# if trendDir == -1 then -1 else na;
def c_slLineUp = slLine > slLine[1];
def c_slLineDn = slLine < slLine[1];
def c_slLine = if c_slLineUp then na else if c_slLineDn then na else 1;
#-- BAr color
AssignPriceColor(if !barColor then Color.CURRENT else
if trendDir == 0 then Color.GRAY else
if trendDir == 1 and open <= close then Color.GREEN else
if trendDir == 1 and open > close then Color.DARK_GREEN else
if trendDir == -1 and open >= close then Color.RED else
if trendDir == -1 and open < close then Color.DARK_RED else Color.GRAY);
#// ——————————— <plots> {
def p_maFast1 = maFast1;# 'EMA Fast 1'
def p_maFast2 = maFast2;# 'EMA Fast 2'
AddCloud(if c_maFill==0 then na else p_maFast1, p_maFast2, Color.DARK_GREEN, Color.DARK_RED);
AddCloud(if c_maFill==0 then p_maFast1 else na, p_maFast2, Color.DARK_GRAY, Color.DARK_GRAy);
plot smaTrend = maTrend; # 'SMA Trend'
smaTrend.SetLineWeight(2);
smaTrend.AssignValueColor(if c_maTrend==2 then Color.GREEN else
if c_maTrend==1 then Color.DARK_GREEN else
if c_maTrend==-1 then Color.DARK_RED else
if c_maTrend==-2 then Color.RED else color.GRAY);
plot p_chTop = if ChannelRangeOn then rangeTop else na; # 'Top Channel'
plot p_chBot = if ChannelRangeOn then rangeBot else na; # 'Bottom Channel'
p_chTop.AssignValueColor(if c_maTrend==2 then Color.GREEN else
if c_maTrend==1 then Color.DARK_GREEN else
if c_maTrend==-1 then Color.DARK_RED else
if c_maTrend==-2 then Color.RED else color.GRAY);
p_chBot.AssignValueColor(if c_maTrend==2 then Color.GREEN else
if c_maTrend==1 then Color.DARK_GREEN else
if c_maTrend==-1 then Color.DARK_RED else
if c_maTrend==-2 then Color.RED else color.GRAY);
AddCloud(if c_ch<=0 then na else p_chTop, p_chBot,Color.DARK_GREEN);
AddCloud(if c_ch>=0 then na else p_chTop, p_chBot,Color.DARK_RED);
AddCloud(if c_ch!=0 then na else p_chTop, p_chBot,Color.DARK_GRAY);
plot stopLossLine = if isNaN(c_slLine) or slLine==0 then na else
if ShowStopLoss and condition != 0 then slLine else na; # 'Stop Loss Line'
stopLossLine.SetDefaultColor(Color.MAGENTA);
stopLossLine.SetPaintingStrategy(PaintingStrategy.DASHES);
#// ——————————— <alerts> {
AddChartBubble(SignalsOn and longE, low, "Long", Color.GREEN, no);
AddChartBubble(SignalsOn and shortE, high, "Short", Color.RED, yes);
plot Exit = if SignalsOn and (longX or shortX) then close else na;
Exit.SetPaintingStrategy(PaintingStrategy.POINTS);
Exit.SetDefaultColor(Color.YELLOW);
Exit.SetLineWeight(2);
#//<stop loss>
AddChartBubble(SignalsOn and (longSL or shortSL), slLine, "SL", Color.YELLOW, if longSL then yes else no);
plot GoldCrossUp = if SignalsOn and GoldenCrossOn and (GCross or DCross) then close else na;
GoldCrossUp.SetLineWeight(2);
GoldCrossUp.SetPaintingStrategy(PaintingStrategy.SQUARES);
GoldCrossUp.AssignValueColor( if GCross then Color.CYAN else Color.MAGENTA);
#-- END of CODE@samer800 you are the best! thank you very much! really appreciate your time!
check now, I updated the same code.
@samer800 that look perfect! thank you some much once again!
| Thread starter | Similar threads | Forum | Replies | Date |
|---|---|---|---|---|
| C | AGAIG Lower EMA Crossover For ThinkOrSwim | Custom | 0 | |
| R | KusKus Starlight + EMA For ThinkOrSwim | Custom | 2 | |
| M | Tony's EMA Scalper For ThinkOrSwim | Custom | 2 | |
| L | RCI with EMA&MACD test For ThinkOrSwim | Custom | 2 | |
|
Hybrid EMA AlgoLearner for ThinkOrSwim | Custom | 2 |
useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.
We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.
If you are new, or just looking for guidance, here are some helpful links to get you started.
