blackFLAG FTS - SwingArm Trend Indicator using ATRTrailing Stop and Fibonacci Retracements

[lowtrade]

You don't need to change any of the script, just change the aggregation period to set the individual columns in the watchlist.

Do we need to change the ATRFactor or ATRPeriod to get the 10 Minutes, 1HR, 4Hr, Day column watchlist?
input ATRPeriod = 28;
input ATRFactor = 5;

 

[Playstation]

Do we need to change the ATRFactor or ATRPeriod to get the 10 Minutes, 1HR, 4Hr, Day column watchlist?
input ATRPeriod = 28;
input ATRFactor = 5;

no need at all, but you can backtest to find your own edge.
don't edit anything if you're not familiar with it.

 

[Playstation]

irrelevant posting. edited.

 

[Ishaam]

@Playstation, is it possible to have 2 windows / 2 market watchlists, one running the custom quote for the buys and the other custom quote running the sells?

 

[Playstation]

irrelevant posting. edited.

 

[dominos101]

@Ishaam I'm not sure what you mean by windows, but remember the watchlist is pegged to a certain, primary,Master scan of the criteria you set it as.
The custom quotes watchlist will then help you to determine secondarily, the swingarm condition in each column time frame.

How do I install the bullish and bearish alerts?

 

[Ishaam]

@Playstation Ok, I see I can create 2 x watchlists, so I'll just create the top watchlist for buys and the second one for sells.

 

[Happymono]

Odd request would anyone happen to know how to translate this thinkscript into pinescript for tradingview curious as i enjoy they're mobile platform

 

[DaGekko]

I missed the zoom meeting - will the recording be posted soon?

 

[BenTen]

@DaGekko The Zoom meeting from yesterday has been uploaded to our YouTube channel. You can check it out here:

 

[mansor]

@Craighaber71 could you please advice how you were able to set columns (30m/1h/2h/4h/d) with green and red background color & value. I applied your code:

input trailType = {default modified, unmodified};
input ATRPeriod = 28;
input ATRFactor = 5;
input firstTrade = {default long, short};
input averageType = AverageType.WILDERS;
input fib1Level = 61.8;
input fib2Level = 78.6;
input fib3Level = 88.6;
Assert(ATRFactor > 0, "'atr factor' must be positive: " + ATRFactor);
def trail = ATRTrailingStop(trailType, ATRPeriod, ATRFactor, firstTrade, averageType);
def stateLong = low > trail[1];
def stateShort = high < trail[1];
def BuySignal = Crosses(stateLong, 0, CrossingDirection.ABOVE);
def SellSignal = Crosses(stateShort, 0, CrossingDirection.ABOVE);
def ex = if BuySignal then high else if SellSignal then low else if stateLong then Max(ex[1], high) else if stateShort then Min(ex[1], low) else ex[1];
def TrailingStop = trail;
def Extremum = ex;
def f1 = ex + (trail - ex) * fib1Level / 100;
def f2 = ex + (trail - ex) * fib2Level / 100;
def f3 = ex + (trail - ex) * fib3Level / 100;
def l100 = trail + 0;
def Fib1 = f1;
def Fib2 = f2; def Fib3 = f3;
plot data = f1 > f2;
AssignBackgroundColor(if f1 > f2 then Color.GREEN else Color.RED);

Now I am not sure if this a watchlist or a scan (that generally picks, sorts out tickers as they meet script requirements).

 

[ALV]

@mansor- watchlist, You may need to add code above using the gear in the watchlist created for the swing arm. Look for custom scripts and then copy/paste code. Replicate for the amount of columns desired. Make sure to identify the time in the script with the title.

@mansor-

Check this video, form Han -Tech LLC, it will show you how to customize columns around 6:40. I tried it and it works well.

 

[mansor]

@mansor- watchlist, You may need to add code above using the gear in the watchlist created for the swing arm. Look for custom scripts and then copy/paste code. Replicate for the amount of columns desired. Make sure to identify the time in the script with the title.

@ALV thank you for your help and thanks for sharing the video, it made it clear that watchlist is based of a scan & not different than a scan.

 

[lrc11239]

Works nice.. I've been looking at the swing arms on just the RTH sessions and still good zones and information. I use it in conjunction with 2 TMO True Momentum Oscillator with Higher Aggregation by- _Mobius.. Gives me better trade location for my style with /NQ... Many thanks to you and the community for putting these tools together..

 

[Ishaam]

Watchlists using the Fib levels, I'm missing the 4H Sell column as I could only add 19 custom quotes to the watchlist, not sure how to add an extra custom quote if at all possible.

