52-week Highs/Lows For ThinkOrSwim

[DMacTrades]

Hey, how did you get the color codes on the right hand side like that?

Hi MourningWood. I used a script provided by @BenTen on page 1 of this thread to add a column to my scanner results that is red when at 52 wk low, green at 52 week high and yellow for in-between (BenTen's script uses gray instead of yellow). I have pasted the script below, but if you click back 1 page you will see the original post. Again, credit to @BenTen

# HINT: right-click on any watchlist column-->>Customize
# click and drag one of the custom choices to add it to your watchlist column choices
# click on ThinkScript tab and replace the code with this code
# BE SURE to give your new column a name and keep the name short enough it will appear on your watchlist at top of the column (ie new 52wk high)
# REMINDER - you can sort your watchlist by this column by clicking on the column header

#def allows you to teach ThinkScript new "words" that you can reference later in your code
def newHigh = high is equal to highest(HIGH (period = AggregationPeriod.DAY), 252);
def newLow = low is equal to lowest(LOW (period = AggregationPeriod.DAY), 252);

#AddLabel allows you to set conditions such as what words or values will appear when your condition is met.  Yes at the beginning means do show the label ... >=1 or ==1 means when the condition is True then _ and <=0 or ==) would mean then the condition is False then ___
AddLabel(yes, if newHigh >= 1 then "new 52wk high TODAY" else if newLow >= 1 then "new 52wk low TODAY" else " ");

#on a watchlist column AssignBackgroundColor will change the column color when conditions are met.  But AssignBackgroundColor when used in a chart Study or Strategy will change entire chart background
AssignBackgroundColor (if newHigh >= 1 then color.GREEN else if NewLow >= 1 then color.RED else color.YELLOW);

# end custom column code ------------------

 

[vamsu]

Hi there - Could anyone help me with ToS screener which lists the stocks which have a new ATH after 1, 2yrs etc consolidation ?

Thanks

 

[XeoNoX]

@vamsu A new ATH after a full year? Can you define this? From what you are saying is, the candle from 1 year ago, then see if its at all time highs? that wouldn't be all time highs. I assume you mean stocks that are at a 1 year high or 2 year high but you would have to clarify. If that's what you mean that can be found in the default built in scan in think or swim under <price performance>

 

[vamsu]

I meant I want to find stocks which are breaking out to new ATH after 1,2+ years consolidations. For example, recently GM made a new high after 2 yr.

Basically, I want to find stocks which are making new highs after a long consolidation. Thanks for the help!

 

[XeoNoX]

You would have to define consolidation and then scan for price at 12 or 24 month high

 

[vamsu]

@XeoNoX Any exiting script that I could tweak to define consolidation ?

 

[XeoNoX]

you can find quite a few on the forums that fit you the best, then just set it after with the built in TOS scan for price at 12 or 24 month high

 

[BenTen]

@vamsu Check out this thread: https://usethinkscript.com/threads/finding-stocks-on-sideways-trend.3878/

 

[eugchen]

LOVE THIS CODE. i use a white background and the font shows up white. anyway to keep the red and green background, but how would i change the font to black?

also on this code, how do i make sure digits are rounded to nearest hundredth digits? on some stocks, it goes to 4 digits. not sure why.

 

[BenTen]

@eugchen You can only change the color of the label, not the text within it.

Learn about the Round() function here.

 

[eugchen]

Can you help me in figuring out where the round function goes? Cant figure it out. when I added it before the color, I get errors

#CODE BELOW
AddLabel(1, "52Week HIGH = " + Highest(high(period = AggregationPeriod.Week),52), Round(close, 2), Color.green);
AddLabel(1, "52Week LOW = " + Lowest(low(period = AggregationPeriod.Week),52), Round(close, 2), Color.red);
#END CODE

 

[eugchen]

Ok after extensive research, I have figured it out if anyone is interested...

def hi52 = Highest(high(period = AggregationPeriod.Week),52);
addlabel(1, "52Wk HI: $" + Round(hi52, 2), color.green);

def low52 = Lowest(low(period = AggregationPeriod.Week),52);
addlabel(1, "52Wk LOW: $" + Round(low52, 2), color.red);

This code rounds to nearest 2 digits after decimal and adds a "$".

Thanks guys!

 

[KELTON98]

Hi all, Im brand new at thinkscript so any help is appreciated!
Im looking to create a code to find stocks that are trading within 5% of their 52 week high. Can anyone help?

 

[Slippage]

@KELTON98 ThinkOrSwim has a built in scan for that. Add filter, select Study. Then for the study type, in Price Performance select Near_Highs_Lows and change the default 3% to 5%..

 

[MarcVUM]

has anyone seen a tos script that draws a line to mark a defined percentage below the chart high bubble? For instance, on SPX the current 52 week high is 3894.56 and if price were to drop 5% the value would be 3699.83. Looking for a script that can draw and update the 5% line as price moves up. Thanks!

 

[XeoNoX]

vertical or horizontal line? and to understand you... you want the line drawn 5% below the 52 week high or all time high?

 

[rad14733]

Try this code...

#PlotPctDiffDays
#plot price percent above or below close
#days: 5 = week, 22 = month, 252 = year
#pct positive for above, negative for below
#Change Highest to Lowest for finding lowest low
#Coded by rad14733 for usethinkscript.com
#v1.0 : 2021-02-06 : Initial Release

input days = 252;
input price = high;
input pct = 5;

plot data = Highest(price, days) * (1 + (pct / 100));

#END - PlotPctDiffDays

 

[XeoNoX]

@MarcVUM welll i already put the time into it, so figured ide post it anyways, here is a slighly different version of what you requested

Draws Line at the SPECIFIED DAY/WEEK/MONTH HIGH
Draws Secondary Line XYZ Percent away from the SPECIFIED HIGH
DEFAULT IS DRAWS LINE AT 12 MONTH HIGH and ANOTHER LINE AT -5% AWAY
Plots on different time frames
Remember to like if you found this post useful

#By XeoNoX via usethinkscript.com
#Draws Line at the SPECIFIED DAY/WEEK/MONTH HIGH
#Draws Secondary Line XYZ Percent away from the SPECIFIED HIGH
#DEFAULT IS  DRAWS LINE AT 12 MONTH HIGH and ANOTHER LINE AT -5% AWAY
input baseperiod =  {default MONTH, WEEK, DAY};
# Specify The number number of basePeriod periods to go back
Input ago = 12;
#Specify The Percent value you want to draw your secondary line
Input percent_away_to_draw = -5;
Input ShowPercentlabel = yes;
Input ShowMainLabel = yes;
plot PriceValue = HighestAll(if IsNaN(Highest(high(period=BasePeriod), ago)[-1]) and !IsNaN(Highest(high(period = BasePeriod), ago)) then Highest(high(period = BasePeriod), ago) else Double.NaN);
Plot PriceValuePercent = (PriceValue * (.01*percent_away_to_draw)) + pricevalue ;
AddLabel (ShowPercentlabel,  Round(PriceValuePercent,2) +" is " +percent_away_to_draw + "% from" + ago +" "+ baseperiod  + " High" );
AddLabel (ShowMainlabel, ago + " " + BasePeriod + " High:  " + round(PriceValue,2) );
PriceValue.SetDefaultColor(Color.Cyan);
PricevaluePercent.SetDefaultColor(Color.yellow);

 

[DMacTrades]

can you share a link for this I can't seem to get it to work. Thanks

https://usethinkscript.com/threads/...s-scanner-and-watchlist-column.809/post-33302

 

[Almighty1]

Anyone know how to do this one? On Fidelity Investments, I noticed that it shows next to the stock, the current price relative to the 52 week price range.