Advanced Pivot Point Indicator

[woulf1004]

Hi Team,

I will really appreciate if someone can create an indicator that plots the current day pivot point value as a horizontal line with the option to also plot a second indicator that represents the previous day close with a cloud in between them? and please make sure the colors and styles for each plot can be adjusted and modified via edit studies in the TOS tick chart with the choice of show on expansion or show today only as well.
I look forward to hear from you soon.

Thanks.

I will highly appreciate if someone can help put this together please. Thanks

 

[SleepyZ]

I will highly appreciate if someone can help put this together please. Thanks

This should work

input showOnExpansion  = no;
input showprevdayclose = yes;
input clouds           = yes;
input bubbles          = yes;
input bubblemover      = 3;
def   mover = bubbles and isnan(close[bubblemover]) and !isnan(close[bubblemover + 1]);

plot pivotpoints  = if showOnExpansion and !IsNaN(close) then Double.NaN else SVEPivots().PP;
plot prevdayclose = if !showprevdayclose or showOnExpansion and !IsNaN(close) then Double.NaN else close(period = AggregationPeriod.DAY)[1];

pivotpoints.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
pivotpoints.DefineColor("PP", color.cyan);
prevdayclose.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
prevdayclose.DefineColor("PC", color.magenta);

defineGlobalColor("Clouds", color.gray);
addcloud(if !clouds then double.nan else pivotpoints, prevdayclose, globalColor("Clouds"), globalColor("Clouds"));

addchartBubble(bubbles and mover, pivotpoints, "PP", pivotpoints.takevalueColor());
addchartBubble(bubbles and mover, prevdayclose, "PC", prevdayclose.takevalueColor());

#

 

[woulf1004]

This should work

This is awesome SleepyZ!!
Can you please modify it so each plot does not show on expansion? including the bubbles.
I would like to keep the expansion side clean so I can use other tools.

 

[SleepyZ]

This is awesome SleepyZ!!
Can you please modify it so each plot does not show on expansion? including the bubbles.
I would like to keep the expansion side clean so I can use other tools.

This is now defaulted to not show clouds or not show on expansion.

input Plots = {default "Bar Area", "Bars/Expansion", "Expansion Only"};
input showprevdayclose = yes;
input clouds = yes;
input bubbles = yes;
input bubblemover = 0;
def mover = bubbles and IsNaN(close[bubblemover]) and !IsNaN(close[bubblemover + 1]);
def na = double.nan;

plot pivotpoints = if Plots == Plots."Expansion Only" and !IsNaN(close) then na
else if Plots == Plots."Bar Area" and IsNaN(close) then na
else SVEPivots().PP;
plot prevdayclose = if !showprevdayclose then na
else if Plots == Plots."Expansion Only" and !IsNaN(close) then na
else if Plots == Plots."Bar Area" and IsNaN(close) then na
else close(period = AggregationPeriod.DAY)[1];

pivotpoints.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
pivotpoints.DefineColor("PP", Color.CYAN);
prevdayclose.SetPaintingStrategy(PaintingStrategy.HORIZONTAL);
prevdayclose.DefineColor("PC", Color.MAGENTA);

#Clouds
DefineGlobalColor("Clouds", Color.GRAY);
AddCloud(if !clouds then Double.NaN else pivotpoints, prevdayclose, GlobalColor("Clouds"), GlobalColor("Clouds"));

#Bubbles
AddChartBubble(bubbles and pivotpoints != pivotpoints[-1], pivotpoints, "PP", pivotpoints.TakeValueColor());
AddChartBubble(bubbles and prevdayclose != prevdayclose[-1], prevdayclose, "PC", prevdayclose.TakeValueColor());

#Last Bubbles and can be moved by bubblemover input
AddChartBubble(if Plots == Plots."Bars/Expansion" then Double.NaN else bubbles and mover, pivotpoints[bubblemover + 1], "PP", pivotpoints.TakeValueColor());
AddChartBubble(if Plots == Plots."Bars/Expansion" then Double.NaN else bubbles and mover, prevdayclose[bubblemover + 1], "PC", prevdayclose
.TakeValueColor());

#

 

[woulf1004]

This is now defaulted to not show clouds or not show on expansion.

Fantastic!!! One last thing. Can the bubbles show up at the end, on the right side of each plot in the chart?

 

[SleepyZ]

Fantastic!!! One last thing. Can the bubbles show up at the end, on the right side of each plot in the chart?

'
The above code post #4 has been modified to add the bubbles as you requested.
The input plots better describes the various selections. Your default to not plot in expansion is "Bar Area"

 

[woulf1004]

'
The above code post #4 has been modified to add the bubbles as you requested.
The input plots better describes the various selections. Your default to not plot in expansion is "Bar Area"

Perfect! It works great!! Thanks again for all the support SleepyZ!!!