AddCloud - Hide/Remove

[cay7man]

Possible to remove it when the next bar opens?

 

[Joshua]

You can hide it by setting the values to double.nan but the next bar opening is kind of ambiguous. You likely need to provide further detail, perhaps post the script in question.

 

[cay7man]

Don't have any script yet. For example, I want to show the cloud (it will be a vertical bar) if inside bar is forming. The bar should go away if inside bar condition is false or the bar closes (even if it stays inside)

 

[halcyonguy]

Don't have any script yet. For example, I want to show the cloud (it will be a vertical bar) if inside bar is forming. The bar should go away if inside bar condition is false or the bar closes (even if it stays inside)

clouds start and stop at the middle of a bar. can't draw a cloud on just 1 bar.

this will draw a yellow rectangle around the last bar, if it is an inside bar.

# insidebar_lastbar_0

# https://usethinkscript.com/threads/addcloud-hide-remove.12419/#post-106669
# show a vertical bar if inside bar is forming, on the last bar.
# The bar should go away if inside bar condition is false or the bar closes (even if it stays inside)

#yellow outline, addchart()
#https://usethinkscript.com/threads/draw-a-box-around-the-overnight-session-on-futures-intraday-charts.2087/page-3#post-58481
#sleepyz

input tickoffset = 5;
input charttype = ChartType.CANDLE;
def o = open;
def h = high;
def l = low;
def c = close;
def nan = Double.NaN;

def lastbar = !isnan(close) and isnan(close[-1]);
def inside = (high <= high[1] and low >= low[1]);
def cond = lastbar and inside;

def o1 = if cond then h + TickSize() * tickoffset else nan;
def c1 = if cond then l - TickSize() * tickoffset else nan;
def h1 = if cond then h + TickSize() * tickoffset else nan;
def l1 = if cond then l - TickSize() * tickoffset else nan;

DefineGlobalColor(color = Color.YELLOW, name = "Box");
AddChart(growcolor = GlobalColor("Box"), high = h1, low = l1, open = c1, close = o1, type = charttype);
#

 

[cay7man]

@halcyonguy, TY! however my need is different. I would like to see a vertical stripe when the bar is inside and the hide/remove the strip once the bar closes (inside or not)

 

[cay7man]

Even with your script, anyway to remove the yellow box once that bar closes?

 

[SleepyZ]

Don't have any script yet. For example, I want to show the cloud (it will be a vertical bar) if inside bar is forming. The bar should go away if inside bar condition is false or the bar closes (even if it stays inside)

I was working on this also and have a similar code as above. It has a cloud and verticalline options that disappear.

input showmiddlecloud          = yes;
input showoutsideverticallines = yes;

def inside  =  high < high[1] && low > low[1];

#Cloud
def insideh = if showmiddlecloud and IsNaN(inside[-1]) and inside
              then Double.POSITIVE_INFINITY else Double.NaN;
def insidel = if showmiddlecloud and IsNaN(inside[-1]) and inside 
              then Double.NEGATIVE_INFINITY else Double.NaN;
AddChart(if close > open then insideh else Double.NaN, insidel, insideh, insidel, ChartType.CANDLE, growColor = Color.GREEN);
AddChart(if close < open then insideh else Double.NaN, insidel, insideh, insidel, ChartType.CANDLE, growColor = Color.RED);

#Vertical Lines
AddVerticalLine(showoutsideverticallines and IsNaN(inside[-1]) and inside, "", if close > open then Color.GREEN else Color.RED, Curve.FIRM);
AddVerticalLine(showoutsideverticallines and IsNaN(inside[-2]) and inside[1], "", if close[1] > open[1] then Color.GREEN else Color.RED, Curve.FIRM);

 

[cay7man]

@SleepyZ Thank you!!

 

[halcyonguy]

Even with your script, anyway to remove the yellow box once that bar closes?

the yellow box does go away. it only exists on the last bar.

thanks for posting that code , that i used, sleepyz