/ES Futures Trading Strategy on ThinkorSwim

Cant seem to get the link to work from the first page. if some one could pm me the link or repost it I would be grateful :)
 
Cant seem to get the link to work from the first page. if some one could pm me the link or repost it I would be grateful :)

I'm fairly certain that the link works fine, it is your import method of choice that is at fault... It seems that every time TOS releases updates the Zulu Import feature breaks, yet the Manual Method continues to work without issues... Just forget that the Zulu Import exists and opt for the Manual Method... Or use Copy & Paste whenever the code is posted, which should be always, unless someone is sharing and entire Workspace or Chart setup... 💡
 
another update...

Python:
# SPX Strategy
# Strategy designed by Hypoluxa
# barbaros - v1 - 2021/02/25
# barbaros - v2 - 2021/02/25 - added warning arrows, alerts, statistics and non SPX trading option
# barbaros - v3 - 2021/02/26 - added SMA plots, chart type, and price plot
# barbaros - v4 - 2021/03/02 - added trade time limit and do not cross before start time
# barbaros - v5 - 2021/03/02 - added direction label

# Setup
# 10 Min chart
# Heikin Ashi candles
# SMA 3/9
# MACD Bollinger Bands (the one Ben has posted on here a while back) 8,16,36 and uncheck "show plot" on the BB upper, BB lower and BB mid line. You will only be using the zero line, MACD dots and MACD Line for entry purposes. The inputs of "b length" and "bb num dev" are irrelevant here since you will remove the the plots that I mentioned.
# ErgodicOsc 2,10,36 (changed the default negative to red)

# Option call logic:
# 1. The SMA's have to cross first.
# 2. For a call opportunity, you will then wait to see if the MACD dots cross above the MACD zero line. Its critical here to wait until one dot has cleared the zero line...you MUST see a gap....never enter with the dot on the line. Dots must be consistent as well...if its going up...then they must all be white...if a red dot populates between the time a white dot hits the zero line and the time one crosses clear....don't enter. I have a screenshot below showing this example - 13:00 a red dot appears.
# 3. The ErgodicOsc HAS to be green when the MACD dot crosses above the zero line. You can hold the trade most of the time until this turns from green to red....but I always set a sell limit just in case it whips back in the opposite direction.

# Option put logic:
# Obviously its the complete opposite of what I've described above for a call. BUT - the SMA's still have to cross first.

# Note:
# Historical price action testing shows that if the MACDBB crosses zerobase before 9:40 EST, do not take the trade. Also, there might be too much choppiness after 15:00 EST.

declare upper;

input price = close;
input SMAFastLength = 3;
input SMASlowLength = 9;
input BBlength = 30;
input BBNum_Dev = 0.8;
input BBCrossInBars = 3;
input BBCrossDistance = 1.0;
input MACDfastLength = 8;
input MACDslowLength = 16;
input MACDLength = 36;
input ERGODICLongLength = 2;
input ERGODICShortLength = 10;
input ERGODICSignalLength = 36;
input ERGODICAverageType = {"SIMPLE", default "EXPONENTIAL", "WEIGHTED", "WILDERS", "HULL"};
input ShowWarnArrows = no;
input ShowLabels = no;
input ShowStatistics = no;
input ProfitDelta = 1.0;
input LimitTime = yes;
input StartTime = 940;
input EndTime = 1500;
input DoNotCrossBeforeStart = yes;
input AllowNonSPX = no;

# Check for 10min chart
Assert(AllowNonSPX or GetAggregationPeriod() == AggregationPeriod.TEN_MIN, "Incorrect Chart Time, use 10m");
Assert(AllowNonSPX or GetSymbol() == "SPX", "Incorrect Chart Time, use 10m");

# MACD
def MACD_Data = MACD(fastLength = MACDfastLength, slowLength = MACDslowLength, MACDLength = MACDLength);
def MACD_Direction = if MACD_Data > MACD_Data[1] then 1 else -1;

# Ergodic
def Ergodic_Data = ErgodicOsc("long length" = ERGODICLongLength, "short length" = ERGODICShortLength, "signal length" = ERGODICSignalLength, "average type" = ERGODICAverageType).ErgodicOsc;

# SMAs
def SMA_Fast = SimpleMovingAvg(price, SMAFastLength);
def SMA_Slow = SimpleMovingAvg(price, SMASlowLength);

# Time Limit
def isTradeTime = if LimitTime then SecondsFromTime(StartTime) >= 0 and SecondsTillTime(EndTime) >= 0 else yes;
def isNotCrossBeforeStart = if DoNotCrossBeforeStart and SecondsFromTime(StartTime) == 0 then !((MACD_Data crosses above 0 within 2 bars) or (MACD_Data crosses below 0 within 2 bars)) else yes;