https://imgur.com/a/UIFGM8B

 

[fishstick1229]

I was able to add a single watchlist which includes both long and short swingarm color coding (green/red), as well as an indication if price has entered a certain fib zone (z2, z3, z4).

# blackFLAG FTS SwingArms
# StudyName: blackFLAG_Futures_SwingArm_ATRTrail
# My preferred setting is 28 / 5 FOR ALL TIMEFRAMES
# Edited by: Jose Azcarate
# blackFLAG Futures Trading - FOR EDUCATIONAL PURPOSES ONLY
# TWITTER: @blackflagfuture

# ** Updated code below is to be used for custom watchlist column only ***

input trailType = {default modified, unmodified};
input ATRPeriod = 28;
input ATRFactor = 5;
input firstTrade = {default long, short};
input averageType = AverageType.WILDERS;

input fib1Level = 61.8;
input fib2Level = 78.6;
input fib3Level = 88.6;

Assert(ATRFactor > 0, "'atr factor' must be positive: " + ATRFactor);

def HiLo = Min(high - low, 1.5 * Average(high - low, ATRPeriod));
def HRef = if low <= high[1]
    then high - close[1]
    else (high - close[1]) - 0.5 * (low - high[1]);
def LRef = if high >= low[1]
    then close[1] - low
    else (close[1] - low) - 0.5 * (low[1] - high);

def trueRange;
switch (trailType) {
case modified:
    trueRange = Max(HiLo, Max(HRef, LRef));
case unmodified:
    trueRange = TrueRange(high, close, low);
}
def loss = ATRFactor * MovingAverage(averageType, trueRange, ATRPeriod);

def state = {default init, long, short};
def trail;
switch (state[1]) {
case init:
    if (!IsNaN(loss)) {
        switch (firstTrade) {
        case long:
            state = state.long;
            trail = close - loss;
        case short:
            state = state.short;
            trail = close + loss;
    }
    } else {
        state = state.init;
        trail = Double.NaN;
    }
case long:
    if (close > trail[1]) {
        state = state.long;
        trail = Max(trail[1], close - loss);
    } else {
        state = state.short;
        trail = close + loss;
    }
case short:
    if (close < trail[1]) {
        state = state.short;
        trail = Min(trail[1], close + loss);
    } else {
        state = state.long;
        trail = close - loss;
    }
}

def BuySignal = Crosses(state == state.long, 0, CrossingDirection.ABOVE);
def SellSignal = Crosses(state == state.short, 0, CrossingDirection.ABOVE);

def ex = if BuySignal then high else if SellSignal then low else if state == state.long then Max(ex[1], high) else if state == state.short then Min(ex[1], low) else ex[1];

def TrailingStop = trail;
def f1 = ex + (trail - ex) * fib1Level / 100;
def f2 = ex + (trail - ex) * fib2Level / 100;
def f3 = ex + (trail - ex) * fib3Level / 100;
def l100 = trail + 0;
def Fib1 = f1;
def Fib2 = f2;
def Fib3 = f3;

def bullAboveZone = state == state.long and close > Fib1;
def bullZone2 = state == state.long and close <= Fib1 and close > Fib2;
def bullZone3 = state == state.long and close <= Fib2 and close > Fib3;
def bullZone4 = state == state.long and close <= Fib3 and close > TrailingStop;

def bearZone2 = state == state.short and close >= Fib1 and close < Fib2;
def bearZone3 = state == state.short and close >= Fib2 and close < Fib3;
def bearZone4 = state == state.short and close >= Fib3 and close < TrailingStop;

# watchlist
assignBackgroundColor(if state == state.long then Color.green else Color.red);
AddLabel(yes, if bullZone2 then "z2"  else if bullZone3 then "z3"  else if bullZone4 then "z4" else if bearZone2 then "z2"  else if bearZone3 then "z3"  else if bearZone4 then "z4" else " ",  if bullZone4 or bearZone4 then color.white else Color.BLACK);

 

[lowtrade]

@fishstick1229 This is really cool. What WT_15 on your column list.

 

[mini]

@Playstation May I ask how to combine them into one script? Thank you!

 

[Ishaam]

@fishstick1229 thanks for the combined code, works like a champ

 

[Playstation]

@fishstick1229 This is why there are much more and better scripters than me around! Loving it!

It's working correctly on stocks, but not futures. Could you do a backtest on the different timeframes? can be 15m, 1h, 4h.

edit after realizing i'm such a klutz.
Remember to switch on extended hours watchlist for futures. Don't be a klutz like me!