hourly ORB question?

[AdamantBidoof]

Is there an orb script with an hourly aggregation instead of a whole day? something like this that plots a cloud on a 3 min IB. ice been just plotting it out by hand.

 

[SleepyZ]

Is there an orb script with an hourly aggregation instead of a whole day? something like this that plots a cloud on a 3 min IB. ice been just plotting it out by hand.

try finds the 1hour breaks (optional vertical at each)
then optionally plots the high/low of the first 3m bar within each break
as well as an optional cloud

input showlines    = yes;
input showcloud    = yes;
input showvertical = yes;
input agg1 = AggregationPeriod.HOUR;
input agg2 = AggregationPeriod.THREE_MIN;

def active = SecondsFromTime(0900) >= 0 and SecondsFromTime(1600) <= 0;
def agg1break =
if GetDay() != GetDay()[1] and open(period = agg1) != open(period = agg1)[1]
then 1
else if open(period = agg1) != open(period = agg1)[1] then agg1break[1] + 1
else agg1break[1];

AddVerticalLine(showvertical and active and agg1break != agg1break[1], "");

def agg2high = if active and agg1break != agg1break[1] then high(period = agg2) else agg2high[1];
plot highagg2 = if !active then Double.NaN else agg2high;
highagg2.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
highagg2.SetHiding(!showlines);
def agg2low = if active and agg1break != agg1break[1] then low(period = agg2) else agg2low[1];
plot lowagg2 = if !active then Double.NaN else agg2low;
lowagg2.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
lowagg2.SetHiding(!showlines);

DefineGlobalColor("Cloud", Color.LIGHT_GRAY);
AddCloud(if !showcloud then Double.NaN else highagg2, lowagg2, GlobalColor("Cloud"), GlobalColor("Cloud"));

;