# Signals
def buySignal = isTradeTime and isNotCrossBeforeStart and SMA_Fast > SMA_Slow and Ergodic_Data > 0 and MACD_Direction == 1 and MACD_Data >= BBCrossDistance and MACD_Data crosses above 0 within BBCrossInBars bars;
def buyWarnSignal = isTradeTime and isNotCrossBeforeStart and SMA_Fast > SMA_Slow and Ergodic_Data > 0 and MACD_Direction == 1 and MACD_Data crosses above 0 within BBCrossInBars bars;
def sellSignal = isTradeTime and isNotCrossBeforeStart and SMA_Fast < SMA_Slow and Ergodic_Data < 0 and MACD_Direction == -1 and MACD_Data <= -BBCrossDistance and MACD_Data crosses below 0 within BBCrossInBars bars;
def sellWarnSignal = isTradeTime and isNotCrossBeforeStart and SMA_Fast < SMA_Slow and Ergodic_Data < 0 and MACD_Direction == -1 and MACD_Data crosses below 0 within BBCrossInBars bars;

# Plots
plot buy = buySignal and !buySignal[1];
buy.setPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
buy.setDefaultColor(Color.GREEN);
buy.setLineWeight(3);

plot buyWarn = if ShowWarnArrows then buyWarnSignal and !buyWarnSignal[1] else Double.NaN;
buyWarn.setPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
buyWarn.setDefaultColor(Color.CYAN);
buyWarn.setLineWeight(1);
buyWarn.setHiding(!ShowWarnArrows);

plot sell = sellSignal and !sellSignal[1];
sell.setPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
sell.setDefaultColor(Color.RED);
sell.setLineWeight(3);

plot sellWarn = if ShowWarnArrows then sellWarnSignal and !sellWarnSignal[1] else Double.NaN;
sellWarn.setPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
sellWarn.setDefaultColor(Color.MAGENTA);
sellWarn.setLineWeight(1);
sellWarn.setHiding(!ShowWarnArrows);

plot lastPrice = price;
lastPrice.setPaintingStrategy(PaintingStrategy.POINTS);
lastPrice.setDefaultColor(Color.GREEN);

plot fast = SMA_Fast;
fast.setPaintingStrategy(PaintingStrategy.LINE);
fast.setDefaultColor(Color.CYAN);
fast.setLineWeight(1);

plot slow = SMA_Slow;
slow.setPaintingStrategy(PaintingStrategy.LINE);
slow.setDefaultColor(Color.MAGENTA);
slow.setLineWeight(1);

SetChartType(ChartType.HEIKIN_ASHI);

# Alerts
Alert(buy, "Buy", Alert.BAR, Sound.Ring);
Alert(sell, "Sell", Alert.BAR, Sound.Ring);
Alert(buyWarn, "Buy Warning", Alert.BAR, Sound.Ding);
Alert(sellWarn, "Sell Warning", Alert.BAR, Sound.Ding);

# PnL
def entryPrice = if (buySignal and !buySignal[1]) or (sellSignal and !sellSignal[1]) then close else entryPrice[1];
def profitTarget = if buySignal and !buySignal[1] then entryPrice + ProfitDelta else if sellSignal and !sellSignal[1] then entryPrice - ProfitDelta else profitTarget[1];
def orderDir = if BarNumber() == 1 then 0
               else if orderDir[1] == 0 and buySignal and !buySignal[1] then 1
               else if orderDir[1] == 1 and (MACD_Direction != 1 or close crosses above profitTarget) then 0
               else if orderDir[1] == 0 and sellSignal and !sellSignal[1] then -1
               else if orderDir[1] == -1 and (MACD_Direction != -1 or close crosses below profitTarget) then 0
               else orderDir[1];

def isOrder = if IsNaN(orderDir) then no else orderDir crosses 0;
def orderCount = CompoundValue(1, if IsNaN(isOrder) then 0 else if isOrder then orderCount[1] + 1 else orderCount[1], 0);

def orderWinners = if BarNumber() == 1 then 0
                    else if orderDir[1] == 1 and orderDir == 0 then
                        if close >= profitTarget[1] then orderWinners[1] + 1 else orderWinners[1]
                    else if orderDir[1] == -1 and orderDir == 0 then
                        if close <= profitTarget[1] then orderWinners[1] + 1 else orderWinners[1]
            else orderWinners[1];
def winRate = orderWinners / orderCount;

AddLabel(ShowLabels, "SPX Strategy", Color.WHITE);
AddLabel(ShowLabels, if buy then "Buy"
                     else if sell then "Sell"
                     else if buyWarn or sellWarn then "Warn"
                     else if orderDir == 1 then "Long"
                     else if orderDir == -1 then "Short"
                     else "Neutral",
                     if buy then Color.GREEN
                     else if sell then Color.RED
                     else if buyWarn then Color.YELLOW
                     else if sellWarn then Color.LIGHT_RED
                     else if orderDir == 1 then Color.YELLOW
                     else if orderDir == -1 then Color.LIGHT_RED
                     else Color.GRAY
);
AddLabel(ShowLabels and ShowStatistics, "" + orderCount + " Trades | " + AsPercent(winRate), if winRate > 0.5 then Color.GREEN else Color.RED);
How do I make this to work on NQ?
 
TOS shareable links are not working.
Can I get an updated link?

