Join useThinkScript to post your question to a community of 21,000+ developers and traders.
declare upper;
input length = 14;
def o = LinearRegCurve(length = length, price = OPEN);
def h = LinearRegCurve(length = length, price = HIGH);
def l = LinearRegCurve(length = length, price = LOW);
def c = LinearRegCurve(length = length, price = CLOSE);
def o_up = if c > c[1] then o else double.nan;
def h_up = if c > c[1] then h else double.nan;
def l_up = if c > c[1] then l else double.nan;
def c_up = if c > c[1] then c else double.nan;
def o_dn = if c <= c[1] then o else double.nan;
def h_dn = if c <= c[1] then h else double.nan;
def l_dn = if c <= c[1] then l else double.nan;
def c_dn = if c <= c[1] then c else double.nan;
AddChart(open = o_up, high = h_up, low = l_up, close = c_up, growColor = color.green, fallColor = color.green, neutralColor = color.green, type = ChartType.CANDLE);
AddChart(open = o_dn, high = h_dn, low = l_dn, close = c_dn, growColor = color.red, fallColor = color.red, neutralColor = color.red, type = ChartType.CANDLE);
input signal_type = averageType.SIMPLE;
input signal_length = 11;
plot signal = MovingAverage(data = c, length = signal_length, averageType = signal_type);hey you did an excellent job with the candles and that is no easy task on TOS, but can I have the indicator wave line also ? if you look at the trading view one it has a wave line that shows the exact cross over point. The script you did has a plot line { which like all tos scripts I turn the plot line off} hope I'm not asking too much. i must say the candles you did are unbelievable. thanks again
Add these three lines to the end of the indicator and set your colours to taste
input signal_type = averageType.SIMPLE;
input signal_length = 11;
plot signal = MovingAverage(data = c, length = signal_length, averageType = signal_type);great job @mashume , do you think it is possible to changes the candles for dot or something out, because with a candles is a little bit messy. thank you in advance
ThinkOrSwim "supports" the following types of charts*
declare upper;
input length = 14;
input entry_exit_multiplier = 1.5;
input body_only = no;
def o = LinearRegCurve(length = length, price = OPEN);
def h = LinearRegCurve(length = length, price = HIGH);
def l = LinearRegCurve(length = length, price = LOW);
def c = LinearRegCurve(length = length, price = CLOSE);
def o_up = if c > c[1] then o else double.nan;
def h_up = if c > c[1] then if body_only == yes then max(o, c) else h else double.nan;
def l_up = if c > c[1] then if body_only == yes then min(o, c) else l else double.nan;
def c_up = if c > c[1] then c else double.nan;
def o_dn = if c <= c[1] then o else double.nan;
def h_dn = if c <= c[1] then if body_only == yes then max(o, c) else h else double.nan;
def l_dn = if c <= c[1] then if body_only == yes then min(o, c) else l else double.nan;
def c_dn = if c <= c[1] then c else double.nan;
AddChart(open = o_up, high = h_up, low = l_up, close = c_up, growColor = color.green, fallColor = color.green, neutralColor = color.green, type = ChartType.CANDLE);
AddChart(open = o_dn, high = h_dn, low = l_dn, close = c_dn, growColor = color.red, fallColor = color.red, neutralColor = color.red, type = ChartType.CANDLE);
input signal_type = averageType.SIMPLE;
input signal_length = 11;
plot signal = MovingAverage(data = c, length = signal_length, averageType = signal_type);
check the below. I add some potential signals where you need to confirm through other confluences.
#study(title="Humble LinReg Candles", shorttitle="LinReg Candles", format=format.price, precision=4, overlay=true)
# Converted and mod by Sam4COK@Samer800 - 12/2022
input BarColor = yes;
input ShowSignal = yes;
input HidePricePlot = no;
input HideLinRegCandles = no;
input signal_length = 11; # "Signal Smoothing"
input signalMovAvg = AverageType.SIMPLE; # "Simple MA (Signal Line)"
input lin_reg = yes; # "Lin Reg"
input linreg_length = 11; # "Linear Regression Length"
HidePricePlot(HidePricePlot);
def na = Double.NaN;
def bopen = if lin_reg then Inertia(open, linreg_length) else open;
def bhigh = if lin_reg then Inertia(high, linreg_length) else high;
def blow = if lin_reg then Inertia(low, linreg_length) else low;
def bclose = if lin_reg then Inertia(close,linreg_length) else close;
def ohlc = (bopen + bhigh + blow + bclose) / 4;
def candleUp = if HideLinRegCandles then na else bopen < bclose;
def signal = MovingAverage(signalMovAvg, bclose, signal_length);
#// Plot Candles
AddChart(high = if candleUp then bhigh else na,
low = if candleUp then blow else na,
open = if candleUp then bclose else na,
close = if candleUp then bopen else na,
type = ChartType.CANDLE, growcolor = CreateColor(0,153,153));
AddChart(high = if candleUp then na else bhigh,
low = if candleUp then na else blow ,
open = if candleUp then na else bopen,
close = if candleUp then na else bclose,
type = ChartType.CANDLE, growcolor = CreateColor(153,0,153));
# --- Signal Line
def sigUp = signal>signal[1];
plot SigLine = signal;
SigLine.AssignValueColor(if sigUp then Color.GREEN else Color.RED);
#--Bar Color
def raising = bclose > bopen;
def ExtHi = raising and sigUp;
def Hi = !ExtHi and (raising or sigUp);
def ExtLo = !raising and !sigUp;
def Lo = !ExtLo and (!raising or !sigUp);
AssignPriceColor(if !BarColor then Color.CURRENT else
if ExtHi then Color.GREEN else
if Hi then Color.DARK_GREEN else
if ExtLo then Color.RED else
if Lo then Color.DARK_RED else Color.GRAY);
# ---- Signal
def up = signal>signal[1] and ohlc>signal and ohlc>ohlc[1];
def countUp = if up then CountUp[1] + 1 else 0;
def Dn = signal<signal[1] and ohlc<signal and ohlc<ohlc[1];
def countDn = if Dn then CountDn[1] + 1 else 0;
plot PtUp = if countUp==1 and ShowSignal then signal else na;
PtUp.SetLineWeight(3);
PtUp.SetDefaultColor(Color.GREEN);
PtUp.SetStyle(Curve.POINTS);
plot PtDn = if countDn==1 and ShowSignal then signal else na;
PtDn.SetLineWeight(3);
PtDn.SetDefaultColor(Color.RED);
PtDn.SetStyle(Curve.POINTS);
#--- END CODE
try my conversion in post#9, it include bar color feature as well.
I played around with it looking like this:How do you guys use this to trade? Chart is a mess.
#study(title="Humble LinReg Candles", shorttitle="LinReg Candles", format=format.price, precision=4, overlay=true)
# Converted and mod by Sam4COK@Samer800 - 12/2022 - Update - option to change plot Line/Candle
input BarColor = no;
input ShowSignal = yes;
input HidePricePlot = no;
input LinRegStyle = {Default Line, Candle, None};
input signal_length = 11; # "Signal Smoothing"
input signalMovAvg = AverageType.SIMPLE; # "Simple MA (Signal Line)"
input lin_reg = yes; # "Lin Reg"
input linreg_length = 11; # "Linear Regression Length"
HidePricePlot(HidePricePlot);
def na = Double.NaN;
def Style = if LinRegStyle==LinRegStyle.Line then 1 else
if LinRegStyle==LinRegStyle.Candle then -1 else 0;
def bopen = if lin_reg then Inertia(open, linreg_length) else open;
def bhigh = if lin_reg then Inertia(high, linreg_length) else high;
def blow = if lin_reg then Inertia(low, linreg_length) else low;
def bclose = if lin_reg then Inertia(close,linreg_length) else close;
def ohlc = (bopen + bhigh + blow + bclose) / 4;
def raising = bclose > bopen;
def candleUp = if Style>=0 then na else bopen < bclose;
def signal = MovingAverage(signalMovAvg, bclose, signal_length);
plot candleLine = if Style==1 then ohlc else na;
candleLine.AssignValueColor(if raising then Color.CYAN else Color.MAGENTA);
#// Plot Candles
AddChart(high = if candleUp then bhigh else na,
low = if candleUp then blow else na,
open = if candleUp then bclose else na,
close = if candleUp then bopen else na,
type = ChartType.CANDLE, growcolor = CreateColor(0,153,153));
AddChart(high = if candleUp then na else bhigh,
low = if candleUp then na else blow ,
open = if candleUp then na else bopen,
close = if candleUp then na else bclose,
type = ChartType.CANDLE, growcolor = CreateColor(153,0,153));
# --- Signal Line
def sigUp = signal>signal[1];
plot SigLine = signal;
SigLine.AssignValueColor(if sigUp then Color.GREEN else Color.RED);
#--Bar Color
def ExtHi = raising and sigUp;
def Hi = !ExtHi and (raising or sigUp);
def ExtLo = !raising and !sigUp;
def Lo = !ExtLo and (!raising or !sigUp);
AssignPriceColor(if !BarColor then Color.CURRENT else
if ExtHi then Color.GREEN else
if Hi then Color.DARK_GREEN else
if ExtLo then Color.RED else
if Lo then Color.DARK_RED else Color.GRAY);
# ---- Signal
def up = signal>signal[1] and ohlc>signal and ohlc>ohlc[1];
def countUp = if up then CountUp[1] + 1 else 0;
def Dn = signal<signal[1] and ohlc<signal and ohlc<ohlc[1];
def countDn = if Dn then CountDn[1] + 1 else 0;
plot PtUp = if countUp==1 and ShowSignal then signal else na;
PtUp.SetLineWeight(3);
PtUp.SetDefaultColor(Color.GREEN);
PtUp.SetStyle(Curve.POINTS);
plot PtDn = if countDn==1 and ShowSignal then signal else na;
PtDn.SetLineWeight(3);
PtDn.SetDefaultColor(Color.RED);
PtDn.SetStyle(Curve.POINTS);
#--- END CODE
Okay, but when do you enter? And what is your lowers indicator, please (OCEAN_NMM)? ThanksI played around with it looking like this:
It's still messy, but the black bars are my preferred color scheme anyway, and the color overlay doesn't disturb much
-mashume
I haven't used it for timing entries... this is just a study chart (looking at new and intersting things) I've looked at it for trend following.
Will try it thanks a lot! I know this sounds stupid but what is the regression study telling us?
It's just another way of visualizing trends and changes in direction. I've been playing around with linear regression curves for a while (see https://usethinkscript.com/threads/...on-from-the-centerline-for-thinkorswim.10726/) and find them fascinating to use for visualization.
useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.
We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.
If you are new, or just looking for guidance, here are some helpful links to get you started.