Draw Vertical Line for MACD crossover?

[JP782]

I want to have vertical lines drawn when the MACD crosses, I assumed the script would be similar to the one Im using..

def condM1CrossUndr0 = Value < 0 and Value > Avg;
Addlabel(condM1CrossUndr0, "M1”, Color.Green);

... to add a label when crossover happens: changing "addlabel" to "addverticalline" but of course not - clearly theres more to it, what am I missing?

 

[SleepyZ]

Im not having much luck with anyone answering any of the questions Ive been asking last couple weeks but Ill try again-

I want to have vertical lines drawn when the MACD crosses, I assumed the script would be similar to the one Im using..

def condM1CrossUndr0 = Value < 0 and Value > Avg;
Addlabel(condM1CrossUndr0, "M1”, Color.Green);

... to add a label when crossover happens: changing "addlabel" to "addverticalline" but of course not - clearly theres more to it, what am I missing?

The following script will work in the upper panel as well as the lower.

def condM1CrossUndr0 = reference macd().Value < 0 and reference macd().Value > reference
macd().Avg;
Addlabel(condM1CrossUndr0, "M1”, Color.Green);
addverticalLine(condM1CrossUndr0[1]==0 and condm1CrossUndr0,"",color.green);

 

[Nari2007]

anyway it can be coded where it gives a signal or label if not a vertical line,,, when macd cross and histogram are broth above or under the Zero Line? any assistance would be greatly appreciated

 

[SleepyZ]

anyway it can be coded where it gives a signal or label if not a vertical line,,, when macd cross and histogram are broth above or under the Zero Line? any assistance would be greatly appreciated

Input options to show or not: signals (arrows), alerts, verticallines, bubbles and/or labels.

#
# TD Ameritrade IP Company, Inc. (c) 2009-2022
#

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;

def value = MACD(fastLength, slowLength, MACDLength, averageType);
def avg   = MACD(fastLength, slowLength, MACDLength, averageType).Avg;
def Diff  = MACD(fastLength, slowLength, MACDLength, averageType).Diff;

input signal = yes;
plot upsignal = if !signal then Double.NaN else value > 0 and Diff > 0 and value crosses avg;

upsignal.DefineColor("Negative to Positive", Color.GREEN);
upsignal.AssignValueColor(upsignal.Color("Negative to Positive"));
upsignal.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_UP);
upsignal.SetLineWeight(3);

plot dnsignal = if !signal then Double.NaN else value < 0 and Diff < 0 and value crosses avg;

dnsignal.DefineColor("Positive to Negative", Color.RED);
dnsignal.AssignValueColor(dnsignal.Color("Positive to Negative"));
dnsignal.SetPaintingStrategy(PaintingStrategy.BOOLEAN_ARROW_DOWN);
dnsignal.SetLineWeight(3);

input label =  yes;
AddLabel(label, if upsignal then "(Cross and Histogram) > 0" else "(Cross and Histgram) < 0", if upsignal then Color.GREEN else Color.RED);

input bubbles = yes;
input bubbleoffset = 3;
addchartBubble(bubbles and (upsignal or dnsignal), if upsignal then low - ticksize() * bubbleoffset else high + ticksize() * bubbleoffset, if upsignal then "Up" else "Dn", if upsignal then color.green else color.red, if upsignal then no else yes);

input verticalline = yes;
AddVerticalLine(verticalline and upsignal, "", Color.GREEN, stroke = Curve.LONG_DASH);
AddVerticalLine(verticalline and dnsignal, "", Color.RED, stroke = Curve.LONG_DASH);

input alert = yes;
Alert(alert, if upsignal then "(Cross and Histogram) > 0" else "(Cross and Histgram) < 0", Alert.BAR, Sound.Chimes);

 

[Nari2007]

Input options to show or not: signals (arrows), alerts, verticallines, bubbles and/or labels.

WOW!! thank you soo much that was fast!!!

 

[Nari2007]

Input options to show or not: signals (arrows), alerts, verticallines, bubbles and/or labels.

maybe i need to try it when market is open,, the label seems to be staying as is,,, even when i switch TF and macd is over 0 line,

 

[SleepyZ]

maybe i need to try it when market is open,, the label seems to be staying as is,,, even when i switch TF and macd is over 0 line,

Try replacing the label code with this and the label will now only appear on the bar when a signal happens.

input label =  yes;
AddLabel(label and (upsignal or dnsignal), if upsignal then "(Cross and Histogram) > 0" else if dnsignal then "(Cross and Histgram) < 0" else "", if upsignal then Color.GREEN else Color.RED);

 

[bspratt22]

Any chance we can get signal line whenever the MACD crosses regardless if both are over/under zero line?

 

[SleepyZ]

Any chance we can get signal line whenever the MACD crosses regardless if both are over/under zero line?

This will plot a vertical line and bubble at all crosses.
A label will depict the status of the most recent cross.
The colors of the label and bubble are based upon where the cross occurs in relation to the zero line
The colors can be adjusted at the input screen under globals
Optional alerts are included

#MACD_Crosses_Verticals
# TD Ameritrade IP Company, Inc. (c) 2009-2022
#

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;

def value = MACD(fastLength, slowLength, MACDLength, averageType);
def avg   = MACD(fastLength, slowLength, MACDLength, averageType).Avg;
def Diff  = MACD(fastLength, slowLength, MACDLength, averageType).Diff;
def last_cross = if value crosses above avg then 1 else if value crosses below avg then 0 else last_cross[1];

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Above-Below", Color.LIME);
DefineGlobalColor("Below-Below", Color.RED);
DefineGlobalColor("Below-Above", Color.PINK);

input label =  yes;
AddLabel(label and last_cross == 1, "Value crosses ABOVE Avg when" + (if value > 0 or avg > 0 then  " Above 0 line" else " Below 0 line")
, if avg > 0 or value > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"));
AddLabel(label and last_cross == 0, "Value crosses BELOW Avg when" + (if value > 0 or avg > 0 then  " Above 0 line" else " Below 0 line")
, if avg < 0 or value < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"));

input bubbles = yes;
input bubbleoffset = 3;
AddChartBubble(bubbles and value crosses above avg, low - TickSize() * bubbleoffset, "Up" , if avg > 0 or value > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"), no);
AddChartBubble(bubbles and value crosses below avg, high + TickSize() * bubbleoffset, "Dn" , if avg < 0 or value < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"), yes);

input verticalline = yes;
AddVerticalLine(verticalline and value crosses above avg , "", if value > 0 or avg > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"), Curve.LONG_DASH);
AddVerticalLine(verticalline and value crosses below avg, "", if value < 0 or avg < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"), Curve.LONG_DASH);

input alert = yes;
Alert(alert, if value crosses above avg then "Cross ABOVE" else "Cross BELOW", Alert.BAR, Sound.Chimes);

#

 

[bspratt22]

Thank you very much SleepyZ!

 

[rajaodu1]

HI @SleepyZ

From your original code, I added bubbles to be limited by adding Line 27 - 31 and then updated line 33 and 34 and also updated the vertical color based on my eyes. Like this bubble limit, can you please help to create to have limited vertical lines. This may help to reduce the chart with crowded vertical lines. Thanks in advance

input fastLength = 12;

input slowLength = 26;

input MACDLength = 9;

input averageType = AverageType.EXPONENTIAL;



def value = MACD(fastLength, slowLength, MACDLength, averageType);

def avg   = MACD(fastLength, slowLength, MACDLength, averageType).Avg;

def Diff  = MACD(fastLength, slowLength, MACDLength, averageType).Diff;

def last_cross = if value crosses above avg then 1 else if value crosses below avg then 0 else last_cross[1];



DefineGlobalColor("Above-UP", Color.LIME);

DefineGlobalColor("Below-UP", Color.GREEN);

DefineGlobalColor("Below-Down", Color.PINK);

DefineGlobalColor("Above_Down", Color.RED);



input label =  yes;

AddLabel(label and last_cross == 1, "Value crosses ABOVE Avg when" + (if Value > 0 or Avg > 0 then  " Above 0 line" else " Below 0 line")

, if Avg > 0 or Value > 0 then GlobalColor("Above-UP") else GlobalColor("Below-UP"));

AddLabel(label and last_cross == 0, "Value crosses BELOW Avg when" + (if Value > 0 or Avg > 0 then  " Above 0 line" else " Below 0 line")

, if Avg < 0 or Value < 0 then GlobalColor("Below-Down") else GlobalColor("Above_Down"));



input showbubbles = yes;

input bubbleoffset = 3;



input limit_bubbles  = 10;

def count = if !IsNaN(close)  then count[1] + 1 else count[1];

def cond  = HighestAll(count) - count + 1;



AddChartBubble(showbubbles and Value crosses above Avg, if limit_bubbles and cond > limit_bubbles then Double.NaN else low - TickSize() * bubbleoffset, "Up" , if Avg > 0 or Value > 0 then GlobalColor("Above-UP") else GlobalColor("Below-UP"), no);

AddChartBubble(showbubbles and Value crosses below Avg, if limit_bubbles and cond > limit_bubbles then Double.NaN else high + TickSize() * bubbleoffset, "Dn" , if Avg < 0 or Value < 0 then GlobalColor("Below-Down") else GlobalColor("Above_Down"), yes);





#AddChartBubble(bubbles and value crosses above avg, low - TickSize() * bubbleoffset, "Up" , if avg > 0 or value > 0 then GlobalColor("Above-UP") else GlobalColor("Below-UP"), no);

#AddChartBubble(bubbles and value crosses below avg, high + TickSize() * bubbleoffset, "Dn" , if avg < 0 or value < 0 then GlobalColor("Below-Down") else GlobalColor("Above_Down"), yes);



input verticalline = yes;



AddVerticalLine(verticalline and value crosses above avg , "", if value > 0 or avg > 0 then GlobalColor("Above-UP") else GlobalColor("Below-UP"), Curve.LONG_DASH);

AddVerticalLine(verticalline and value crosses below avg, "", if value < 0 or avg < 0 then GlobalColor("Below-Down") else GlobalColor("Above_Down"), Curve.LONG_DASH);



input alert = yes;

Alert(alert, if Value crosses above Avg then "Cross ABOVE" else "Cross BELOW", Alert.BAR, Sound.Chimes);



#

 

[SleepyZ]

HI @SleepyZ

From your original code, I added bubbles to be limited by adding Line 27 - 31 and then updated line 33 and 34 and also updated the vertical color based on my eyes. Like this bubble limit, can you please help to create to have limited vertical lines. This may help to reduce the chart with crowded vertical lines. Thanks in advance

Here is a modification of my last code to limit the plots of both lines and bubbles.
You may need to modify the colors to your liking.

#MACD_Crosses_Verticals
# TD Ameritrade IP Company, Inc. (c) 2009-2022
#

input fastLength = 12;
input slowLength = 26;
input MACDLength = 9;
input averageType = AverageType.EXPONENTIAL;
input limit_lines_bubbles  = 5;

def value = MACD(fastLength, slowLength, MACDLength, averageType);
def avg   = MACD(fastLength, slowLength, MACDLength, averageType).Avg;
def Diff  = MACD(fastLength, slowLength, MACDLength, averageType).Diff;


def count = if BarNumber() == 1 then 0 else if !IsNaN(close) and value crosses avg then count[1] + 1 else count[1];
def cond  = HighestAll(count) - count + 1;
def last_cross = if cond[1] == 2 and cond == 1 and value crosses above avg then 1 else if cond[1] == 2 and cond == 1 and value crosses below avg then 0 else last_cross[1];
def last_cross_ = if cond[1] == 2 and cond == 1 and (value > 0 or avg > 0) then 1 else if  cond[1] == 2 and cond == 1  then 0 else last_cross_[1];

DefineGlobalColor("Above-Above", Color.GREEN);
DefineGlobalColor("Above-Below", Color.LIME);
DefineGlobalColor("Below-Below", Color.RED);
DefineGlobalColor("Below-Above", Color.PINK);

input label =  yes;
AddLabel(label and last_cross == 1, "Value crosses ABOVE Avg when" + (if last_cross_ then  " Above 0 line" else " Below 0 line")
, if last_cross_ == 1 then GlobalColor("Above-Above") else GlobalColor("Above-Below"));
AddLabel(label and last_cross == 0, "Value crosses BELOW Avg when" + (if last_cross_ then  " Above 0 line" else " Below 0 line")
, if last_cross_ == 0  then GlobalColor("Below-Below") else GlobalColor("Below-Above"));

input bubbles = yes;
input bubbleoffset = 3;
AddChartBubble(bubbles and cond <= limit_lines_bubbles and value crosses above avg, low - TickSize() * bubbleoffset, "Up" , if avg > 0 or value > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"), no);
AddChartBubble(bubbles and cond <= limit_lines_bubbles and value crosses below avg, high + TickSize() * bubbleoffset, "Dn" , if avg < 0 or value < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"), yes);

input verticalline = yes;
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and value crosses above avg , "", if value > 0 or avg > 0 then GlobalColor("Above-Above") else GlobalColor("Above-Below"), Curve.LONG_DASH);
AddVerticalLine(verticalline and cond <= limit_lines_bubbles and value crosses below avg, "", if value < 0 or avg < 0 then GlobalColor("Below-Below") else GlobalColor("Below-Above"), Curve.LONG_DASH);

input alert = yes;
Alert(alert, if value crosses above avg then "Cross ABOVE" else "Cross BELOW", Alert.BAR, Sound.Chimes);

#

 

[rajaodu1]

Thank you very much @sleepy.