Shared Link ARE working, just not the way you are attempting... Not sure how many times I've posted that the Zulu Import is the culprit, yet the Manual Method listed below that button works... Forget that Zulu Import exists and use the Manual Method... Virtually every TOS Update breaks the Zulu functionality...
 
Shared Link ARE working, just not the way you are attempting... Not sure how many times I've posted that the Zulu Import is the culprit, yet the Manual Method listed below that button works... Forget that Zulu Import exists and use the Manual Method... Virtually every TOS Update breaks the Zulu functionality...
@rad14733 Thanks for the help!

Manual method (if anyone needs this):
Copy the shareable link
Open TOS
Click on "Setup" (top right on the screen)
Then go into "Open Shared Item..."
Paste the link (ctrl+v) and click Import
 
@blakecmathis I have just read through 41 pages of glorious information. Thank you so much. Can't put into words how much I appreciate what you shared.

Also, a question: is there any reason why this wouldn't work with regular candlesticks (which I prefer) as well? I don't see a reason why not.
 
@blakecmathis Have you ever tried confirming on a 3:1 chart ratio? I'm gonna go and backtest that on mine. I really like the oscillator and I have a feeling the 1000:3000 tick chart double confirmation might be key (also in trend)
 
Just want to add my thanks to everyone who has contributed to this thread. Just did my first real money trade using a version of this methodology and it was a winner :) Looking forward to more!
 
If you take a look at the grids that me and @skynetgen posted you'll see exactly what I'm talking about.
@blakecmathis, Thanks for sharing this strategy. Sorry to ask you some basic questions:

1.Today (03-29-21)I have seen up arrow signals at 9:55,9:57 and 10 AM , and FE line is below middle line, If I take position any of these 3 times there was no much moment .
2.But 12:12 PM there was a up arrow signal and FE is line is at around 14% and the from there it had a good move.


MY question is 9:55 ;9:57 and 10 AM, Is it good time to enter If not what is the criteria I can avoid this and enter the Trade at 12:12 PM?


3ncjvwa.png

A7TwlW5.png
 
That is due to the current market condition. It is not the indicator that is at fault. Since the end of January the market is very volatile.
 
@blakecmathis, Thanks for sharing this strategy. Sorry to ask you some basic questions:

1.Today (03-29-21)I have seen up arrow signals at 9:55,9:57 and 10 AM , and FE line is below middle line, If I take position any of these 3 times there was no much moment .
2.But 12:12 PM there was a up arrow signal and FE is line is at around 14% and the from there it had a good move.


MY question is 9:55 ;9:57 and 10 AM, Is it good time to enter If not what is the criteria I can avoid this and enter the Trade at 12:12 PM?


3ncjvwa.png

A7TwlW5.png
Morning Madhu - Speaking only for myself, I did not take the triggers around 10am as I did not get confirmation from either the 2000t chart or the BB Stop line. On the 12:12 signal, the BB stop line confirmed at 12:27 and the 2000t chart confirmed at 12:26. - Matt.
 
Morning Madhu - Speaking only for myself, I did not take the triggers around 10am as I did not get confirmation from either the 2000t chart or the BB Stop line. On the 12:12 signal, the BB stop line confirmed at 12:27 and the 2000t chart confirmed at 12:26. - Matt.
Thank you for replying, i am sorry i am not sure what to check in 2000t or BB stop line, could you please share the screenshot ?
 

New Indicator: Buy the Dip

Check out our Buy the Dip indicator and see how it can help you find profitable swing trading ideas. Scanner, watchlist columns, and add-ons are included.

Download the indicator

Join useThinkScript to post your question to a community of 21,000+ developers and traders.

Not the exact question you're looking for?

Start a new thread and receive assistance from our community.

87k+ Posts
338 Online
Create Post

The Market Trading Game Changer

Join 2,500+ subscribers inside the useThinkScript VIP Membership Club
  • Exclusive indicators
  • Proven strategies & setups
  • Private Discord community
  • ‘Buy The Dip’ signal alerts
  • Exclusive members-only content
  • Add-ons and resources
  • 1 full year of unlimited support

Frequently Asked Questions

What is useThinkScript?

useThinkScript is the #1 community of stock market investors using indicators and other tools to power their trading strategies. Traders of all skill levels use our forums to learn about scripting and indicators, help each other, and discover new ways to gain an edge in the markets.

How do I get started?

We get it. Our forum can be intimidating, if not overwhelming. With thousands of topics, tens of thousands of posts, our community has created an incredibly deep knowledge base for stock traders. No one can ever exhaust every resource provided on our site.

If you are new, or just looking for guidance, here are some helpful links to get you started.

What are the benefits of VIP Membership?
VIP members get exclusive access to these proven and tested premium indicators: Buy the Dip, Advanced Market Moves 2.0, Take Profit, and Volatility Trading Range. In addition, VIP members get access to over 50 VIP-only custom indicators, add-ons, and strategies, private VIP-only forums, private Discord channel to discuss trades and strategies in real-time, customer support, trade alerts, and much more. Learn all about VIP membership here.
How can I access the premium indicators?
To access the premium indicators, which are plug and play ready, sign up for VIP membership here.
Back
Top