find holidays on a chart (missing days) for ThinkOrSwim

[halcyonguy]

find holidays, missing trading days, on a chart.
..draw a vertical line and/or a bubble
..the text includes the name of the missing day and the date after it.
..works on any timeframe. on smaller times, will need the expansion area set to a big number.


sometimes i forget about a holiday and end up holding a trade over it.
i wanted somthing on the chart, to remind me about future holidays.
i have been working on and off on some ideas for awhile. but they involve typing in dates, which gets messy and long, with all of the comparisons.

then today i was using dayofweek for something and i came up with this.

if references the first bar of the day.
now that it is done, i see i could have referenced the dayend variable and compared to a future value [-1] , and probably come up with the date of the missing day... but it's late and this will work for me.

# dow_holidays_01
# halcyonguy
# 22-04-06
# check if a trading day is skipped, holidays
# compare 2 day of week #'s  to see if a date was skipped
# dow 1 = monday , 5 = friday

# mobius
def data = getYYYYMMDD();
def year = Round(data/10000, 0);
def month = Round((data % 10000) / 100, 0);
def day = (data % 100);
#addLabel(1, "date: " + month + "/" + day + "/" + AsPrice(year), color.white);

def bn = barnumber();
def lastbar = !isnan(close[0]) and isnan(close[-1]);
def lastcls = if !isnan(close) and !lastbar then close else if lastbar then close else lastcls[1];

def DOW = GetDayOfWeek(GetYYYYMMDD());
def daystart = if GetDay() != GetDay()[1] then 1 else 0;
#def dayend = if GetDay() != GetDay()[-1] then 1 else 0;

# if no skip  = 99
def dayskipped;
if bn == 1 then {
  dayskipped = 99;
} else if (daystart and dow == 2 and dow[1] != 1) then {
  dayskipped = 1;
} else if (daystart and dow == 3 and dow[1] != 2) then {
  dayskipped = 2;
} else if (daystart and dow == 4 and dow[1] != 3) then {
  dayskipped = 3;
} else if (daystart and dow == 5 and dow[1] != 4) then {
  dayskipped = 4;
} else if (daystart and dow == 1 and dow[1] != 5) then {
  dayskipped = 5;
} else {
  dayskipped = 99;
}

input show_bubble = yes;
addchartbubble(show_bubble and dayskipped != 99, lastcls,
(if dayskipped == 1 then "Monday"
else if dayskipped == 2 then "Tuesday"
else if dayskipped == 3 then "Wednesday"
else if dayskipped == 4 then "Thursday"
else if dayskipped == 5 then "Friday"
else "") + "\n" +
"skipped\n" +
"before\n" +
( month + "/" + day + "/" + AsPrice(year) )
, color.cyan, no);

input show_vertical_line = yes;
addverticalline(show_vertical_line and dayskipped != 99,
(if dayskipped == 1 then "Monday"
else if dayskipped == 2 then "Tuesday"
else if dayskipped == 3 then "Wednesday"
else if dayskipped == 4 then "Thursday"
else if dayskipped == 5 then "Friday"
else "") + "  skipped before  " + ( month + "/" + day + "/" + AsPrice(year)) , color.cyan);

# ---------------------------------------------------------
input test1_dow = no;
AddChartBubble( test1_dow, lastcls, dow , color.yellow, no);
#

WMT day chart expansion area = 300

hal_hol

 

[Doubbi]

def na = Double.NaN;
def bn = BarNumber();
def lastbar = (!IsNaN(close) and IsNaN(close[-1]));
def newday = GetDay() <> GetDay()[1];
def currentday = GetDay() == GetLastDay();

# 0 = current day , 1 = prev day, 2 = 2 days ago
input days_back_date = 1;
def dayx = (GetDay() + days_back_date) == GetLastDay();



Hello, this is a part of a code I use it to draw yesterdays lows. It woek perfectly expets the days after market holidays ( it does not work on mondays because the day before is sundays and also it does not work the day just after holidays). Can someone help me. Thanks in advance.

 

[Svanoy]

@Doubbi
Use the difference between the values of GetDay() and GetDay()[1].
If it is greater than 1, the previous day is not charted(i.e. Sundays and Holidays).
So you would look back whatever the difference between GetDay()[1] and GetDay() number of days further to pull the previous trading day low.

 

[halcyonguy]

take a look at this
https://usethinkscript.com/threads/find-holidays-on-a-chart-missing-days-for-thinkorswim.10856/

 

[Doubbi]

@Doubbi
Use the difference between the values of GetDay() and GetDay()[1].
If it is greater than 1, the previous day is not charted(i.e. Sundays and Holidays).
So you would look back whatever the difference between GetDay()[1] and GetDay() number of days further to pull the previous trading day low.

Thank you very much.

 

[Doubbi]

take a look at this
https://usethinkscript.com/threads/find-holidays-on-a-chart-missing-days-for-thinkorswim.10856/

thank you very much.